glife/locations/before.qsrc

# before
!Calculating the events at the beginning of round.
!Who protection, clones, etc.
knife = 0
knifeV = 0
BonusAtak = 0
BonusDef = 0
BonusAtakV = 0
BonusDefV = 0
!stunner = 0
!stunnerV = 0
kisamePro = 0

round = round + 1
if tuman > 0:'<font color = green>The battlefield is covered by fog. All the stats go down, it will last for <<tuman>> moves.</font>'
if tumanV > 0:'<font color = red>The battlefield is covered by the fog, you can''t see your enemy. All the stats go down, it will last for <<tumanV>> moves.</font>'
if stun > 0:'<font color = red>You''re still stunned.</font>'
if stunV > 0:'<font color = green><<$boydesc>> is still stunned and unable to move.</font>'

if unmaterialV > 0:
	unmaterialV = unmaterialV - 1
	mannaV = mannaV - 20
end

if unmaterial > 0:
	unmaterial = unmaterial - 1
	pcs_manna = pcs_manna - 20

	'<font color = green>You''re unable to withstand the most <<unmaterial>> moves.</font>'
end

if klon > 0:
	'<font color = green>You have spawned <<klon>> Clones that will protect you in case of an enemy attack.</font>'
end

if poison > 0:
	healthV = healthV - poison
	'<font color = green><<$boydesc>> is poisoned and loses <<poison>> life.</font>'
	poison = poison - 1
end

if poisonV > 0:
	pcs_health = pcs_health - poisonV
	'<font color = red>You are poisoned and lose <<poisonV>> life.</font>'
	poisonV = poisonV - 1
end

if blood > 0:
	healthV = healthV - blood
	'<font color = green><<$boydesc>> loses <<blood>> life from bleeding.</font>'
	blood = blood - 1
	if blood < 0:blood = 0
end

if bloodV > 0:
	pcs_health = pcs_health - bloodV
	'<font color = red>You lose <<bloodV>> life from bleeding.</font>'
	bloodV = bloodV - 1
	if bloodV < 0:bloodV = 0
end

if dospehEnV <= 0 and dospehV > 0:
	dospehEnV = 0
	dospehV = 0
	dospehDefV = 0
	dospehVesV = 0

	'<font color = green>The enemy''s armor is destroyed.</font>'
end

if dospehEn <= 0 and dospeh > 0:
	dospehEn = 0
	dospeh = 0
	dospehDef = 0
	dospehVes = 0

	'<font color = red>Your armor is destroyed.</font>'
end

if initBonusA > 0:initBonusA = 0

--- before ---------------------------------