glife/locations/swamp.qsrc

# swamp

$loc = 'swamp'
$metka = ''
$location_type = 'secluded'

$menu_loc = 'swamp'
$menu_arg = ''
menu_off = 0

new_boletus = 0
new_bilberry = 0
goswamp = 1

gs 'gadukino_event', 'sound'
gs 'stat'

cls

'<center><H4>Swamp</H4></center>'

if month >= 4 and month <= 10:
	if hour >= 6 and hour < 22:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swamp.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swamp_night.jpg"></center>'
	end
else
	if hour >= 8 and hour < 18:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swamp_winter.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swamp_winter_night.jpg"></center>'
	end
end

'You are in the swamp area of the forest.'
'It is considered dangerous to hike here day unless extremely physically fit and should be avoided at night no matter what.'
'But you can find a lot of mushrooms and berries here.'

'There''s a small visible path to a clearing that leads to <a href="exec: gt ''swamp_yard'' ">the hut</a>, used by the hunters.'

if hour >= 6 and hour <= 21 and month >= 6 and month <= 9:
	act 'Walk into the forest':gs 'clothing', 'swamp_clothes', 0 & minut += 30 & gt 'gadforest','4'
end
if hour >= 6 and hour < 21:
	act 'Return to the edge of the forest':gs 'clothing', 'swamp_clothes', 0 & hanters = 0 & minut += 150 & gt 'gadforest','1'
else
	act 'Return to the edge of the forest':gs 'clothing', 'swamp_clothes', 0 & hanters = 0 & gt 'gadforest_event', 'forest_road'
end

if hour >= 6 and hour <= 20 and month >= 6 and month <= 9 and boletus + bilberry < 10 and swamp_day ! daystart:
	act 'Look for mushrooms and berries (0:30)':
		cla
		*clr
		minut += 30
		temp = RAND(1,2)
		swamp_day = daystart
		if goforest < 20:goforest += rand(0,1)
		new_boletus += rand(4,5)
		boletus += new_boletus
		new_bilberry += rand(4,5)
		bilberry += new_bilberry
		pcs_mood += 5
		gs 'stat'

		gs 'gadforest', 'clothes1'

		'You spend half an hour wandering through the woods in search of mushrooms and berries and manage to find <<new_boletus>> kg of mushrooms and <<new_bilberry>> kg of berries.'

		act 'Continue': gt'swamp'
	end
end

--- swamp ---------------------------------