glife/locations/sister

# sister

!!model Megan Vale Valentina Azarov
sisterAge = year - ((npc_dob['A33'] - (npc_dob['A33'] mod 10000)) / 10000)
$sisterLocationTitle = '<center><h1><font color="maroon">Anya</font></h1></center>'
gs 'stat'

*pl $sisterLocationTitle
'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/sister2.jpg"></center>'
*nl
'Your sister Anya is a bit older than you. She is <<sisterAge>> years old. She graduated from high school, but didn''t go to university and now works at the supermarket.'
gs 'dinsister'
dynamic $sischecks

if hour = 8 and week < 6: 
	'God damn it, <<$pcs_nickname>>, because of you I will be late for work.'	
	act '<B> Apologize and move away</B>':gt $loc, $metka
exit
end

if $ARGS[0] = 'gdk':
	!Near the club with friends
	if npc_rel['A33'] < 40:
		'"What do you want? Fuck off!" Anya and her friends laugh and point at you, until you leave them alone.'
       
	elseif sisboypartyQW < 2 and sisboyparty = 2 and sisboyparty_day + 1 = daystart:   
		cla
		'Anya and some of her friends are dressed up organizing themselves before going to a party. Anya sees you and waves you to her.'
			
		act 'Go to the party':gt 'sisterQW','sisboyQW_party'

	elseif sisboypartyQW >= 2 and sisboyparty = 2 and sisboyparty_day + 1 = daystart:
		cla
		'A merry group of friends have gathered for another boozy party at Rex''s.'

		act 'Go to the party':dynamic $party_pre_conditions

	else
		cla
		'Anya sits with some girls and boys, drinking beer. "Hey <<$pcs_nickname>>!" Anya smiles, "Want some beer?"'

		act 'Drink beer':
			cls
			minut += 60
			npc_rel['A33'] += 5
			alko += 3
			cumspclnt = 2
			gs 'cum_cleanup'
			pcs_breath = 0
			gs'stat'

			if AniaFrends >= 1:
				gt'annafrends', 'scene1'
			elseif AniaFrends = 0:
				AniaFrends = 1
				'You meet Anya''s friends. They are all her former classmates. There''s small and nimble Lena, Ira who is constantly confused, a tall athletic guy, whom everyone calls Rex, and a red-haired lanky guy named Roma. After the introductions you sit down with them, drinking beer and chatting with Anya and her friends.'
			end

			act 'Move away':SiSgdk = 0 & gt $loc, $metka
		end
		if sisboyparty = 2 and sisboyparty_day + 1 = daystart and hour = 17 and minut >= 30:act 'Go to the party':gt'sisterQW','sisboyQW_party'
	end

	act '<B>Move away</B>':SiSgdk = 0 & gt $loc, $metka
	exit
end

!Terms of the campaign to the party
$party_pre_conditions ={
	cla
	*clr
	minut += 5
	gs'stat'
	if rex <= 80:
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/party_sister_1.jpg"></center>'
		$sisPartyInvite = '"Hi <<$pcs_nickname>>, we''re going to a party at Rex''s today. Want to come with us?"'

		if mesec > 0:
			*pl $sisPartyInvite
			'"Sorry Anya, I''m not in the mood today, you go without me."'
			'"What, are you on the rag today? You should have told me! Alright, go home and get some rest."'
			act 'Move away':SiSgdk = 0 & gt $loc, $metka

		elseif pcs_mood < 50:
			*pl $sisPartyInvite
			'"Sorry Anya, I''m not in the mood today, you go without me."'
			'"You do look a little pale sis, go home and get some rest."'
			act 'Move away':SiSgdk = 0 & gt $loc, $metka

		elseif alko >= 3:
			'"<<$pcs_nickname>>, how the hell did you get so drunk already? I was going to invite you to a party, but you look like you have already been to one. Go home and sleep it off."'
			act 'Move away':SiSgdk = 0 & gt $loc, $metka

		elseif cumloc[11] = 1 or (cumloc[6] = 1 or cumloc[7] = 1):
			'"My God, you''ll get yourself a reputation! Go home and wash that off, quickly."'
			'You feel a little ashamed that your sister has seen you looking like this in public.'
			act 'Move away':SiSgdk = 0 & gt $loc, $metka

		else
			*pl $sisPartyInvite

			act 'Yes':gt 'sbReksHome','party'

			act 'Decline':
				cla
				*clr
				minut += 5
				sisboyparty = -1
				gs'stat'
				'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/party_sister_1.jpg"></center>'
				*nl
				'"I''d love to, but I have a lot of homework to do. I''m sorry."'
				'"Don''t worry, maybe next time you can come."'
				act 'Move away':SiSgdk = 0 & gt $loc, $metka
		
			end

		end
	end
	
	if rex > 80:
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/reks/reks.jpg"></center>'
		*nl
		if pav_slut >= 50:
			'"Shit, <<$pcs_nickname>> everywhere people say you are a fucking whore. What is this garbage, <<$pcs_nickname>>? I thought we were an item, and things were getting serious, and you''re fucking around?"'
			'"I do not know what came over me, I was not myself, please forgive me, if you can."'
			'"Listen, everything''s OK, but let''s just be friends and forget all that we had. Okay?"'
			'"Okay..."'

			act 'Move away':SiSgdk = 0 & gt $loc, $metka

		elseif mesec > 0 or pcs_mood < 50:
			'"Sorry Rex, sweetie, I''m not feeling too good today, you go without me."'
			'"Sweetie, I do not want to leave you alone, but I need to go with the guys, take care, and do not be sad."'
			'Rex gives you a gentle kiss on your cheek and leaves.'

			act 'Move away':SiSgdk = 0 & gt $loc, $metka

		elseif alko >= 3:
			'"<<$pcs_nickname>>, are you drunk? I wanted to invite you to the party, but you look like you just left a party. Go home and sleep it off."'

			act 'Move away':SiSgdk = 0 & gt $loc, $metka

		elseif cumloc[11] = 1 or (cumloc[6] = 1 or cumloc[7] = 1):
			'"Shit, <<$pcs_nickname>> you are covered in semen. What is this garbage, <<$pcs_nickname>>? I thought we were an item, and things were getting serious, and you''re fucking around?"'
			'"I do not know what came over me, I was not myself, please forgive me, if you can."'
			'"Listen, everything''s OK, but let''s just be friends and forget all that we had. Okay?"'
			'"Okay..."'

			act 'Move away':SiSgdk = 0 & gt $loc, $metka
		else
			'"Baby, let''s go to my place, once again I am hosting a great get together."'
				
			act 'Accept':gt 'sbReksHome','party'
				
			act 'Decline':
				cla
				minut += 5
				sisboyparty = -1
				gs'stat'
				'"Sorry Rex, I have a lot of homework. I''d love to but I don''t want to fail my exams."'
				'"Well, go on then, but next time you definitely come, okay?"'
		
				act 'Move away':SiSgdk = 0 & gt $loc, $metka
			end

		end
	end
}


act '<B>Move away</B>':gt $loc, $metka
if hour >= 7 and hour < 24:

	if npc_rel['A33'] > 65 and mesec > 0 and preg = 0 and tampon = 0 and narkossister = 0:

		act 'Ask for a tampon':
			'You tell your sister that you are menstruating and have no tampons. She looks at you knowingly, brings some of hers and recommends that next time you take care of this in advance.'
			tampon=3
			npc_rel['A33'] -= 15
			minut += 3
			cla 
			act '<B>Move away</B>':gt $loc, $metka
			exit
		end
	end
	
	!!This is to make sure that you have this skill
	if canBraidHair ! 0 and canBraidHair ! 1:
		canBraidHair = 0
	end
	
	
	if canBraidHair = 0 and npc_rel['A33'] > 75 and (pcs_hairlng > 80 and pcs_hairlng <= 800):
		act '"Hey sis, can you teach me how to braid my hair...?"':
			cls
			minut += 1
			'She pauses for a moment and looks at you funny, "You don''t know how to braid your own hair?"'
			'You look down embarrassed, "I usually just go to the salon for them to braid it..."'
			'She laughs and gives you a hug. "<<$pcs_nickname>>, of course I will teach you how to braid your hair, though it make take a bit."'
			act 'Spend an hour with your sister learning how to braid your hair.':
				minut += 60
				canBraidHair = 1
				npc_rel['A33'] += 5
				cls
				'Though you made plenty of mistakes and got your hair in a knot a couple of times, afterwords you feel confident that you can braid your hair on your own.'
				act 'Thank your sister and leave':gt $loc, $metka
			end
			act 'Thank her but say you really actually have to get going':
				cls
				'She shrugs her head and says, "Come back if you want to learn how <<$pcs_nickname>>!"'
				minut += 3
				act 'Thank your sister and leave':gt $loc, $metka
			end
			
		end
	
	
	
	end
	
	
	
	
	
	act 'Chat':
		cls
		minut+=rand(10,15)
		npc_rel['A33'] += 1
		gs'stat'
		*pl $sisterLocationTitle
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/sister2.jpg"></center>'
		if npc_rel['A33'] < 20:'Your relationship with your sister is scandalous.'
		if npc_rel['A33'] >= 20 and npc_rel['A33'] < 40:'Your relationship with your sister is tense.'
		if npc_rel['A33'] >= 40 and npc_rel['A33'] < 60:'You and your sister have a normal relationship.'
		if npc_rel['A33'] >= 60 and npc_rel['A33'] < 80:'You and your sister have a good relationship.'
		if npc_rel['A33'] >= 80:'You have a great relationship with your sister.'
		''
!sisboyparty
!-1 - don''t go to the party
!0 - don''t know about Vecherinka
!1 - knows about the parties
!2 - agreed to go to the party

		if sisboypartyQW >= 2 and sisboyparty = 1:
			if sisboyparty_day = daystart:
				'"Listen, <<$pcs_nickname>>, Rex''s apartment is available tomorrow and he''s having a party, do you want to go?"'
			elseif week + sisboyparty_day - daystart = 4:
				'"Listen, <<$pcs_nickname>>, Rex''s apartment is available on Friday and he''s having a party, do you want to go?"'
			elseif week + sisboyparty_day - daystart = 5:
				'"Listen, <<$pcs_nickname>>, Rex''s apartment is available on Saturday and he''s having a party, do you want to go?"'
			elseif week + sisboyparty_day - daystart = 6:
				'"Listen, <<$pcs_nickname>>, Rex''s apartment is available on Sunday and he''s having a party, do you want to go?"'
			else
				'"Its too late for this weeks party, I find out when they are held on Tuesday morning so you can ask me earlier in the week about the next one."'
				sisboyparty = -1
				act 'Finish':SiSgdk = 0 & gt'sister'
				exit
			end
	
			act 'Yes':
				cls
				minut += 5
				sisboyparty = 2
				gs'stat'
				'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_2.jpg"></center>'
				*nl
				'You agree to go to the party.'
				'"Awesome <<$pcs_nickname>>, it''ll be fun. We will meet at the community center, don''t forget to be there before 18:00, otherwise we will leave without you."'
				'With these words, your sister hugs you and kisses you on the cheek.'
				act 'Finish':SiSgdk = 0 & gt'sister'
			end

			act 'No (study)':
				cls
				minut += 5
				sisboyparty = -1
				gs'stat'
				'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_3.jpg"></center>'
				*nl
				'You turn down the invitation.'
				'"Sorry Anya, I would love to, but I can''t get behind at school. I have homework and books to read, you know what it''s like."'
				act 'Finish':SiSgdk = 0 & gt'sister'
			end

			if bronzebeg > 0 or silverbeg > 0 or goldbeg > 0:
				act 'No (training)':
					cls
					minut += 5
					sisboyparty = -1
					gs'stat'
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_4.jpg"></center>'
					*nl
					'You turn down the invitation.'
					'"I would love to, but I have a competition to prepare for. I have to train. One day I could be a great athlete, not like you lazy bones."'
					act 'Finish':SiSgdk = 0 & gt'sister'
				end
			end

			if pcs_vball >= 40:
				act 'No (volleyball)':
					cls
					minut += 5
					sisboyparty = -1
					gs'stat'
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_5.jpg"></center>'
					*nl
					'You turn down the invitation.'
					'"I can''t, the coach does not allow my to stay out late, and drinking is also prohibited."'
					act 'Finish':SiSgdk = 0 & gt'sister'
				end
			end

			exit
		elseif sisboypartyQW >= 2 and sisboyparty = 2 and (sisboyparty_day ! 0 and sisboyparty_day +2 <= daystart):
			sisboyparty = 1
			'"We missed you at the party, <<$pcs_nickname>>." Anya pouts at you, "I''ll let you know when the next party is and maybe you''ll be able to make it, okay?"'
			'You apologize for missing the party and Anya smiles at you.'
			act '<B>Further</B>':SiSgdk = 0 & gt'sister'
		exit
		end
		act '<B>Further</B>':SiSgdk = 0 & gt'sister'

		if npc_rel['A33'] <20:
			dynamic $d_sister[1]
			exit
		elseif npc_rel['A33'] >= 20 and npc_rel['A33'] < 40:
			dynamic $d_sister[2]
			exit
		elseif npc_rel['A33'] >=40:
			dynamic $d_sister[3]
		end
	end

	if sisterLesb = 2:
		cls
		minut += 5
		gs'stat'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_24.jpg"></center>'
		*nl
		'You''re both embarrassed after what happened that night, and can not look into each other''s eyes, finally Anya speaks with you.'
		'"<<$pcs_nickname>>," with a smile she tells you, "Well, you''re a fool, I thought you liked guys, and I always found it much more pleasant to handle men."'
		'You look at Anya blushing, "Forgive me, I was so worked up, I just could not control myself, I do not know what came over me."'
		'"Well, I do not mind, if you sometimes lose control of yourself." She smiles slyly, You smile at her...'

		sisterLesb = 3
		act 'Finish':SiSgdk = 0 & gt'sister'
		exit
	end

	if npc_QW['A33'] = 0 and npc_rel['A33'] >= 40:
		act 'Ask about her boyfriend':
			cls
			minut += 5
			npc_rel['A33'] += 2
			npc_QW['A33'] = 1
			gs'stat'
			*pl $sisterLocationTitle
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/sister.jpg"></center>'
			'You ask Anya about her boyfriend. She smiles.'
			'"Well, I have a boyfriend. Although nothing serious. He is more of a friend who I have sex with."'
			'"Awesome, now when I think out about it, you simply must introduce me to him!"'
			'"Good sister, we hang out in the evenings at the community center. Meet me there and I''ll introduce you to him."'

			act 'Finish':SiSgdk = 0 & gt'sister'
		end
	elseif npc_QW['A33'] >= 2 and npc_rel['A33'] >= 40 and sisboytrioQW > -1 and sisboytrioDayOtkaz <= daystart and sisboypartyQW < 2:
		act 'Talk about Roma':
			cls
			minut += 5
			sisboyrand = RAND(1,10)
			gs'stat'

	!sisboyparty
	!-1 - don''t go to the party
	!0 - ''t know about Vecherinka
	!1 - knows about the parties
	!2 - agreed to go to the party
			if sisboytrio >= 5 and sisboyparty = 0 and sisboyparty_day ! daystart:
				cls
				minut += 5
				sisboyparty = 1
				sisboyparty_day = daystart
				gs'stat'
				'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_1.jpg"></center>'
				*nl
				'"<<$pcs_nickname>>, one of my friends birthday is tomorrow and he''s having a party. He asked me to invite you."'
				'"Oh, Anya I don''t know, they are your friends and I haven''t got to know the boys, I basically just talked to the girls."'
				'"Come on, he really wants you to go, I think he might like you. So will you come?"'
				act 'Yes':
					cls
					minut += 5
					sisboypartyQW = 1
					sisboyparty = 2
					gs'stat'
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_2.jpg"></center>'
					*nl
					'You agree to go to the birthday party.'
					'"Awesome <<$pcs_nickname>>, it''ll be fun! We will meet at the community center, don''t forget to be there before 18:00, otherwise we will leave without you."'
					'With these words, your sister hugs you and kisses you on the cheek.'
					act 'Finish':SiSgdk = 0 & gt'sister'
				end

				act 'No (study)':
					cls
					minut += 5
					sisboyparty = -1
					gs'stat'
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_3.jpg"></center>'
					*nl
					'You refuse to go to the birthday party.'
					'"Sorry Anya, I would love to, but I can''t get behind at school. I have homework and books to read, you know what it''s like."'
					act 'Finish':SiSgdk = 0 & gt'sister'
				end

				if bronzebeg > 0 or silverbeg > 0 or goldbeg > 0:
					act 'No (training)':
						cls
						minut += 5
						sisboyparty = -1
						gs'stat'
						'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_4.jpg"></center>'
						*nl
						'You refuse to go to the birthday party.'
						'"I would love to, but I have a competition to prepare for. I have to train. One day I could be a great athlete, not like you lazy bones."'
						act 'Finish':SiSgdk = 0 & gt'sister'
					end
				end

				if pcs_vball >= 100:
					act 'No (volleyball)':
						cls
						minut += 5
						sisboyparty = -1
						gs'stat'
						'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/sisboyqwparty_5.jpg"></center>'
						*nl
						'You refuse to go to the birthday party.'
						'"I can''t, the coach does not allow my to stay out late, and drinking is also prohibited."'
						act 'Finish':SiSgdk = 0 & gt'sister'
					end
				end
				exit
			end

			if sisboyrand >= 8 and npc_QW['A33'] = 2 and sisboyday ! daystart:
				*pl $sisterLocationTitle
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_01.jpg"></center>'
				*nl
				'Anya takes a long and hesitant look at you, and eventually decides to ask you.'
				'"<<$pcs_nickname>> could you spend an hour tomorrow after 18:00 going for a walk or something? Roma wants to visit me here and... well, you know what I mean.'
				'Your sister is blushing a little and looks at you with pleading eyes.'

				act 'Of course':
					cls
					minut += 5
					npc_rel['A33'] += 10
					sisThank = 1
					npc_QW['A33'] = 3
					sisboyday = daystart
					gs'stat'

					*pl $sisterLocationTitle
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_03.jpg"></center>'
					*nl
					'"Certainly sister, I understand, I will go for a walk late at night. Only do not be too loud, if Kolka hears you it will blow his tiny little mind."'
					'You and Anya laugh and she joyfully hugs you saying, "You''re the best!"'

					act 'Finish':SiSgdk = 0 & gt'sister'
				end

				act 'No':
					cls
					npc_rel['A33'] -= 10
					minut += 5
					sisboyday = daystart
					gs'stat'

					*pl $sisterLocationTitle
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_04.jpg"></center>'
					*nl
					'"Sorry Anya, I need to study in the evening."'
					'"Fine!" Anya turns away angrily and buries her head in her book.'

					act 'Finish':SiSgdk = 0 & gt'sister'
				end
			elseif sisboyrand >= 8 and (npc_QW['A33'] = 4 or npc_QW['A33'] = 6 or npc_QW['A33'] = 8) and sisboyday ! daystart and sisboyparty = 0:
				*pl $sisterLocationTitle
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_09.jpg"></center>'
				*nl
				'"The last time Roma was here was so good, thank you very much."'
				'"You''re welcome, I''m always very happy to help my beloved sister and to see her happy."'
				'"He would like to come here again tomorrow, do you mind taking another walk for about an hour?"'

				act 'Of course':
					cls
					minut += 5
					npc_rel['A33'] += 10
					sisThank = 1
					if npc_QW['A33'] = 4 or npc_QW['A33'] = 6 or npc_QW['A33'] = 8:npc_QW['A33'] += 1
					sisboyday = daystart
					gs'stat'

					*pl $sisterLocationTitle
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_03.jpg"></center>'
					*nl
					'"Certainly sister, I understand, I will go for a walk late at night. Only do not be too loud, if Kolka hears you it will blow his tiny little mind."'
					'You and Anya laugh and she joyfully hugs you saying, "You''re the best!"'

					act 'Finish':SiSgdk = 0 & gt'sister'
				end

				act 'No':
					cls
					npc_rel['A33'] -= 10
					minut += 5
					sisboyday = daystart
					gs'stat'

					*pl $sisterLocationTitle
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_04.jpg"></center>'
					*nl
					'"Sorry Anya, I need to study in the evening."'
					'"Fine!" Anya turns away angrily, and buries her head in her book.'

					act 'Finish':SiSgdk = 0 & gt'sister'
				end
			elseif sisboyrand >= 8 and npc_QW['A33'] = 9 and sisterLesb >= 4 and sisboytrioQW = 0 and sisboytrio < 5 and sistrioday <= daystart:
				*pl $sisterLocationTitle
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_09.jpg"></center>'
				*nl
				if hour > 16:
					sisboyday = daystart
					$siboyday_text = 'tomorrow'
				else
					sisboyday = daystart - 1
					$siboyday_text = 'this'
				end
				if sisboytrio = 0:
					'"Sister, Roma and I have thought about it a lot and... I do not know how to say this..."'
					'"Well, don''t just leave me hanging. What is it that you want to say to me?"'
					'"Well, hmmm... We want, you to err... join us <<$siboyday_text>> evening."'
				else
					'"Hello <<$pcs_nickname>>! Well, did you like it last time? We had a very good time with Roma."'
					'You do not say anything and just smile slyly watching your sister''s eyes.'
					'"We want to repeat our games <<$siboyday_text>> evening, if you would like to.'
				end

				act 'Agree':
					cls
					sisboytrioQW = 1
					minut += 5
					npc_rel['A33'] += 10
					gs'stat'
					*pl $sisterLocationTitle
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/sex/sisboyqw_36.jpg"></center>'
					*nl
					'You agree to Anya''s indecent proposal.'
					'"Well, aren''t you all liberated? Of course I agree, it will be very interesting."'
					'You hug and kiss with your beloved sister.'
					act 'Finish':SiSgdk = 0 & gt'sister'
				end
				
				act 'Sounds interesting, but can we postpone it?':
					cls
					minut += 5
					sistrioday = daystart + rand(7,14)
					gs'stat'
					*pl $sisterLocationTitle
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/sex/sisboyqw_36.jpg"></center>'
					*nl
					'"Oh, sis! I would be glad to join you, but <<$siboyday_text>> evening is really not good! Could we do it some other day?"'
					'She looks kind of dejected, so you continue to talk to her.'
					'"Really Anya, I am glad to be asked! And I do want to have sex with you two at the same time! But it is really not a good time, and I am the most bummed about it."'
					'Finally she realize that you didn''t reject her idea, and simply the timing is off a little. She smiles at you and then kisses your lips.'
					'"Then later it is, little sis.", she says.'
					act 'Finish':SiSgdk = 0 & gt'sister'
				end

				act 'Decline':
					cls
					sisboytrioQW = -1
					sisboytrioDayOtkaz = daystart + 3
					minut += 5
					npc_rel['A33'] = 0
					npc_QW['A33'] = 2
					sisThank = 0
					gs'stat'
					'<center><img <<$set_imgh>> src="images/characters/city/mikhail/terminal/sisboyqw_37.jpg"></center>'
					*nl
					'You decline your sisters indecent proposal.'
					'"You fucking perverts! No way, you disgusting bitch!'
					'You quarrel with your sister and when you have both shouted yourselves out and tears roll down your cheeks, she turns away from you and does not want to talk any more.'
					act 'Finish':SiSgdk = 0 & gt'sister'
				end
			else
				minut += 10
				npc_rel['A33'] += 2
				talkrand = RAND(0,10)
				gs'stat'

				*pl $sisterLocationTitle
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_05.jpg"></center>'
				*nl
				if talkrand = 0:'You ask your sister about Roma, she is happy talking about him and says how he is good, responsive and courageous.'
				if talkrand = 1:'Anya says, before she met Roma he was with a mean girl, and after ignoring her for a long time he called her,  making Anya jealous and she scolded him.'
				if talkrand = 2:'One day she and Roma were in a movie, and noticed on the back row a girl sucking a guy, and that Roma asked her if she would do the same.'
				if talkrand = 3:'Anya complains that Roma drinks too much beer, does not buy her gifts, and doesn''t pay her enough attention.'
				if talkrand = 4:'Anya says, Roma offered her a threesome with another girl, which she was most offended by and didn''t speak to him for a week afterwards.'
				if talkrand = 5:'Anya blushes as she tells you that Roma sometimes comes to her work and drags her into the back room.'
				if talkrand = 6:'Anya in detail and with enthusiasm tells you about Roma''s magnificent virility, and how if not for this, they would have long since parted.'
				if talkrand = 7:'Anya shares with you a secret, that her favorite position is "cowgirl", even though Roma prefers to do her doggy-style.'
				if talkrand = 8:'You speak with your sister very frankly about sexual things, and she says shyly, she does not like to swallow sperm, but with Roma it''s different, and she is willing to swallow for him.'
				if talkrand = 9:
					if reksLike = 0:
						reksLike = 1
						rex = 50
						rexSisTalk = 0
						rexPark = 0
						rexCar = 0
						'Anya talks for a long time about her and Roma''s friends, and asks you if you want to get to know any of them.'
						'"Well, Rex sounds quite nice... I guess."'
						'Anya smiles, "Hmm... He is a nice guy, but sometimes behaves a bit strange, Rex is obsessed with women''s legs.'
						'There was a case when Rex was driving without a license in his father''s car and gazing at a girl walking on the sidewalk, in stockings and a short skirt. Imagine, he was so carried away, he had not noticed a van ahead sitting at the traffic lights.'
						'He drove straight into it and totalled the car! That''s why we call him Rex, because he stares at legs with his mouth open, teeth on show, wanting to devour them." As she says this, Anya is holding her hands like claws and impersonating a T-Rex growling at your legs.'
					else
						'You ask your sister about Roma, she is happy talking about him and says how he is good, responsive and courageous.'
					end
				end
				if talkrand = 10:'Anya says that Roma likes you and asks if you like him, too.'
				act 'Finish':SiSgdk = 0 & gt'sister'
			end
		end
	end

	if ((sisboyday + 1 = daystart and hour > 18) or sisboyday + 1 < daystart) and sisThank = 1:
		cls
		if npc_QW['A33'] = 9 or npc_QW['A33'] = 7 or npc_QW['A33'] = 5 or npc_QW['A33'] = 3:npc_QW['A33'] = npc_QW['A33'] - 1
		sisboyday = 0
		sisThank = 0
		gs'stat'

		*pl $sisterLocationTitle
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/home/sisboyqw_00.jpg"></center>'
		*nl
		'Merrily Anya runs up to you and wraps her arms around your neck.'
		
		if sisboytrioQW ! 1:
			'"Sister, I adore you! I spent a lovely evening with Roma."'
			'"Yes, I''m glad for you. Enough already, you''ll strangle me."'
			'Anya is happy to let you go, and kisses you on the cheek.'
		else
			'"<<$pcs_nickname>>, I adore you! I really enjoyed our evening with Roma."'
			'"Yes, me too. But pease, not so tight, you''re strangling me."'
			'Anya is bouncing with joy and loosens her grip just enough to kiss you on the cheek.'
			sisboytrioQW = 0
		end
		act 'Finish':SiSgdk = 0 & gt'sister'
	elseif sisboytrioQW = 1 and ((sisboyday + 1 = daystart and hour > 18) or (sisboyday + 1 < daystart)):
		cls
		minut += 1
		npc_rel['A33'] -= 10
		sisboytrioQW = 0
		sisboyday = 0
		gs'stat'

		*pl $sisterLocationTitle
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/sister2.jpg"></center>'
		*nl
		'Anya doesn''t look happy with you.'
		'"You promised to join me and Roma, what happened? Well maybe next time..."'

		act 'Continue':SiSgdk = 0 & gt'sister'
	end

	if SisterKnowMastr > 0 and sisterQW = 0:
		cls
		sisterQW = 1
		gs'stat'
		*pl $sisterLocationTitle
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/sister2.jpg"></center>'
		'Anya looks at you and laughs "Well, <<$pcs_nickname>>, I know what you were up to! I went into the room, and you were playing with yourself!"'

		act 'Move away':SiSgdk = 0 & gt $loc, $metka
	end

	if sisterdialog = 2:
		cls
		cla
		gs'stat'
		*pl $sisterLocationTitle
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/sobir.jpg"></center>'
		'Your sister is busy getting ready for work.'
		'Anya, without even turning around, says, "<<$pcs_nickname>>, no time to talk, I''m already late!"'
		act '<B>Move away</B>':gt $loc, $metka
	end

	!going for a walk
	if sisterdialog = 3:
		cls
		cla
		gs'stat'
		*pl $sisterLocationTitle
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/progulka.jpg"></center>'
		'Your sister is getting herself ready to go out. She admires herself in a mirror and wiggles her ass, trying different poses.'
		'Anya, without even turning to look at you, says: "<<$pcs_nickname>>, If you decide to take a walk, I will be near the club with my friends."'
		act '<B>Move away</B>':gt $loc, $metka
	end

	if npc_rel['A33'] >= 80 and sisterknowslut > 0 and sisterdialog < 2:
		act 'Talk about sex':
			cla
			cls
			gs'stat'
			minut+=rand(10,15)
			pcs_horny += RAND(5,10)
			npc_rel['A33'] += 1
			dynamic $d_sistersexstories[1]
			act '<B>Move away</B>':gt 'sister'
		end
	end

else
	'OK <<$pcs_nickname>>, it''s time for bed.'
end

--- sister ---------------------------------