# uni_library

!!This is the file containing the university library

killvar '$downlibrary'
$downlibrary['read'] = {
	*clr & cla
	menu_off = 1
	if blizoruk = 500 or glassqw = 1:
		glassqw = 1
		msg '	The text blurs across the page. It seems you have poor eyesight. Maybe you should visit an ophthalmologist?'
		gt 'uni_library', 'start'
	end
	if pcs_nerd > 0:
		lastread = totminut
		lastreadday = daystart
		pcs_nerd += 1
	end
	minut += 60
	blizoruk += 1
}

if $ARGS[0] = 'start' or $ARGS[0] = '':
	$sexloc = 'uni_library'
    $location_type = 'public_indoors'
	cla & *clr
	minut += 5
	$menu_loc = 'uni_library'
	$menu_arg = 'start'
	menu_off = 0
	gs 'katja_meynold_schedule'
	!!gs 'albina_uni_schedule'
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">The University Library</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/library.jpg"></center>'
	'One of the medium sized buildings is the university''s library. It is three stories tall and filled with books, sections with tables scattered around to study or relax at and computer stations to help students with their studying.'
	
	if locat['katja'] = 29:
		'You see '+iif(katjaQW['know_katja_uni'] = 0 and ($start_type = 'city_tg' or $start_type = 'uni_tg'), 'a cute redheaded girl', '<a href="exec:gt ''katja_uni'', ''library''">Katja</a>')+' sitting at one of the desks with a laptop and a pile of books.'
	end
	
	!!if locat['albina'] = 6:
		!!'You see '+iif(AlbinaQW['know_albina_uni'] = 0 and ($start_type = 'city_tg' or $start_type = 'uni_tg'), 'an attractive looking brunette', '<a href="exec:gt ''albina_uni'', ''library''">Albina</a>')+' searching the shelves for books.'
	!!end

	if week <= 4 and hour >= 15 and hour < 17:
		if meet_kendra = 1:
			'You see <a href="exec:gt ''uni_library'', ''kendra''">Kendra</a> sitting at one of the tables studying some books.'
		else
			'You see a pretty ebony <a href="exec:gt ''uni_library'', ''kendra''">girl</a> sitting at one of the tables studying some books.'
		end
	end
	
	if mid($start_type,1,2) = 'sg' and yearstart > 1 and week > 5 and hour >= 12 and hour < 14:
		if nataliaQW['library_day_check'] ! daystart:
			nataliaQW['library_day_check'] = daystart
			if rand(0,3) = 0: nataliaQW['library_day'] = daystart
		end
		if nataliaQW['library_day'] = daystart:
			'You see your former classmate <a href="exec: gt ''natalia_pavlova'',''library''">Natalia Pavlova</a>.'
		end
	end
	
	if (week < 6 or hour < 23) and hour > 7:
		act 'Read a book':
			gt 'uni_library', 'read'	
		end
		
		act 'Borrow a book':
			gt 'uni_library', 'loan'
		end

		if university['enrolled_in_semester'] > university['semester_passed']:
			act 'Study': gt 'uni_library', 'study'
		end

		act 'Wander around': gt 'uni_library', 'wander'
	else
		'The library is closing for the night.'
	end
	act 'Leave':
		minut += 2
		gt 'uni_grounds', 'main'
	end
end

if $ARGS[0] = 'study':
	$sexloc = 'uni_library'
	cla & *clr
	minut += 5
	gs 'stat'
	'<center><b><font color="maroon">The University Library</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/study' + rand(1,7) + '.jpg"></center>'
	'You spend some time collecting some books on your subjects and grab one of the library''s laptops before finding a quiet place to sit.' 
	if university['semester_week'] > 0:
		i = 0
		:study_loop
		if $class_list_institution[i] = 'uni_<<$university[''enrolled_in'']>>_semester_<<university[''enrolled_in_semester'']>>':
			if dyneval ('RESULT = class[''<<$class_list_institution[i]>>_<<$class_list_name[i]>>_optional_weekly_grade_gain'']') < dyneval ('RESULT = class[''<<$class_list_institution[i]>>_<<$class_list_name[i]>>_optional_weekly_max'']'):
				dynamic '	act ''Study for your <<$class_list_name[i]>> class (30 minuts)'': gt ''uni_library'', ''studying'', ''<<$class_list_institution[i]>>'', ''<<$class_list_name[i]>>'' '
			else
				*nl
				'You don''t need to study any more this week for your <<$class_list_name[i]>> class.'
			end
		end
		
		i += 1
		if ARRSIZE('class_list_institution') >= i: jump 'study_loop'
		killvar 'i'
	elseif university['exam_week'] > 0:
		i = 0
		:exam_loop
		if $class_list_institution[i] = 'uni_<<$university[''enrolled_in'']>>_semester_<<university[''enrolled_in_semester'']>>' and func('uni_programs', 'exam', 'is_over', $class_list_name[i]) = 0:
			dynamic '	act ''Study intensely for your <<$class_list_name[i]>> exam (30 minuts)'': gt ''uni_library'', ''studying_exam'', ''<<$class_list_institution[i]>>'', ''<<$class_list_name[i]>>'' '
		end
		
		i += 1
		if ARRSIZE('class_list_institution') >= i: jump 'exam_loop'
		killvar 'i'
	end	
	act 'Leave':
		minut += 5
		gt 'uni_grounds', 'main'
	end
	act 'Return to the entrance':
		minut += 2
		gt 'uni_library', 'start'
	end
	act 'Wander around': gt 'uni_library', 'wander'
end

if $ARGS[0] = 'studying':
	cla & *clr
	'<center><b><font color="maroon">The University Library</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/study' + rand(1,7) + '.jpg"></center>'
	minut += 30
	gs 'grades', 'optional_activity_attribute', '<<$ARGS[1]>>', '<<$ARGS[2]>>', 'yes', min(pcs_intel+10,100)
	gs 'stat'
	'You open the books and start studying for your <<$ARGS[2]>> class. The library is mostly quiet, but you hear occasional noises, some of them hard to make out and some of them fairly suspicious. Despite this, it is a good environment to study in and you can see a number of other students studying as well.'
	*nl
	if dyneval ('RESULT = class[''<<$ARGS[1]>>_<<$ARGS[2]>>_optional_weekly_grade_gain'']') < dyneval ('RESULT = class[''<<$ARGS[1]>>_<<$ARGS[2]>>_optional_weekly_max'']'):
		'You study for half an hour and can tell that you will need to study more if you want to completly understand this week''s material.'
	else
		'You study for half an hour and believe you now understand everything that is being covered this week.'
	end
	act 'Leave':
		minut += 5
		gt 'uni_grounds', 'main'
	end
	if (week < 6 or hour < 23) and hour > 7:
		act 'Return to entrance':
			minut += 2
			gt 'uni_library', 'start'
		end
		act 'Keep studying': gt 'uni_library', 'study'
		act 'Wander around': gt 'uni_library', 'wander'
	else
		'The library is closing for the night.'
	end
end

if $ARGS[0] = 'studying_exam':
	cla & *clr
	'<center><b><font color="maroon">The University Library</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/study' + rand(1,7) + '.jpg"></center>'
	!!Nerds like studying and so their mood improves a little. Everybody else gets in a worse mood by studying.
	gs 'exp_gain', 'intel', max(0,rand(-1,1))
	pcs_mood += (pcs_traits['nerd_status']*5 -10)
	minut += 30
	'You open the books and start studying for your <<$ARGS[2]>> exam. The library is mostly quiet, but you hear occasional noises, some of them hard to make out and some of them fairly suspicious. Despite this, it''s a good environment to study in and you can see a number of other students studying as well.'
	if pcs_sleep < 5:
		no_study = 1
		'You''re so tired that you''re constantly falling asleep. You get no studying done in this condition.'
	elseif pcs_sleep < 30:
		study_mod -= 20
		'You''re very tired and have a hard time keeping your eyes open.'
	end
	if alko >= 6:
		no_study = 1
		'You''re so drunk that your eyes can''t make sense of the letters written in the books. Holding your pen is also a problem.'
	elseif alko >= 4:
		study_mod -= 40
		'You''re drunk and have trouble concentrating on reading the books. When you look at the notes you''ve made, a lot of them are incomprehensible.'
	elseif alko >= 2:
		study_mod -= 20
		'You''re feeling a little tipsy, but feel like your studying is going great. However, when you look at your notes afterwards, you notice that a lot of them make no sense.'
	end
	if mentats_dose >= 1: study_mod += 30
	If pcs_mood < 50:
		study_mod -= 20
		'You''re in a bad mood and it clearly affects your studying.'
	end
	if StrongNarkota > 0 or jointhigh > 0:
		study_mod -= 40
		'You''re stoned, which makes it hard to concentrate on studying.'
	end
	if amphHigh > 0: study_mod += 20
	if pcs_energy < 5:
		study_mod -= 20
		'You''re extremely hungry and it''s hard to think about anything other than food.'
	elseif pcs_energy < 10:
		study_mod -= 10
		'You''re very hungry and it affects your ability to concentrate.'
	elseif pcs_energy < 20:
		study_mod -=10
		'You''re hungry and your thoughts often drift to food, affecting your performance negatively.'
	end
	if pcs_horny > 90:
		study_mod -= 10
		'You''re extremely horny and your thoughts often drift to sex, affecting your ability to study.'
	end
	if pain['total'] > 90:
		no_study = 1
		'You''re in so much pain that you can''t study.'
	elseif pain['total'] > 75:
		study_mod -= 40
		'You''re in so much pain that you have a very hard time concentrating on studying.'
	elseif pain['total'] > 60:
		study_mod -= 20
		'Your pain is constantly bothering you and makes it hard to study.'
	end
	*nl
	study_mod = max(0,(rand(30 + study_mod,pcs_intel + study_mod) + 10)/33)
	if no_study = 1:
		'You try to study for half an hour, but get nothing done.'
	else
		if study_mod = 0:
			'You study for half an hour, but you don''t think you''re improving.'
		elseif study_mod = 1:
			'You study for half an hour and think you''re improving a little.'
		elseif study_mod = 2:
			'You study for half an hour and believe that you''re making good progress in getting ready for the exam.'
		else
			'You study for half an hour and believe that you''re improving a lot.'
		end		
		gs 'grades', 'grade_award', '<<$ARGS[1]>>', '<<$ARGS[2]>>', study_mod
	end
	
	gs 'stat'
	
	killvar 'study_mod'
	killvar 'nod_study'
	
	act 'Leave':
		minut += 5
		gt 'uni_grounds', 'main'
	end
	if (week < 6 or hour < 23) and hour > 7:
		act 'Return to the entrance':
			minut += 2
			gt 'uni_library', 'start'
		end
		act 'Keep studying': gt 'uni_library', 'study'
		act 'Wander around': gt 'uni_library', 'wander'
	else
		'The library is closing for the night.'
	end
end

if $ARGS[0] = 'wander':
	$sexloc = 'uni_library'
	cla & *clr
	minut += 15
	gs 'stat'
	'<center><b><font color="maroon">The University Library</font></b></center>'
	temp = rand(1,20)
	if temp = 1:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/accident_panty_flash.jpg"></center>'
		'As you wander around, you spot two girls in one of the rows of books. One of them starts climbing the shelf to get at a book out of reach and her short skirt rides up as she does, showing off her panties to everyone looking. You can''t help but smile as you continue on.'
		gs 'arousal', 'erotic_nudity', 3
		gs 'stat'
	elseif temp = 2:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/accident_pussy_flash.jpg"></center>'
		'As you wander around, you spot a girl in one of the rows of books. She starts climbing the shelf to get at a book out of reach and her short skirt rides up as she does, showing off her pussy to everyone looking. You can''t help but smile as you continue on.'
		gs 'arousal', 'erotic_nudity', 3
		gs 'stat'
	elseif temp = 3:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/asian_titflash.jpg"></center>'
		'As you wander around, you stop inside of one of the rows of books before it opens up into another one of the small study areas. Before you are several guys, sitting at a table encouraging an Asian girl to pull up her shirt. She keeps refusing, but you can tell she is getting aroused and excited by the attention they are giving her. Finally, blushing a little, she pulls up her shirt and holds it up, showing off her firm little breasts. The guys all grin and quietly clap before she pulls her shirt down and walks away blushing. You wonder if she regrets doing it before you continue on your way.'
		gs 'arousal', 'erotic_nudity', 3
		gs 'stat'
	elseif temp = 4:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/black_titflash.jpg"></center>'
		'As you wander around, you stop inside of one of the rows of books before it opens up into another one of the small study areas. Before you are several guys, sitting at a table encouraging a chubby black girl to pull up her shirt. She keeps refusing, but you can tell she is getting aroused and excited by the attention they are giving her. A few seconds later, she finally exposes her large, saggy breasts to them. The guys all grin and quietly clap before she pulls her shirt down and goes back to studying. You wonder if she regrets doing it before you continue on your way.'
		gs 'arousal', 'erotic_nudity', 3
		gs 'stat'
	elseif temp = 5:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/girl_sleeping.jpg"></center>'
		'As you wander around, you spot a girl with her head down on one of the work stations, apparently having fallen asleep while studying. She snores softly, a few of the other students occasionally glancing over and laughing at her softly. You shake your head and leave the girl to sleep in peace.'
	elseif temp = 6:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/laying_in_row.jpg"></center>'
		'As you wander around, you start down one of the rows, only to find a girl lying in the middle of the aisle on her stomach, reading a book. She briefly glances up at you before going back to her book and ignoring you. Not able to easily get past her and not wanting to be rude by trying to step over her, even if she is being rude in the first place, you decide to just walk over to the next aisle and continue your wandering.'
	elseif temp = 7:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/naked_run.jpg"></center>'
		'As you wander around, you glimpse what appears to be a naked girl dashing between two aisles of books. You glance into the aisle she went down and see her continue running down the aisle. You have no clue where her clothes are or why she''s doing it, but with how fast she''s running, you doubt she is enjoying it. She quickly disappears down another row of shelves.'
		gs 'arousal', 'erotic_nudity', 3
		gs 'stat'
	elseif temp = 8:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/naked_walk.jpg"></center>'
		'As you turn to head down an aisle, you come nearly face to face with a pretty blond girl standing there naked. She just smiles at you and says hello. You respond in kind and she walks past you like nothing is wrong. You shake your head and continue on your way. A few seconds later, you come across a guy holding a girl''s clothes while glancing down each aisle. You can only assume he is looking for the naked girl you seen and so point in the direction you saw her. He smiles and nods before jogging in that direction.'
		gs 'arousal', 'erotic_nudity', 3
		gs 'stat'
	elseif temp = 9:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/pussy_flash.jpg"></center>'
		'As you wander around, you go through one of the small study areas. Before you are several guys sitting at a table, encouraging a girl standing just inside of one of the aisles to flash them. She keeps refusing, but you can tell she is getting aroused and excited by the attention they are giving her. Finally, she lifts her skirt and flashes her neatly trimmed pussy at them. One of the guys briefly woops loudly, but is promptly hit by his friends and told to be quiet. Several others look over at the boys, but the girl has already dropped her skirt back in place and walks off with a grin on her face. You wonder if she regrets doing it as you continue on your way.'
		gs 'arousal', 'erotic_nudity', 3
		gs 'stat'
	elseif temp = 10:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/tit_flash.jpg"></center>'
		'As you wander around, you go through one of the small study areas. Before you are several guys sitting at a table, encouraging a girl standing just inside of one of the aisles to flash them. She keeps refusing, but you can tell she is getting aroused and excited by the attention they are giving her. Finally, she lifts her shirt and flashes her breasts at them. One of the guys briefly woops loudly, but is promptly hit by his friends and told to be quiet. Several others look over at the boys, but the girl has already dropped her shirt back in place and walks off with a grin on her face. You wonder if she regrets doing it as you continue on your way.'
		gs 'arousal', 'erotic_nudity', 3
		gs 'stat'
	elseif temp = 11:
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/events/sex/bj.jpg"></center>'
		'As you walk around, you hear some moaning, and glancing down one of the rows of shelves, you see a boy sitting at one of the work stations. It takes a moment for you to notice the girl under the desk on her knees bobbing her head up and down in his lap. You watch for a few more seconds, feeling aroused at the scene before you decide to move on before you''re spotted.'
		gs 'arousal', 'erotic', 3
		gs 'stat'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/island/university/library/library.jpg"></center>'
		'You wander around the library for a while, looking at all the books. You pass by several of your fellow students, some quietly studying, reading or just looking through the bookshelves. You don''t come across anything of interest.'
	end
	act 'Leave':
		minut += 5
		gt 'uni_grounds', 'main'
	end
	if (week < 6 or hour < 23) and hour > 7:
		act 'Return to the entrance':
			minut += 2
			gt 'uni_library', 'start'
		end
		act 'Wander around':
			gt 'uni_library', 'wander'
		end 
	else
		'The library is closing for the night.'
	end
end

if $ARGS[0] = 'read':
	cla
	act 'Read a book on science (1:00)':
		dynamic $downlibrary['read']
		gs 'exp_gain', 'intel', rand(3,6) + (mentats_dose - rand(0,mentats_dose))
		grupvalue[3] += 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/science1.jpg"></center>'
		'You spend an hour reading, trying to make sense of all the clever propositions written inside and understand the subject it describes.'
		act 'Put the book back': gt 'uni_library', 'read'
	end

	act 'Read an adventure novel (1:00)':
		dynamic $downlibrary['read']
		pcs_mood = 100
		grupvalue[3] += 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/fiction' + rand(1,2) + '.jpg"></center>'
		'You spend an hour reading an adventure novel, immersing yourself in daring deeds and awesome twists.'
		act 'Put the book back': gt 'uni_library', 'read'
	end

	act 'Read a fantasy novel (1:00)':
		dynamic $downlibrary['read']
		pcs_mood = 100
		grupvalue[3] += 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/fantasy' + rand(1,9) + '.jpg"></center>'
		'You spend an hour reading a fantasy novel, rescuing damsels from dragons, digging for jewels with dwarves and performing word changing magic alongside elves and druids.'
		act 'Put the book back': gt 'uni_library', 'read'
	end

	act 'Read a science fiction novel (1:00)':
		dynamic $downlibrary['read']
		pcs_mood = 100
		grupvalue[3] += 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/scifi' + rand(1,6) + '.jpg"></center>'
		'You spend an hour reading a science fiction novel - flying off into space, travelling though time, running from rogue AI and creating monsters with your hunchbacked assistant.'
		act 'Put the book back': gt 'uni_library', 'read'
	end

	act 'Read a romance novel (1:00)':
		dynamic $downlibrary['read']
		pcs_mood = 100
		pcs_horny += 20
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/romance' + rand(1,20) + '.jpg"></center>'
		'You spend a very short hour reading a romance novel - choosing between a vampire or a werewolf, falling in love with an obscenely wealthy Grey... Several of the scenes are very steamy and you find yourself getting quite aroused.'
		act 'Put the book back': gt 'uni_library', 'read'
	end
	
	temp = pcs_intel * 2 + pcs_sprt
	if temp < 100:
		$diff = 'hard'
	elseif temp < 150:
		$diff = 'medium'
	else
		$diff = 'easy'
	end
	gs 'willpower', 'misc', 'self', $diff
	if will_cost <= pcs_willpwr:
		act 'Read from the collected works of Leo Tolstoy (1:00) (<<will_cost>> Willpower)':
			gs 'willpower', 'pay', 'self'
			killvar 'will_cost'

			dynamic $downlibrary['read']
			gs 'exp_gain', 'sprt', rand(3,6)
			grupvalue[3] += 2
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/tolstoy.jpg"></center>'
			'You read the book for an hour. Tolstoy is certainly a classic writer, but he used a <i>lot</i> of words.'
			act 'Put the book back': gt 'uni_library', 'read'
		end
	else
		act 'Read from the collected works of Leo Tolstoy (1:00) (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end
	
	act 'Go back': gt 'uni_library', 'start'
end

if $ARGS[0] = 'loan':
	cla
	if $lib_book_loaned ! '':
		'You''ve currently borrowed <<$lib_book_loaned>>.'
		if lib_debt <= 0:
			temp_loan_days_left = lib_debt / -50
			'You have <<temp_loan_days_left>> days left before you need to return it.'
		else
			'<font color="red">Your book is overdue!</font>'
		end

		act 'Return your loaned book':
			if lib_book_read = 0:
				if $lib_book_loaned = 'fantasy': f_book -= 1
			elseif lib_book_read = 1:
				if $lib_book_loaned = 'fantasy': fantasybook = 0
			end
			$lib_book_loaned = ''
			if lib_debt <= 0: lib_debt = 0
			gt 'uni_library', 'start'
		end

		act 'Go back': gt 'uni_library', 'start'
	end

	if lib_debt > 0:
		'You owe an outstanding debt of <<lib_debt>> <b>₽</b> to the library.'
		if pcs_money >= lib_debt:
			act 'Pay your debt':
				pcs_money -= lib_debt
				lib_debt = 0
				gt 'uni_library', 'Pay_debt'			
			end
		else
			act '<font color="red">Pay your debt</font>': '<br><font color="red">You don''t have enough money to pay your debt.</font>'
		end
	end

	if $lib_book_loaned = '' and lib_debt = 0:
		!!There''s currently only code for fantasy novels (Is this still true? I''ve left everything but the fantasy novel out until confirmed)
		!{act 'Borrow a science book':
			*clr & cla
			menu_off = 1
			s_book += 1
			$lib_book_loaned = 'a science book'
			lib_debt = -700
			!!Picture here
			'You find a science book that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'uni_library'
		end
		
		act 'Borrow an adventure novel':
			*clr & cla
			menu_off = 1
			a_book += 1
			$lib_book_loaned = 'an adventure novel'
			lib_debt = -700
			!!Picture here
			'You find an adventure novel that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'uni_library'
		end}
		
		act 'Borrow a fantasy novel':
			*clr & cla
			menu_off = 1
			f_book += 1
			$lib_book_loaned = 'a fantasy novel'
			lib_debt = -700
			!!Picture here
			'You find a fantasy novel that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'uni_library'
		end
		
		!{act 'Borrow a science fiction novel':
			*clr & cla
			menu_off = 1
			sf_book += 1
			$lib_book_loaned = 'a science fiction novel'
			lib_debt = -700
			!!Picture here
			'You find a science fiction novel that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'uni_library'
		end
		
		act 'Borrow a romance novel':
			*clr & cla
			menu_off = 1
			r_book += 1
			$lib_book_loaned = 'a romance novel'
			lib_debt = -700
			!!Picture here
			'You find a fantasy novel that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'uni_library'
		end}
		
		act 'Go back': gt 'uni_library', 'start'
	end
end

if $ARGS[0] = 'kendra':
	*clr & cla
	menu_off = 1
	gs 'npc_relationship', 'modify', 'A82', 'like'
	gs 'exp_gain', 'chrsm', rand(1,2)
	minut += 5
	'<center><img <<$set_imgh>> src="images/locations/city/island/university/classroom/ebony_girl_talk.jpg"></center>'
	'You walk over to her table.'
	if meet_kendra = 1:
		if kendraQW['sub'] < 0:
			'You''re about to take a seat when Kendra glares at you. "I don''t think so, Princess. We''re not friends and I want nothing to do with you. Go sit somewhere else."'
			'You glance around and notice a few other students staring at you, so you move away from her and find a seat by yourself.' 
		elseif kendraQW['sub'] >= 10:
			if npc_rel['A82'] >= 60:
				minut += 10
				'You sit next to Kendra. You talk to her and she even lets you get a few words in, but she mostly treats you like a pet or someone simple, often making condescending comments towards you.'
			elseif npc_rel['A82'] <= 20:
				'You''re about to sit next to Kendra when she glares at you. "We''re not friends. You''re nothing more than my white slave bitch to use and abuse as I see fit. You don''t come over to me in public, <i>ever</i>. Go sit somewhere else."'
				'You glance around and notice a few other students staring at you, so you move away from her and find a seat by yourself.' 
			else
				minut += 10
				'You sit next to Kendra and try to have a conversation with her, but anytime you try and get a word in, she gives you a dirty look until you shut up and let her keep talking.'
			end
		else
			if npc_rel['A82'] >= 60:
				minut += 10
				'You sit next to Kendra. You talk to her and she even lets you get a few words in, but she mostly treats you like a pet or someone simple, often making condescending comments towards you.'
			elseif npc_rel['A82'] <= 20:
				'You''re about to sit next to Kendra when she looks over at you. "I don''t think so, Princess. We''re not friends. You''re nothing more than my toy to be used when and where I want, and now is not the time, so go sit somewhere else."'
				'You glance around and notice a few other students staring at you, so you move away from her.' 
			else
				minut += 10
				'You sit next to Kendra. You try and have a conversation with her, but mostly she talks and you listen. Any time you try and get a word in edgewise she just gives you a dirty look until you shut up and let her keep talking.'
			end
		end
		act 'Leave Kendra be':
			minut += 2
			gt 'uni_library', 'start'
		end
	else
		if hotcat >= 5:
			meet_kendra = 1
			'There''s something about this ebony girl that intrigues you, so you decide to sit next to her. "Hi, I''m <<$pcs_nickname>>."'
			'She eyes you like a pair of shoes she might buy. "I''m Kendra, but you can call me Mistress," she replies in an exotic accent. "If you like, I can train you to become one of my slaves."'
			'You''re taken aback by her comment. "Slaves?"'
			'She smiles. "Yes, I have many sex slaves here, and I can train you to serve me well. If you''re interested, come to my dorm room. It''s on the eighth floor of the east dorm, room 808."'
			'She then ignores you, leaving you to wonder if you should visit her dorm room and see what she was talking about...'
			act 'Leave Kendra be':
				minut += 2
				gt 'uni_library', 'start'
			end
		else
			'There''s something about this ebony girl that intrigues you, so you decide to sit next to her. "Hi, I''m <<$pcs_nickname>>."'
			'"No. Not interested. Maybe if you do something about all of... ''this'', you can try again." Her hand indicates your entire person with languid disinterest.'
			'You''re taken aback by her comment. "What?"'
			'She rolls her eyes, believing your shocked silence to be stupidity. "Just go away."'
			'She then ignores you, leaving you to wonder if she doesn''t find you attractive enough to get her attention. Maybe if you were better looking she would talk to you?'
			act 'Leave her be':
				minut += 2
				gt 'uni_library', 'start'
			end
		end
	end
end

--- uni_library ---------------------------------

