# gskver
CLOSE ALL

if $ARGS[0] = 'start':
	*clr & cla
	$loc = 'gskver'
	$metka = 'start'
	$location_type = 'public_outdoors'
	$menu_loc = 'gskver'
	$menu_arg = 'start'
	$locclass = 'park'
	menu_off = 0
	gs 'stat'

	if sound = 0:
		if month >=11 and month <= 12 or month >=1 and month <=3:
			if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/zima.mp3',30
			if hour >= 0 and hour <= 7: PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
		else
			if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street_leto.mp3',30
			if hour >= 0 and hour <= 7:PLAY 'sound/street_night.mp3',30
		end
	end

	if month=3 or month=4 or month=5:
		if hour>=6 and hour<=17:
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.spring.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. Spring has come, melting the worst of the snow. The trees are sprouting new leaves.'
			'There are puddles on the ground everywhere, all remains from the melted snow. A lot of people in the park are having fun with them, trying to jump over them and mocking those that fail. They''re not particularly deep though, and plenty of others just walk through without giving them a second thought.'
			'The park is not particularly crowded, this time of year. Many people think it''s still too cold to spend much time outdoors.'
			*nl
		else
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.spring.night.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. Spring has come, melting the worst of the snow. The trees are sprouting new leaves.'
			'There is no particular reason to visit the park during the night, and as a result it''s largely deserted. In the distance you see one person running through the park, probably using it as a shortcut to go home faster.'
			*nl
		end
	end
	if month=6 or month=7 or month=8:
		if hour>=6 and hour<=19:
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/park/skver.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. At this time of year, it''s one of the primary places in town that locals and tourists enjoy spending their spare time in.'
			'It''s always busy: people are resting, walking, playing and dating to their heart''s desires, enjoying the nice surroundings.'
			*nl
		else
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.summer.night.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. At this time of year, it''s one of the places where locals and tourists enjoy going in their spare time.'
			'However, there is no particular reason to visit the park during the night, and as a result it''s largely deserted. In the distance you see one person running through the park, probably using it as a shortcut to go home faster.'
			*nl
		end
	end
	if month=9 or month=10 or month=11:
		if hour>=6 and hour<=18:
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.autumn.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. Autumn has come, and some of the trees are already shedding their leaves. The leaves that are still on the trees have changed colour, and are a beautiful mix of red and brown.'
			'Everywhere in the park, people are enjoying nature. Some are taking photos of the fallen leaves, kids are playing everywhere, and couples are walking hand-in-hand, simply enjoying each other''s company.'
			*nl
		else
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.autumn.night.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. Autumn has come, and some of the trees are already shedding their leaves.'
			'It gets quite cold at night, and you try to stay active to keep yourself warm. The lone soul you see running across the park is probably trying to get home faster, to warm up with some nice cocoa.'
			*nl
		end
	end
	if month=1 or month=2 or month=12:
		if hour>=7 and hour<=16:
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.winter.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. It''s winter, and the park is quite busy with locals and tourists alike.'
			'There''s snow everywhere, and kids from the whole town have gathered here to make snowmen and enjoy snowball fights. Some of the adults are joining them, happy to play like kids again for just a moment.'
			*nl
		else
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.winter.night.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. It''s winter, and the nights in Pavlovsk are very cold.'
			'As you expected, the park is mostly deserted at this time of day. You occasionally see a wild animal, scrounging for food.'
			*nl
		end
	end

	act 'Walk to the Residential area (0:05)':minut += 5 & gt 'pavResidential'
	act 'Walk to the Commercial area (0:05)':minut += 5 & gt 'pavCommercial'
	act 'Walk to the Old Town (0:10)':minut += 10 & gt 'liam'

	if hour > 8 and hour < 19:'There''s a small <a href="exec:minut += 5 & gt ''gskino''">movie theater</a> in the park. It only has a single screen.'
	'The newly opened cafe <a href="exec:gt''cafe_parco'',''start''">"Del Parco"</a>, with eye-catching facade, lots of tables and a summer terrace. Two paths lead out of the park. One brings you to the <a href="exec:minut += 5 & gt ''pavcommercial''">commercial</a> the other to the <a href="exec:minut += 5 & gt ''pavresidential''">residential</a> area.'
	if ((month > 7 and day > 20) or (month = 9 and day < 16)) and week > 5 and hour > 8 and hour < 20 and alb_father_meeting = 0: 
		'<br>You overhear someone speaking in front of a crowd. The crowd is quite rowdy, with lots of yelling and clapping throughout the <a href="exec: minut += 2 & gt ''gskver'', ''alb_father_meeting_1''">meeting</a>.'
	elseif ((month > 8 and day > 20) or (month = 10 and day < 16)) and week > 5 and hour > 8 and hour < 20 and alb_father_meeting = 1 and alb_father_day < daystart:
		'Once again a large crowd has gathered in the town center. You can hear Albina''s father holding a public <a href="exec: minut += 2 & gt ''gskver'', ''alb_father_meeting_2''">meeting</a>.'
	elseif ((month > 9 and day > 20) or (month = 11 and day < 16)) and week > 5 and hour > 8 and hour < 20 and alb_father_meeting = 2 and alb_father_day < daystart:
		'By this time you''re well aware that it''s Albina''s father that is holding a <a href="exec: minut += 2 & gt ''gskver'', ''alb_father_meeting_3''">meeting</a>, this time though they have erected a big stage.'
	end
	
	*nl
	if $clothingworntype = 'nude': pcs_mood -= 15 & 'You notice passers-by in the park pointing at you as you walk, and overhear one older lady telling her friend: "Look at her... it''s that <<$pcs_lastname>> girl. Youth these days, they have no shame at all!"'

	if GvstreBoy = 1:'You see <a href="exec:numnpc = SkverBoy & gt ''Gnpc''"><<$nameBoyfrend[SkverBoy]>></a> walking across the main square of Pavlovsk Park. He doesn''t look like he''s going anywhere in particular, and seems to just be enjoying his walk.'
	!!if kotovLoveQW > 0 and hour >= 18 and hour < 20 and week < 6 or week >= 6 and kotovLoveQW > 0 and hour >= 9 and hour < 20:'You see <a href="exec:minut += 3 & gt ''kotovEv''">Vitek Kotov</a> sitting on a bench in the park, drinking beer by himself. Judging from the empty bottles near the bench, he''s already had a few.'
	if StoryLine = 1 and SchoolAtestat = 0:
		if (sunWeather = 1 and temper > 0) and (hour >= 18 and hour < 20 and week < 6) or (week >= 6 and hour >= 9 and hour < 20):
			'You see your classmates <a href="exec:minut += 3 & gt ''gopskver''">Vitek, Dan and Vasily</a> sitting on a park bench, drinking beer.'
		end
	end

	if week <= 5 and hour >= 16 and hour < 20 and strelaQW = -2 and fedorKozlovQW <= -10 and FedorOutcast = 0:
		'You can see the <a href="exec:gt ''FedorMisc'', ''Outcast Intro''">train tracks</a> from here.'
	elseif week <= 5 and hour >= 16 and hour < 20 and strelaQW = -2 and fedorKozlovQW <= -10 and FedorOutcast = 1:
		'You can see the train tracks where <a href="exec:gt ''FedorMisc'', ''Outcast''">Fedor</a> spends his time.'
	end

	if rexPark = 1 and rexParkDay = daystart and hour >= 16 and hour < 18:
		'You see Rex walking in the park.'
		act 'Go and see Rex':gt 'reks', 'skver'
	end

	if week >= 6 and hour >= 8 and hour <= 9 and StoryLine = 1: '<a href="exec:gt ''gschool_socialchg1'',''tVanya''">Vanya</a> is out on a light jog and is slowly approaching you.'

	act 'Go for a walk (0:15)':
		if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1', 1

		if StoryLine = 1 and SchoolAtestat = 0 and mey_vika['mey_vika_qw'] > 0 and mey_vika['mey_vika_qw'] < 27 and mey_vika['qw_day'] ! daystart and ((week > 5 and hour >= 8 and hour < 20) or (week < 6 and week mod 2 = 1 and hour > 14)):
			gs 'mey_vika_events', 'park_meet'
			gs 'stat'
		else
			*clr & cla
			minut += 15
			place = 1
			Frend_num = 0
			if MagikDostup ! 1 and rand (1, 4) <= pcs_magik and (hour <=6 or hour >=19): gt 'MagEncounterFairy'
			gt 'placer'
		end
	end

	!! If you already know about the treeCircle here in PavPark, go ahead and show it.
	if tpKnown['PavlovskPark'] = 1:	gs 'treeCircEntry', 'PavlovskPark'

	gs 'parkivent', 'run'

	if hour >= 8 and hour < 22:
		act 'Distribute flyers to earn money (50 <b>₽</b>) (1:00)':
			*clr & cla
			menu_off = 1
			minut += 60
			money += 50
			pcs_mood -= 5
			gs 'stat'
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/shared/park/flaer.jpg"></center>'
			*nl
			'You spend an hour handing out flyers to park visitors, advertising something or another. You get paid 50 <b>₽</b> for your efforts.'

			act 'Continue':gt 'gskver', 'start'
		end
	end

	if mey_vika['mey_vika_qw'] > 0 and mey_vika['mey_vika_qw'] < 27 and mey_vika['qw_day'] ! daystart:
		if hour >= 20 or (week > 5 and hour < 8) or (week < 6 and week mod 2 = 0 and hour < 14) or (week mod 2 = 1 and hour < 18):
			'<br>Vicky and Vanya never are in the park at this time.'
		else
			act 'Look for Vicky and Vanya (0:05)':
				cla
				minut += 5
				gs 'mey_vika_events', 'park_meet'
				gs 'stat'
			end
		end
	end

	if pcs_inhib >= 35 or exhibitionist_lvl > 0:
		act 'Flash your tits (0:05)':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			menu_off = 1
			gs 'flash', 'tits', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'gskver', 'start'
		end
	end

	gs 'kseniyaQW', 'events'

	if exhibitionist_lvl > 1:
		act 'Flash your pussy (0:05)':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			menu_off = 1
			gs 'flash', 'pussy', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'gskver', 'start'
		end
	end

	act 'Sit down on the bench': gt'placer_sex','sitting_park_bench'

	if joint > 0 and jointhigh = 0: act 'Smoke a joint': gs 'drugs', 'joint' & gt $loc, $metka

	if (hour >= 20 or hour < 6) and pcs_sleep <= 40:
		if home_owned[2] = 0 and workPTU <= 2 and HotelRoom < 1:
			!nowhere to live in town
			'It''s quite dark now, and you have no where to stay nearby. Maybe you should try to sleep on a bench?'
			if StoryLine = 1: 'Or try your luck and go to Uncle Shulgin''s Apartment?'
		elseif home_owned[2] = 1 and (hour >= 22 or hour < 6):
			'It''s quite dark outside, and you feel tired. Maybe you should head home.'
		else
			'It''s quite dark now, and you feel tired. Maybe you should try sleeping on a bench?'
		end
		act 'Sleep on a bench': gt'placer_sex','sleeping_park_bench'
	end
end

if $ARGS[0] = 'alb_father_meeting_1':
	cla & *clr
	alb_father_meeting = 1
	alb_father_day = daystart + 2
	minut += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/park/event/meeting/meeting1.jpg"></center>'
	'<i>"First of all, we need to take care of the corruption originating from the police force!!!"</i> the speech is ringing out to the crowd that are cheering on...'
	'You take a closer look to see that is Albina''s father holding the speech. He''s really going hard on the authorities while the crowd is getting more and more rowdy.'
	'<i>"Calm down everyone, don''t take out your anger now, instead go and show them at the ballots how upset you truly are!!!"</i> Albina''s father finishes to cheers from the crowd.'

	act 'Go on with your day': gt 'gskver', 'start'
end

if $ARGS[0] = 'alb_father_meeting_2':
	cla & *clr
	alb_father_meeting = 2
	alb_father_day = daystart + 2
	minut += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/park/event/meeting/meeting2.jpg"></center>'
	'<i>"Don''t believe the ridiculous accusations thrown against me! They''re just trying to smear me!"</i> he''s slamming the speaking booth as he passionately speaks.'
	'The crowd is keeping calm except his most die hard supporters that are yelling profanities against the current administration.'
	'Albina''s father continues on, <i>"I''m just a regular guy, just like the rest of you! My opponents are jealous of my self-made fortune! Why would I be corrupt if I''m already well-off?! No one can pay me off!"</i> he slams the booth again.'
	
	act 'Go on with your day': gt 'gskver', 'start'
end

if $ARGS[0] = 'alb_father_meeting_3':
	cla & *clr
	alb_father_meeting = 3
	alb_father_day = daystart + 2
	minut += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/park/event/meeting/meeting3.jpg"></center>'
	'You walk over to see what the commotion is about and you see Albina''s father speaking to the crowd as usual, the difference this time is that he seems a bit nervous and stutters a lot while speaking to the crowd. He continues on for a couple more minutes and by the end of the speech he''s profoundly sweating.'
	'Just as he''s about to finish you hear him say, <i>And now for some entrainment, my daughter and her dance group and if you look at the right there are some refreshments for you all.</i>'
	'The music starts and the dance group steps out, they''re all wearing really skimpy clothes and directly you can hear the hollering from the men while the females at the gathering are whispering amongst each other that they can''t believe that someone would walk out in those type of outfits...'
	'You stay for a little while and watch the performance and after you get tired of it you move away while the music is still loudly playing in the background.'

	act 'Leave': gt 'gskver', 'start'
end

--- gskver ---------------------------------