glife/locations/saunawork

# saunawork
$metka = $ARGS[0]
$loc = $CURLOC
$metkaBroom = $ARGS[0]
$locBroom = $CURLOC
$metkaM = $ARGS[0]
$locM = $CURLOC
saunaYouRoom = 1

if paymamka = 0:paymamka = 300
if workDolg > 0:paymamka = 300
if workDolg <= 0:paymamka = 500

gs 'stat'
'<center><b><font color="maroon">Sauna</font></b></center>'
'<center><img src="images/etogame/sauna1.jpg"></center>'
'On the walls are full of <a href="exec:gt ''mirror'', ''start''">mirrors</a>.'

if saunaWorkNow = 1:
	set saunaWorkNow = 0
	set money -= paymamka
	'Nurse came to you and took you to <<paymamka>> per customer.'
end

if money > 0 and workDolg > 0:workDolg -= money & money = 0
if workDolg > 0:'Your debt is <<workDolg>> rubles'

gs 'stat'

if workDolg <= 0:act 'Leave':gt 'sauna'
if workDolg > 0:act 'Go to your room':gt 'saunaroom'

if hour > 8 and hour < 12 and whorehour ! hour:
	whorehour = hour
	klientrand = rand(0, 100)

	if klientrand >= 80:saunaWorkKlient = 1
end

if hour >= 12 and hour < 16 and whorehour ! hour:
	whorehour = hour
	klientrand = rand(0, 100)

	if klientrand >= 50:saunaWorkKlient = 1
end

if hour >= 16 and hour < 21 and whorehour ! hour:
	whorehour = hour
	klientrand = rand(0, 100)

	if klientrand >= 10:saunaWorkKlient = 1
end

if hour >= 21 and whorehour ! hour:
	whorehour = hour
	saunaWorkKlient = 1
end

if saunaWorkKlient = 1:
	cls
	gs 'stat'
	'<center><img src="images/etogame/saunawhore.jpg"></center>'
	'In the sauna arrived client, girls lined up that would be a customer could choose your favorite.'

	if mop > 1 and hapri = 1 and sweat <= 0 and leghair <= 0 and lobok <= 0:
		whorerand = rand(0, 25)

		if whorerand < vnesh:
			'Client jabbed a finger at you "This one."'

			act 'Go to the sauna with a client':saunaWorkKlient = 0 & gt 'saunawhore'
		else
			'Client examined picky eyes and turned away you chose another girl.'

			act 'Exit':saunaWorkKlient = 0 & gt $curloc
		end
	else
		'Looking at your client immediately turned away and chose another girl.'

		act 'Exit':saunaWorkKlient = 0 & gt $curloc
	end

	exit
end

if vnesh = -10 or SLomka > 0:
	cls
	gs 'stat'
	workDolg += 1500
	'You beckoned nurse. "Hey, come here."'
	'You came up to her and she demanded to bare your hand. You have done the required and she took a syringe with what that rubbish. "Sit still, do a shot now and will bring you into a normal form."'

	act 'Exit':StrongNarkota += 25 & SNarkTimes += 1 & minut += 10 & gt $curloc

	exit
end

act 'Sit on the couch (1:00)':
	cls
	minut += 60
	gs 'stat'
	'<center><img src="images/etogame/saunawork.jpg"></center>'
	'You are within an hour sitting on the couch waiting for customers.'

	act 'Exit':gt $curloc
end

if clenerSauna ! day:
	act 'Clean toilets (1:00)':
		cla
		*clr
		set minut += 60
		set clenerSauna = day
		set manna -= 25
		workDolg -= 100
		set sweat += 3
		'<center><img src="images/etogame/clener2.jpg"></center>'
		'You scrubbed toilets for an hour in the sauna to shine.'

		act 'Exit':gt $curloc
	end
end

if clenerSauna2 ! day:
	act 'Scrubbing floors (1:00)':
		cla
		*clr
		set minut += 60
		set clenerSauna2 = day
		set manna -= 25
		workDolg -= 100
		set sweat += 3
		'<center><img src="images/etogame/clener1.jpg"></center>'
		'You within the hour scrubbed floors mopped to shine.'

		act 'Exit':gt $curloc
	end
end

act 'Take a shower (0:15)':
	cla
	*clr
	set minut += 15
	set sweat = -3
	set horny += 1
	set hapri = 0
	set mop = 1
	dynamic $showerdin

	if frost > 0:frost = 0

	'<center><img src="images/pics/dush.jpg"></center>'
	'You got into the bathroom and turned on the shower. Lathered body and washed off in the shower.'

	act 'Get razor':dynamic $saunabrit

	if horny >= 90:
		act 'Send shower pussy':
			cla
			*clr
			set horny = 0
			set minut += 30
			set mastr += 1
			set orgasm += 1
			set manna += 15
			set willpower += 15
			'<center><img src="images/pics/wash2.jpg"></center>'
			'You sent a shower pussy and tight jet of warm water began to caress you. Soon you will feel like a warm wave covers your entire body and you began to shudder in orgasm.'

			act 'Get out and get dressed':gt $curloc
		end
	end

	if horny >= 40 and hormy < 90:
		act 'Send shower pussy':
			cla
			*clr
			set horny += 5
			set minut += 30
			set manna += 10
			set willpower += 10
			'<center><img src="images/pics/wash2.jpg"></center>'
			'You sent a shower pussy and tight jet of warm water began to caress you. First you were very nice, but after a while, even as it was painful. Excitation of sleep and you stop masturbating.'

			act 'Get out and get dressed':gt $curloc
		end
	end

	act 'Get out and get dressed':gt $curloc
end

$saunabrit = {
	cls
	'You rinsed the razor blade which will be enough for <<stanok>> time.'

	if leghair > 0:
		act 'Shave your legs (0:15)':
			cla
			*clr
			set minut += 15
			set leghair = -5
			set horny += 5
			'<center><img src="images/pics/shave.jpg"></center>'
			'You lathered up and shaved hair with them.'

			act 'Postpone machine':dynamic $saunabrit
		end
	end

	if lobok > 0:
		act 'Shave pubis (0:15)':
			cla
			*clr
			set minut += 15
			set lobok = -5
			set horny += 5
			'<center><img src="images/pics/shave3.jpg"></center>'
			'You lathered pubis, then shaved all the hair from it.'

			act 'Postpone machine':dynamic $saunabrit
		end
	end

	act 'Get out and get dressed':gt $curloc
}

--- saunawork ---------------------------------