glife_ij/locations/street

# street

CLOSE ALL
music_on = 0
$metkaM = $ARGS[0]
$locM = $CURLOC
$metka = $ARGS[0]
$loc = $CURLOC
$location_type = 'public_outdoors'

if sound = 0:
	if month >=11 and month <= 12 or month >=1 and month <=3:
		if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/zima.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
	else
		if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/street_leto.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_night_leto.mp3' & PLAY 'sound/street_night.mp3',30
	end
end

'<center><b>Residential Area<a href="exec:gs ''obj_din'', ''new''">.</a></b></center>'
if month >= 11 or month <= 3:
	if hour >= 8 and hour <= 21:
		'<center><img src="images/locations/city/residential/streetw.jpg"></center>'
	else
		'<center><img src="images/locations/city/residential/streetwn.jpg"></center>'
	end
else
	if hour >= 8 and hour <= 21:
		'<center><img src="images/locations/city/residential/street.jpg"></center>'
	else
		'<center><img src="images/locations/city/residential/street_night.jpg"></center>'
	end
end

!all random events move to [street_events], and display them before show location. by illume
gs'street_event','street' & if streetrand=-1:exit

if (opusk > 0 or gnewQW = 5) and housr > 0:'Near the entrance to where you live there is something written on the wall. It says:<b>"<<$pcs_nickname>> from apartment 69 is a cheap slut!"</b>'

clr
gs 'stat'
palMir = 0
bordysh = 0
housrA = 0
obdysh = 0
tanhouse1 = 0
obMir = 0
houseob = 0
borMir = 0
$onobjsel = 'onobjsel'

if gopdeath = 1 and vsehsdaladay ! daystart:
	over = 6
	gt 'gameover'
	exit
end

housrA = 0

if car > 0 and cardrive = 1:
	cardrive = 1
	'In the parking lot is <a href="exec:GS ''carF'', ''start''">your <<$car>></a>.'
end

if housr = 1:
	act '<b>GO HOME</b>':
		gorand = rand(0, 100)

		if (loh > 0 or gnewQW = 7) and gopdolg > 0 and hour >= 20 and gorand >= 80:
			gt 'gopnew', 'start'
			exit
		end

		if (opusk > 0 or gnewQW = 5) and hour >= 20 and gorand >= 80 and gopopusday ! daystart:
			gt 'gopnew', 'start'
			exit
		end

		gt 'korr'
	end
end

act 'Wait':
	cla
	waiting = input ("How long would you like to wait? (Not more than 120 minutes)")

	if waiting <= 0 or waiting > 120:
		minut += 15
	elseif waiting > 0 and waiting <= 120:
		minut += waiting
	end

	act 'Take a look at the clock':gt curloc
end

gs 'taxi'

if hour >= 8 and hour <= 22:'You can see the <a href="exec:$locM = ''street'' & gt ''kiosk'', ''start''">kiosk</a> selling cigarettes and magazines.'
if Enable_tablemap = 0:
	if katkey = 1:'<a href="exec:gt ''katspalnya'', ''start''">Katies</a> apartment'
	if IrinaQW >= 1:'<a href="exec:gt ''IrinaRoom'', ''start''">Irenes</a> apartment is not far away from yours.'
	if hour >= 16 and hour < 22 and dimaQW > 0:'<a href="exec:gt ''dima'', ''start''">Dimas</a> apartment'
	if klofQW >= 2:'<a href="exec:gt ''klofdomhouse'', ''start''">Joras</a> apartment'
else
	st_count=0 & $show_table=''
	if katkey = 1:gs'show_table','<a href="exec:gt ''katspalnya'', ''start''">Katies</a> apartment','3'
	if IrinaQW >= 1:gs'show_table','<a href="exec:gt ''IrinaRoom'', ''start''">Irenes</a> apartment is not far away from yours.','3'
	if hour >= 16 and hour < 22 and dimaQW > 0:gs'show_table','<a href="exec:gt ''dima'', ''start''">Dimas</a> apartment','3'
	if klofQW >= 2:gs'show_table','<a href="exec:gt ''klofdomhouse'', ''start''">Joras</a> apartment','3'
	if hour >= 10 and hour < 22 and lesbiQW = 1:
		gs'show_table','<a href="exec:gt ''lesbidomhouse'', ''start''">Natalia Petrovnas</a> apartment.'
	elseif lesbiday ! daystart and subdom = 2:
		gs'show_table','<a href="exec:GT ''lesbisubhouse'', ''start''">Your slaves</a> apartment.','3'
	elseif lesbiday ! daystart and hour >= 8 and hour < 22 and lesbiQW >= 2 and lesbiQW < 13:
		gs'show_table','<a href="exec:GT ''lesbidomhouse'', ''start''">Mistress''</a> apartment.','3'
	elseif lesbiday ! daystart and hour >= 8 and hour < 22 and lesbiQW >= 13:
		gs'show_table','<a href="exec:GT ''lesbimistress'', ''start''">Mistress''</a> apartment.','3'
	end
	if st_count > 0 :'<TABLE BORDER=1><<$show_table>></TR></TABLE>'
end

if hour >= 5 and hour <= 23:'The <a href="exec:gt ''metro'', ''start''">Metro</a> Station is within a 5 minute walk from here.'
if hour >= 8 and hour <= 20:'The <a href="exec:gt ''shop'', ''start''">supermarket</a> is not far from here.'
if hour >= 8 and hour <= 20:'The <a href="exec:gt ''poli'', ''start''">clinic</a> is also nearby.'
if hour >= 6 and hour <= 9 and military = 1 and week = 6:'There is a <a href="exec:minut += 60 & gt ''Military'', ''start''">military bus</a> waiting on the other side of the street.'
if hour >= 8 and hour <= 14 and week ! 1:'You could go shopping at the noisy local <a href="exec:gt ''rinok'', ''start''">marketplace</a>.'
if hour >= 8 and hour <= 15 and week < 6:'Near the market is a <a href="exec:gt ''rinok'', ''tailor''">tailor shop</a> where you can get your clothes resized if needed.'
if hour >= 11 and hour < 12 and week > 1 and week < 5 and workKafe = 1:'The side door of the <a href="exec:gt ''kafe'', ''work''">cafe</a> is open, so employees can enter to begin their shift.'
if hour >= 12 and hour <= 22 and week ! 1:'In a side alley, next to the <a href="exec:gt ''kafe'', ''start''">cafe</a>, you can hear the swearing and laughing of some <a href="exec:gt ''gopnew'', ''start''">gopniks</a>.'
if hour > 22 or hour <= 3:'In one of the parking lots you can hear the swearing and laughing of some <a href="exec:gt ''gopnew'', ''start''">gopniks</a>.'
if clener >= 1 and hour >= 7 and hour <= 22:'There''s a small office building where a <a href="exec:gt ''clener'', ''start''">cleaning lady</a> is needed.'


'The city''s large <a href="exec:minut += 20 & gt ''park'', ''start''">central park</a> is about a 20-minute walk away.'
'The city''s only <a href="exec:minut += 40 & gt ''lake'', ''start''">lake</a> is just a 40-minute walk away.'
'24 Hour <a href="exec:$loc = ''street'' & gt ''pharmacy'', ''start''">Pharmacy</a>.'

if Enable_tablemap = 0:
	if hour >= 10 and hour < 22 and lesbiQW = 1:
		'<a href="exec:gt ''lesbidomhouse'', ''start''">Natalia Petrovna''s</a> apartment.'
	elseif lesbiday ! daystart and subdom = 2:
		'<a href="exec:GT ''lesbisubhouse'', ''start''">Your slave''s</a> apartment.'
	elseif lesbiday ! daystart and hour >= 8 and hour < 22 and lesbiQW >= 2 and lesbiQW < 13:
		'<a href="exec:GT ''lesbidomhouse'', ''start''">Mistress''</a> apartment.'
	elseif lesbiday ! daystart and hour >= 8 and hour < 22 and lesbiQW >= 13:
		'<a href="exec:GT ''lesbimistress'', ''start''">Mistress''</a> apartment.'
	end
end

'In the courtyard of one of the apartment buildings, you see several <a href="exec:gt ''trashplace''">trash bins</a>.'

if SNarkPriton > 0:'The <a href="exec:minut += 5 & gt ''narkopriton''">drug house</a> is clearly recognizeable by the syringes and the trash that lies in front of it.'
if hour >= 8 and hour <= 23 or saunaWorkWhore > 0 or workDisk = 2:'<a href="exec:minut += 10 & gt ''sauna''">The Sauna</a> is a 10 minute walk away. Rumors say the sauna is just the front for a brothel.'

--- street ---------------------------------