glife/locations/fit.qsrc

# fit

if $ARGS[0] = 'start':
	*clr & cla
	gs 'shortgs', 'setloc', 'fit', $ARGS[0]
	killvar '$locclass'
	menu_off = 0
	minut += 5
	frost = 0
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Fitness Center</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/desk.jpg"></center>'
	*nl
	'This modern and well staffed fitness center provides all the latest equipment and trainers to help you make the most of them.'
	*nl
	'There is a <a href="exec: gt ''food'', ''watercooler''">drinking fountain</a> near the doors to the bathrooms.'
	*nl
	'At the reception you may buy '+iif(abonement > 0, 'a subscription package', 'an additional subscription package')+' for access to all available facilities.'
	*nl
	if abonement > 0:'Your existing subscription package is valid for <<abonement>> more classes.'
	*nl
	'<b>Classes included in subscription:</b>'
	*nl
	'Running'
	'CrossFit'
	'Aerobics'
	'Weights'
	'Cross Trainer'
	'Tennis'
	'Dancing'
	'Kickboxing'
	'Swimming pool.'
	*nl
	'Sportswear is required for all available classes.'

	act 'Leave': killvar 'epayments' & minut += 5 & gt 'city_center'
	
	if abonement > 0:
		act 'Go to the dressing room': gt 'fit', 'dressing_room'

	elseif money > 100:
		act 'Use the pool (100 <b>₽</b>)':
			money -= 100
			gs 'stat'
			gt 'fit', 'dressing_room'

		end
	end

	!! Pay cash or card - Hooded Silence.

	*nl
	if abonement = 0:
		'How long do you want to subscribe for?'
	else
		'Extend your subscription:'
	end	

	$epayments['method'] = ''
	$epayments['item_variable'] = 'abonement'
	$epayments['description'] = 'lesson subscriptions and facilities access'
	$epayments['loc'] = 'fit'
	$epayments['loc_arg'] = 'start'
	$epayments['banner']= 'locations/city/citycenter/gym/desk.jpg'

	'<center><table width="90%" align="center" width="90%" cellspacing="0" cellpadding="0" valign="top">'	
	if money >= 3000 or karta + bankDebtLimit => 3000:
		'<tr><td> <a href="exec: epayments[''value''] = 3000 & epayments[''quantity''] = 30 & gs ''shortgs'',''payments'' ">3,000<b> ₽</b> for 30 lessons</a></td>'
	end
	if money >= 2250 or karta + bankDebtLimit => 2250:
		'<td> <a href="exec: epayments[''value''] = 2250 & epayments[''quantity''] = 20 & gs ''shortgs'',''payments'' ">2,250<b> ₽</b> for 20 lessons</a></td>'
	end
	if money >= 1500 or karta + bankDebtLimit => 1500:
		'<td><a href="exec: epayments[''value''] = 1500 & epayments[''quantity''] = 10 & gs ''shortgs'',''payments'' ">1,500<b> ₽</b> for 10 lessons</a></td>'
	end
	'</tr></table></center>'

end

if $ARGS[0] = 'dressing_room':
	gs 'shortgs', 'setloc', 'fit', $ARGS[0]
	menu_off = 0
	$sexloc = 'fit'
	$location_type = 'private'
	$locclass = 'changingroom'
	*clr & cla
	gs 'stat'
	'<center><b><font color="maroon">Dressing</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/locker.jpg"></center>'
	'Recruiting girls for local track team, the winners will receive cash prizes.'
	'Attention, visitors to the sports section must wear sports outfits and shoes when using the facilities.'
	*nl
	if abonement > 0:'Your existing subscription package is valid for <<abonement>> more classes.'
	*nl
	if nichTanya['Known'] = 0 and (rand(1,100) <= 20 or nichDebug = 1):
		'In the locker room you notice <a href="exec:gt ''fit'', ''fitgirl''">a cute girl</a>.'
	end

	act 'Exit the locker room':
        if $clothingworntype ! 'nude' and PCloswimwear = 0:
            if Fit['FMR'] = 0 and vidage <= 40 and hotcat >=6 and fame['city_sport'] >=10:
                gt 'fit', 'FMR'
            else
                gt 'fit', 'start'
            end
        else
            cla
            msg'<b><font color = red>You need to get dressed.</font></b>'
            act 'Return': gt 'fit', 'dressing_room'

        end
    end

	if shampoo > 0:
		act 'Take a shower (0:15)':
			cla
			*clr
			menu_off = 1
			minut += 15
			pcs_horny += 1
			pcs_hairbsh = 0
			pcs_makeup = 1
			if pcs_inhib < 15:inhib_exp += rand(1,2)
			dynamic $showerdin
			'<center><video autoplay loop src="images/shared/home/bathroom/dush.mp4"></video></center>'
			'You go into the bathroom and turn on the shower. You lather your body and wash in the shower.'
			if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'

			act 'Get out of the shower':gt 'fit', 'dressing_room'

		end
	else
		'<font color="red">You''ve run out of shampoo and will have to buy some more before you can wash yourself.</font>'
	end

	act 'Use mirror':
		cla
		gt 'mirror', 'start'
	end

	act 'Change outfit':
		cla
		gt 'wardrobe', 'start'
	end

	gs 'wardrobe', 'default_sport_options'

	if PCloswimwear = 1:
		act 'Use the pool': gt 'bass', 'start'
	else
		act 'Change into swimwear': gt 'changingroom', 'view_swim_list'
	end

	if abonement > 0:
		if $clothingworntype = 'danilovich_outfits' and $shoeworntype = 'danilovich':
			act 'Go to the gym':
				cla
				gt 'fit', 'gym'
			end

			act 'Go to the dance studio':
				cla
				gt 'danceclass'
			end

			act 'Go do a crossfit workout':
				cla
				gt 'crossfit_north_box', 'box'
			end
		end

		if begsec = 0:
			act 'Join track team':
				cla
				*clr
				minut += 5
				begsec = 1
				'You signed up for the track team.'

				act 'Leave':gt 'fit', 'dressing_room'

			end
		elseif $clothingworntype = 'danilovich_outfits' and $shoeworntype = 'danilovich' and pcs_stam >= stammax / 5 and pcs_energy >= 20:
			act 'Go to team practice':gt 'beg', 'start'
			if week = 6 and pcs_run >= 20 and run_comp_day ! daystart:
				act '<b>Enter competition race</b>':run_comp_day = daystart & gt 'beg1', 'start'
			end
		elseif $clothingworntype = 'danilovich_outfits' and $shoeworntype = 'danilovich' and pcs_stam >= stammax / 5:
			act 'Go to team practice': '<br><font color="red">You feel too hungry to do this.</font>'
			if week = 6 and pcs_run >= 20 and run_comp_day ! daystart:
				act '<b>Enter competition race</b>': '<br><font color="red">You feel too hungry to do this.</font>'
			end
		elseif $clothingworntype = 'danilovich_outfits' and $shoeworntype = 'danilovich':
			act 'Go to team practice': '<br><font color="red">You are to exhausted to do this. Recover your stamina before trying to train.</font>'
			if week = 6 and pcs_run >= 20 and run_comp_day ! daystart:
				act '<b>Enter competition race</b>': '<br><font color="red">You are to exhausted to do this. Recover your stamina before entering the race.</font>'
			end
		end
	end
	
	if deodorant > 0 and deodorant_on = 0:
		'Your deodorant will last you for <b><<deodorant>></b> more '+iif(deodorant = 1, 'application.', 'applications.')
		act 'Apply deodorant (0:01)':
			*clr & cla
			menu_off = 1
			minut += 1
			deodorant -= 1
			gs 'sweat', 'deo'
			iif(func('body_din','pregnancyVisibility') = 1, '<center><img <<$set_imgh>> src="images/shared/home/bathroom/deodorant_preg.jpg"></center>', '<center><img <<$set_imgh>> src="images/shared/home/bathroom/deodorant.jpg"></center>')
			'You apply deodorant to your armpits. It will keep you feeling fresh and clean for longer.'
			act 'Continue': menu_off = 0 & gt $loc, $loc_arg
		end
	end
	dynamic $tampon
end

if $ARGS[0] = 'fitgirl':
	menu_off = 1
	'<center><img <<$set_imgh>> src="images/characters/city/tanya/gym/idle0.jpg"></center>'
	'The girl notices you looking and returns the smile. She undresses and taking some toiletries goes into the shower.'

	act 'Turn away':gt 'fit', 'dressing_room'

	act 'Follow her':
		*clr & cla
		pcs_hairbsh = 0
		pcs_makeup = 1
		noShampoo = 1
		dynamic $showerdin
		shovertania += 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/city/tanya/gym/shower0.jpg"></center>'
		'There''s no one in the shower, except this girl. The girl looks around and seeing you smiles again then turns away.'

		act 'Leave the shower':gt 'fit', 'dressing_room'

		gs 'willpower', 'misc', 'force'
		if will_cost <= pcs_willpwr:
			act 'Molest her (<<will_cost>> Willpower)':
				*clr & cla
				gs 'willpower', 'pay', 'self'
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/characters/city/tanya/gym/shower_mol0.jpg"></center>'
				'You walk up to the girl and gently place one hand on her right breast. She turns to face you.'

				gs 'arousal', 'foreplay', 5, 'dom', 'lesbian'
				gs 'stat'

				if pcs_apprnc < 80:
					'The girl pushes you off, and shouts something very rude about you and each and everyone of your relatives, you run out to the locker room.'

					act 'Go':gt 'fit', 'dressing_room'

				elseif pcs_apprnc >= 80:
					'The girl quickly turns around. She looks a little bit puzzled as she realizes that it was you who grabbed her. She probably expected to see a guy and isn''t sure what to do.'

					act 'Take advantage of the confusion':
						cla
						*clr
						gs 'clothing', 'strip_all'

						'<center><img <<$set_imgh>> src="images/characters/city/tanya/gym/shower_mol1.jpg"></center>'
						'While she is trying to understand what is happening you begin fondling her sex with your fingers, and then her hand strokes your ass.'

						gs 'arousal', 'foreplay', 10, 'dom', 'lesbian'
						gs 'stat'

						act 'Further': gt 'fit', 'tanyaIntroduction'
					end

					act 'Wait for her reaction':
						*clr & cla
						gs 'stat'

						if pcs_apprnc < 100:
							gs 'arousal', 'end'
							'The girl smiles at you, but removes your hand and leaves, blowing you a kiss.'

							act 'Continue':gt 'fit', 'dressing_room'

						elseif pcs_apprnc >= 100:
							cla
							*clr
							gs 'clothing', 'strip_all'
							'<center><img <<$set_imgh>> src="images/characters/city/tanya/gym/shower_mol2.jpg"></center>'
							'The girl presses up to you even stronger and kisses your lips.'

							gs 'arousal', 'kiss', 5, 'dom', 'lesbian'
							gs 'stat'

							act 'Further':
								gt 'fit', 'tanyaIntroduction'
							end
						end
					end
				end
			end
		else
			act 'Molest her (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	end
end

if $ARGS[0] = 'tanyaIntroduction':
	'<center><img <<$set_imgh>> src="images/characters/city/tanya/gym/shower1.jpg"></center>'
	'Just as the both of you are about to get more intimate a group of middleaged women enters the showers. They haven''t noticed you yet. The girl next to you is clearly afraid of being spotted in the shower with you and takes her first opportunity to quietely escape to the dressing room.'
	'You follow her only a few seconds later. She has already begun to dress herself.'

	if $pantyworntype = 'none': gs 'underwear', 'wear'
	gs 'panties', 'dispose'
	gs 'clothing', 'wear_last_worn'
	nichTanya['Relationship'] = 1
	nichTanya['RelationshipState'] = 10
	nichTanya['Known'] = 1
	npc_rel['A218'] += 5
	nichTanya['FuckLast'] = daystart
	gs 'arousal', 'end'
	gs 'stat'
	'"You can at least tell me your name, seeing as you did not even have the decency to do so before you assaulted me." The girl says, catching her breath. Despite her words she doesn''t seem to be angry with you.'
	'"I am <<$pcs_nickname>>, and how can I assault someone so keen?" You ask trying to find your panties.'
	'"Looking for this?" asks the girl twirling your panties on her finger.'
	'"Yes, can I have them back, please?" you ask, while holding out your hand.'
	'"Nope. You seduced me. I have never been with a girl before and I think I earned this as a memento." With these words, Tanya slips your panties in her pocket.'
	'"My name is Tanya by the way. I live only a short distance from here with my parents. You might come over if you like. Usually I''m home in the late afternoon. We could continue were we left off." she winks at you and leaves.'
	'<i>You can now visit Tanya at her parents home in the Downtown area once a day after 16:00.</i>'
	act 'Back':gt 'fit', 'dressing_room'

end

if $ARGS[0] = 'gym':
	*clr & cla
	killvar '$locclass'
	menu_off = 1
	minut += 5
	sportzalrand = RAND(0,20)
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Fitness Center</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/schedule.jpg"></center>'
	'In the fitness center there are a lot of different classes and clubs, designed to improve physical development.'
	*nl
	if abonement > 0:'Your existing subscription package is valid for <<abonement>> more classes.'

	if mid($start_type,1,2) = 'sg':
		if hour >= 10 and hour < 12 and week = 7 and centr = 1: 'In the hall you see <a href="exec:gt ''VolleyTrenCentr''">Mikhail Nikolaevich</a> talking with a strange man.'
		if hour >= 10 and hour < 12 and week = 7 and centr = 2 and ricewine < 2: 'In the hall you see <a href="exec:gt ''VolleyTrenCentr''">Guang</a>'
	end

	gs 'fit', 'exercise_end'

	if pcs_energy >= 15 or pcs_stam >= stammax / 5:
		act 'Aerobics (Burn fat)':
			cla
			*clr
			abonement -= 1
			gs 'exercise', 'tier1', 30, 'vital', 'react'
			fat -= rand(0,4)
			if pcs_inhib < 30:inhib_exp += rand(1,2)

			'<center><img <<$set_imgh>> src="images/pc/activities/exercises/gym/fit11.jpg"></center>'
			'You do very vigorous exercises to the music, and burn some fat.'

			if pcs_stam < 30:
				*nl
				'You are too tired to do any more exercise and will have to rest and regain some stamina.'
				gs 'fit', 'exercise_end'
			else
				act'Continue': gt 'fit', 'gym'
			end
		end

		act 'Light weights (Build strength)':
			cla
			*clr
			abonement -= 1
			gs 'exercise', 'tier3', 30, 'stren'
			if pcs_inhib < 30:inhib_exp += rand(1,2)
			'<center><img <<$set_imgh>> src="images/pc/activities/exercises/gym/fit2.jpg"></center>'
			'You pump dumbells doing reps at fairly low total weight, building strength.'

			if pcs_stam < 30:
				*nl
				'You are too tired to do any more exercise and will have to rest and regain some stamina.'
				gs 'fit', 'exercise_end'
			else
				act'Continue': gt 'fit', 'gym'
			end
		end

		act 'Heavy weights (Build muscle <font color=red>This can lead to extreme strength at a cost to appearance</font>)':
			cla
			*clr
			abonement -= 1
			gs 'exercise', 'tier3', 30, 'stren_plus'
			if pcs_inhib < 30:inhib_exp += rand(1,2)
			'<center><img <<$set_imgh>> src="images/pc/activities/exercises/gym/fit6.jpg"></center>'
			'You pump the heavy weights doing low reps with high total weight, building muscle.'

			if pcs_stam < 30:
				*nl
				'You are too tired to do any more exercise and will have to rest and regain some stamina.'
				gs 'fit', 'exercise_end'
			else
				act'Continue': gt 'fit', 'gym'
			end
		end

		act 'Squats (Tone your butt)':
			cla
			*clr
			abonement -= 1
			gs 'exercise', 'tier2', 30, 'stren', 'butt_tr'
			if pcs_inhib < 30:inhib_exp += rand(1,2)
			'<center><img <<$set_imgh>> src="images/pc/activities/exercises/butt_gym.jpg"></center>'
			'You do various squats to tone your thighs and glutes, it also helps with building strength.'

			if pcs_stam < 30:
				*nl
				'You are too tired to do any more exercise and will have to rest and regain some stamina.'
				gs 'fit', 'exercise_end'
			else
				act'Continue': gt 'fit', 'gym'
			end
		end

		act 'Cross trainer (endurance)':
			cla & *clr
			abonement -= 1
			gs 'exercise', 'tier3', 30, 'vital'
			if pcs_inhib < 30:inhib_exp += rand(1,2)
			'<center><img <<$set_imgh>> src="images/pc/activities/exercises/gym/fit3.jpg"></center>'
			'You spend a half hour doing reps on the cross trainer developing your endurance.'

			if pcs_stam < 30:
				*nl
				'You are too tired to do any more exercise and will have to rest and regain some stamina.'
				gs 'fit', 'exercise_end'
			else
				act'Continue': gt 'fit', 'gym'
			end
		end

		act 'Tennis practice (agility)':
			cla
			*clr
			abonement -= 1
			gs 'exercise', 'tier3', 30, 'agil'
			if pcs_inhib < 30:inhib_exp += rand(1,2)
			'<center><img <<$set_imgh>> src="images/pc/activities/exercises/gym/fit4.jpg"></center>'
			'You run tennis exercises, concentrating on defensive drills.'

			if pcs_stam < 30:
				*nl
				'You are too tired to do any more exercise and will have to rest and regain some stamina.'
				gs 'fit', 'exercise_end'
			else
				act'Continue': gt 'fit', 'gym'
			end
		end

		act 'Tennis practice (reactions)':
			cla
			*clr
			abonement -= 1
			gs 'exercise', 'tier3', 30, 'react'
			if pcs_inhib < 30:inhib_exp += rand(1,2)
			'<center><img <<$set_imgh>> src="images/pc/activities/exercises/gym/fit4.jpg"></center>'
			'You run tennis exercises, concentrating on court reactions.'

			if pcs_stam < 30:
				*nl
				'You are too tired to do any more exercise and will have to rest and regain some stamina.'
				gs 'fit', 'exercise_end'
			else
				act'Continue': gt 'fit', 'gym'
			end
		end
		act 'Go to the kickboxing gym':gt 'fit', 'kickboxing'
	elseif pcs_energy >= 15:
		act 'Aerobics (Burn fat)': '<br><font color="red">You are to exhausted to do this. Recover your stamina before trying to train.</font>'
		act 'Free weights (Build muscle)': '<br><font color="red">You are to exhausted to do this. Recover your stamina before trying to train.</font>'
		act 'Cross trainer (endurance)': '<br><font color="red">YYou are to exhausted to do this. Recover your stamina before trying to train.</font>'
		act 'Tennis practice (agility)': '<br><font color="red">You are to exhausted to do this. Recover your stamina before trying to train.</font>'
		act 'Tennis practice (reactions)': '<br><font color="red">You are to exhausted to do this. Recover your stamina before trying to train.</font>'
		act 'Go to the kickboxing gym': '<br><font color="red">You are to exhausted to do this. Recover your stamina before trying to train.</font>'
	else
		act 'Aerobics (Burn fat)': '<br><font color="red">You feel too hungry to do this.</font>'
		act 'Free weights (Build muscle)': '<br><font color="red">You feel too hungry to do this.</font>'
		act 'Cross trainer (endurance)': '<br><font color="red">You feel too hungry to do this.</font>'
		act 'Tennis practice (agility)': '<br><font color="red">You feel too hungry to do this.</font>'
		act 'Tennis practice (reactions)': '<br><font color="red">You feel too hungry to do this.</font>'
		act 'Go to the kickboxing gym': '<br><font color="red">You feel too hungry to do this.</font>'
	end
end

if $ARGS[0] = 'exercise_end':
	menu_off = 1
	RESULT = rand(0, 19)

	act 'Leave':
		if RESULT = 0:
			cla
			*clr
			'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/sex/zal1.jpg"></center>'
			'You see a nice guy on the weight machine.'

			act 'Continue':gt 'fit', 'dressing_room'

			act 'Flirt':
				cla
				*clr
				guy += 1
				gs 'npcgeneratec', 0, 'guy from the gym', rand(19,45)
				gs 'boyStat', $npclastgenerated
				samecount = 1
				picrand = 17
				'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/sex/zal2.jpg"></center>'
				'You go up to the guy lying on the machine, squat and start stroking his cock through his pants. The man rises and kisses you on the lips, then lowers his pants releasing his impressive size dick.'

				gs 'arousal', 'foreplay', 10, 'dom'
				gs 'stat'

				act 'Suck':gt 'sex', 'minet'
			end
		elseif RESULT = 1:
			cla
			*clr
			'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/sex/zal3.jpg"></center>'
			'As you finish training, a guy sits behind, caresses your breasts and kisses your ear, sucking the lobe.'
			gs 'willpower', 'misc', 'self', 'medium'
			if will_cost <= pcs_willpwr:
				act 'Hit him in the balls (<<will_cost>> Willpower)':
					*clr & cla
					gs 'willpower', 'pay', 'self'
					gs 'stat'
					gt 'fit', 'dressing_room'

					'Event text'
					
					act 'Next action': gt 'farawayistan'
				end
			else
				act 'Hit him in the balls (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end	

			act 'Enjoy':
				cla
				*clr
				guy += 1
				gs 'npcgeneratec', 0, 'guy from the gym', rand(19,45)
				gs 'boyStat', $npclastgenerated
				picrand = 18
				'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/sex/zal4.jpg"></center>'
				'Guy gets up and moves around to face you, he pulls out his cock and lays it on your chest, eventually moving the head to your mouth.'

				gs 'arousal', 'foreplay', 15, 'sub'
				gs 'stat'

				act 'Suck':gt 'sex', 'minet'
			end
		elseif RESULT = 2:
			cla
			'As you finish training, a fit girl offers to play a little squash with her as she waits for her boyfriend to came.'

			act 'Refuse':gt 'fit', 'dressing_room'

			act 'Agree':
				cla
				*clr
				picrand = 15
				'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/sex/zal5.jpg"></center>'
				'You have fun playing with the girl, neither of you are any good, but it just amuses you. After some time, it appears as a man and looking at your clumsy attempts and offers to show you how to play correctly.'
				'He stands just behind you and puts one hand on your hand, guiding your racket and showing you how to strike the ball. The other hand starts stroking your hips gradually approaching your crotch.'
				'You feel his cock resting against your back and looking at the girl, you know that she understands what is going on and that the man is her boyfriend.'

				act 'Escape from these perverts':gt 'fit', 'dressing_room'
				act 'Enjoy':
					guy += 1
					girl += 1
					gs 'npcgeneratec', 0, 'guy from the gym', rand(19,45)
					gs 'boyStat', $npclastgenerated
					gt 'podrsex', 'suck'
					gs 'arousal', 'foreplay', 15, 'group', 'lesbian'
					gs 'stat'
				end
			end
		elseif RESULT = 3:
			cla
			*clr
			'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/sex/zal6.jpg"></center>'
			'You train near to a girl and engage in conversation, two guys obviously take you for girlfriends and try to chat you up.'

			act 'Continue':gt 'fit', 'dressing_room'

			act 'Flirt back':
				cla
				*clr
				picrand = 12
				'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/sex/zal7.jpg"></center>'
				'You flirt with a guy, and notice that he is getting very excited and constantly glancing behind you. Turning, you see that the girl is already on her haunches and sucking the second guy with gusto.'

				act 'Leave':gt 'fit', 'dressing_room'
				act 'Suck':
					guy += 2
					girl += 1
					gang += 1
					gs 'npcgeneratec', 0, 'guy from the gym', rand(19,45)
					gs 'boyStat', $npclastgenerated
					gs 'npcgeneratec', 0, 'guy from the gym', rand(19,45)
					gs 'boyStat', $npclastgenerated, 'a'
					gs 'arousal', 'bj', 15, 'group', 'lesbian'
					gs 'stat'
					gt 'sexdvanadva', 'var'

				end
			end
		else
			gt 'fit', 'dressing_room'
		end
	end
end

if $ARGS[0] = 'kickboxing':
	cla
	*clr
	killvar '$locclass'
	menu_off = 1
	minut += 5
	gs 'stat'
	gs 'razrKik'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Kickboxing Gym</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/kik.jpg"></center>'
	'This section is dominated by the ring itself, square like a boxing ring and the only equipment that can''t be easily moved.'
	'Around it there are various punching bags of different sizes and weights and a couple of coaches with practice pads.'
	'You can try your luck in a fight here on Saturdays but safety concerns limit everyone to a maximum of 1 bout per week.'

	act 'Return to dressing room': gt 'fit', 'dressing_room'

	act 'Work on your jabs':
		cla
		*clr
		abonement -= 1
		gs 'exercise', 'tier3', 30, 'jab', 'react'
		if pcs_inhib < 30:inhib_exp += rand(1,2)
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/kik1.jpg"></center>'
		'You practice your jabs on the speed bag and double-end bag, straight punches with a step forward. These strikes are not so powerful, but they are fast.'

		act 'Leave':gt 'fit', 'kickboxing'
	end

	act 'Work on your heavy punches':
		cla
		*clr
		abonement -= 1
		gs 'exercise', 'tier3', 30, 'stren', 'punch'
		if pcs_inhib < 30:inhib_exp += rand(1,2)
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/kik1.jpg"></center>'
		'You practice your power punches on the heavy bag. These are high impact and powerful, but they are hard to get to their target.'

		act 'Leave':gt 'fit', 'kickboxing'
	end

	act 'Work on your kicking':
		cla
		*clr
		abonement -= 1
		gs 'exercise', 'tier3', 30, 'stren', 'kick'
		if pcs_inhib < 30:inhib_exp += rand(1,2)
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/kik1.jpg"></center>'
		'You practice your powerful kicks on a kickboxing bag. These impacts are very powerful and able to cut down an opponant, but are very difficult to hit with.'

		act 'Leave':gt 'fit', 'kickboxing'
	end

	act 'Work on defence':
		cla
		*clr
		abonement -= 1
		gs 'exercise', 'tier3', 30, 'def', 'agil'
		if pcs_inhib < 30:inhib_exp += rand(1,2)
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/kik1.jpg"></center>'
		'You practice your defense movements.'

		act 'Leave':gt 'fit', 'kickboxing'
	end

	act 'Sparring (training bout in the ring)':
		cla
		*clr
		'You need to choose a partner for sparring'
		if pcs_inhib < 30:inhib_exp += rand(1,2)
		act 'Pick a random partner':
			abonement -= 1
			pcs_mood += 2
			gs 'exercise', 'tier3', 30, 'jab', 'punch', 'kick', 'def'
			pointKik = 0
			pointKikV = 0
			round = 1
			minround = 0

			gs 'npcgeneratec', 0, 'sparring partner', rand(19,45)
			gs 'boyStat', $npclastgenerated
			strenV = rand(10, 20)
			speedV = rand(10, 20)
			agilV = rand(10, 20)
			reactV = rand(10, 20)
			vitalV = rand(10, 20)
			intelV = 10
			willV = 10
			!!skills
			JabV = rand(5, 20)
			PunchV = rand(5, 20)
			KikV = rand(5, 20)
			KikDefV = rand(5, 20)
			!!parameters
			healthV = vitalV * 10 + strenV * 5
			formula = 3
			sparing = 1
			gt 'kikbox', 'start'
		end
	end

	if week = 6 and kickbox['amateur_fight_day'] ! daystart:
		'You can take part in an amateur fight.'

		act 'Amateur fight':
			kickbox['amateur_fight_day'] = daystart
			pcs_mood += 2
			gs 'exercise', 'tier3', 30, 'jab', 'punch', 'kick', 'def'
			pointKik = 0
			pointKikV = 0
			round = 1
			minround = 0

			kickbox['opponent'] = kickbox['sash'] + rand(0, 1)

			if kickbox['opponent'] = 0:
				gs 'npcgeneratec', 0, 'Useless rival', rand(19,45)
				gs 'boyStat', $npclastgenerated
				strenV = rand(10, 20)
				speedV = rand(10, 20)
				agilV = rand(10, 20)
				reactV = rand(10, 20)
				vitalV = rand(10, 20)
				intelV = 10
				willV = 10
				!!skills
				JabV = rand(10, 30)
				PunchV = rand(10, 30)
				KikV = rand(10, 30)
				KikDefV = rand(10, 30)
				!!parameters
				healthV = vitalV * 10 + strenV * 5
				formula = 3
				kickbox['amateur'] = 1
			elseif kickbox['opponent'] = 1:
				gs 'npcgeneratec', 0, '3rd class rival', rand(19,45)
				gs 'boyStat', $npclastgenerated
				strenV = rand(15, 25)
				speedV = rand(15, 25)
				agilV = rand(15, 25)
				reactV = rand(15, 25)
				vitalV = rand(15, 25)
				intelV = 10
				willV = 10
				!!skills
				JabV = rand(15, 35)
				PunchV = rand(15, 35)
				KikV = rand(15, 35)
				KikDefV = rand(15, 35)
				!!parameters
				healthV = vitalV * 10 + strenV * 5
				formula = 3
				kickbox['amateur'] = 1
			elseif kickbox['opponent'] = 2:
				gs 'npcgeneratec', 0, '2rd class rival', rand(19,45)
				gs 'boyStat', $npclastgenerated
				strenV = rand(20, 30)
				speedV = rand(20, 30)
				agilV = rand(20, 30)
				reactV = rand(20, 30)
				vitalV = rand(20, 30)
				intelV = 10
				willV = 10
				!!skills
				JabV = rand(30, 50)
				PunchV = rand(30, 50)
				KikV = rand(30, 50)
				KikDefV = rand(30, 50)
				!!parameters
				healthV = vitalV * 10 + strenV * 5
				formula = 3
				kickbox['amateur'] = 1
			elseif kickbox['opponent'] = 3:
				gs 'npcgeneratec', 0, '1st class rival', rand(19,45)
				gs 'boyStat', $npclastgenerated
				strenV = rand(30, 40)
				speedV = rand(30, 40)
				agilV = rand(30, 40)
				reactV = rand(30, 40)
				vitalV = rand(30, 40)
				intelV = 10
				willV = 10
				!!skills
				JabV = rand(40, 60)
				PunchV = rand(40, 60)
				KikV = rand(40, 60)
				KikDefV = rand(40, 60)
				!!parameters
				healthV = vitalV * 10 + strenV * 5
				formula = 3
				kickbox['amateur'] = 1
			elseif kickbox['opponent'] = 4:
				gs 'npcgeneratec', 0, 'Excellent rival', rand(19,45)
				gs 'boyStat', $npclastgenerated
				strenV = rand(40, 60)
				speedV = rand(40, 60)
				agilV = rand(40, 60)
				reactV = rand(40, 60)
				vitalV = rand(40, 60)
				intelV = 10
				willV = 10
				!!skills
				JabV = rand(60, 80)
				PunchV = rand(60, 80)
				KikV = rand(60, 80)
				KikDefV = rand(60, 80)
				!!parameters
				healthV = vitalV * 10 + strenV * 5
				formula = 3
				kickbox['amateur'] = 1
			elseif kickbox['opponent'] >= 5:
				gs 'npcgeneratec', 0, 'Best rival in the gym', rand(19,45)
				gs 'boyStat', $npclastgenerated
				strenV = rand(60, 100)
				speedV = rand(60, 100)
				agilV = rand(60, 100)
				reactV = rand(60, 100)
				vitalV = rand(60, 100)
				intelV = 10
				willV = 10
				!!skills
				JabV = rand(80, 110)
				PunchV = rand(80, 110)
				KikV = rand(80, 110)
				KikDefV = rand(80, 110)
				!!parameters
				healthV = vitalV * 10 + strenV * 5
				formula = 3
				kickbox['amateur'] = 1
			end

			gt 'kikbox', 'start'
		end
	end
end

if $ARGS[0] = 'FMR':    
    *clr & cla
	killvar '$locclass'
    menu_off = 0
    minut += 5
    Fit['FMR'] = 1
    gs 'stat'
    '<center><b><font color="maroon">Photographer</font></b></center>'
    '<center><img <<$set_imgh>> src="images/locations/city/citycenter/photo/fotograph.jpg"></center>'
	if model['status'] = 1:
		'"Hey! <<$pcs_nickname>>!"'
		'Waiting for you, there is a man with several cameras hanging from his neck. You remember him, as one of Aphrodite''s photographers. Now that you think about it, he has been hanging around some of the sports events, you have participated.'
		'"<<$pcs_nickname>>, the agency has sent me to tell you, that our sponsors want to give you an opportunity as a fitness model. Congratulations! You are getting famous!"'
		'You smile, at the sudden good news. The fitness jobs in the agency are paid based not only on your modeling cache but taking into consideration your relative sports fame and bodybuild. Good job!'
		'"Congratulations <<$pcs_nickname>>! you have earned it!"'
		'Saying this, he turns around, and after waving a final goodbye, he leaves.'
		act 'Leave':gt 'fit', 'start'
	else
		'Waiting for you, there is a man with several cameras hanging from his neck. You vaguely remember him, hanging around some of the sports events, you have participated in. He smiles and quickly takes your hands in a handshake.'
		'"<<$pcs_lastname>> Isn''t it? I''m here to make you a proposal. Don''t be afraid! Not that kind of "proposal". A serious... business... career-oriented... proposal. Tell me... would you consider becoming a model?"'
		'You blink, utterly taken by the sudden verbal barrage... What has he said? You a model?! You have the looks, and it''s not that weird for a woman in the sports career to be offered a job in the model business, but, are you going to trust this stranger? Sensing your hesitation, the man pushes a business card into your hands, before continuing.'
		'"Don''t worry. You don''t need to answer me right now, investigate, ask around if you want, and when you''ve made your decision. Come to see us. If you pass some basic tests, you can initiate a new exciting career."'
		'Saying this, the man turns around, and after waving goodbye, he leaves. On the card, the name "Aphrodite Photography" can be read with and attached are directions. You remember seeing that name around the city center. Maybe you could go and take a look?'
		act 'Leave':gt 'fit', 'start'
	end
end

--- fit ---------------------------------