glife/locations/traits.qsrc

# traits

if $ARGS[0] = 'menu':
	*clr & cla
	gs 'obj_din', 'chartabs'
	'<center><h1>Traits</h1></center>'
	'<center><table cellspacing="0" cellpadding="20" valign="top"><tr>'
	'<td>'
	'<center><b>Bimbo</b></center>'
	if bimbolevel = 0:
		'You do not have this trait.'
		'To gain this trait, you must wear bimbo make up, clothing and shoes on 10 consecutive days.'
		'You have <<bimbo>> out of 10 points towards level 1.'
	elseif bimbolevel = 1:
		'You have this trait at level 1.'
		'To maintain this trait, you must wear bimbo make up, clothing and shoes at least once per day.'
		'Due to this trait, you gain a very small bonus to appearance and a very small penalty to intelligence.'
		'You have <<bimbo>> out of 20 points towards level 2.'
		if bimbowithdrawal = 0:
			'You are not in withdrawal.'
		else
			'You are in withdrawal and have <<14 - bimbowithdrawal>> days before losing this trait.'
		end
	elseif bimbolevel = 2:
		'You have this trait at level 2.'
		'To maintain this trait, you must wear bimbo make up, clothing and shoes at least once per day.'
		'Due to this trait, you gain a small bonus to appearance and a small penalty to intelligence.'
		'You have <<bimbo>> out of 30 points towards level 3.'
		if bimbowithdrawal = 0:
			'You are not in withdrawal.'
		else
			'You are in withdrawal and have <<14 - bimbowithdrawal>> days before losing this trait.'
		end
	else
		'You have this trait at level 3.'
		'To maintain this trait, you must wear bimbo make up, clothing and shoes at least once per day.'
		'Due to this trait, you gain a moderate bonus to appearance and a moderate penalty to intelligence.'
		if bimbowithdrawal = 0:
			'You are not in withdrawal.'
		else
			'You are in withdrawal and have <<14 - bimbowithdrawal>> days before losing this trait.'
		end
	end
	
	*nl
	
	'<center><b>Exhibitionist</b></center>'
	if Exhibitionist_lvl = 0 and exhib_cheat = 0:
		'You do not have this trait.'
		'To gain this trait, you must have low enough inhibition and choose to expose your breasts in public.'
		'You have <<pcs_exhib>> out of 10 points towards level 1. This will slowly decrease each day unless you expose yourself.'
	elseif Exhibitionist_lvl = 1:
		'You have this trait at level 1.'
		'To increase this trait, you must choose to expose your breasts and/or bare bottom in public.'
		'This trait grants you a small amount of excitement from exposing yourself.'
		'You have <<pcs_exhib>> out of 50 points towards level 2.'
	elseif Exhibitionist_lvl = 2:
		'You have this trait at level 2.'
		'To increase this trait, you must choose to expose your breasts, bare bottom and/or pussy in public.'
		'This trait grants you a moderate amount of excitement from exposing yourself.'
		if pcs_exhib < 100:
			'You have <<pcs_exhib>> out of 100 points towards level 3.'
		elseif pcs_exhib >= 100 and exhibitionQW < 3:
			'You must trigger an event in the park to gain level 3.'
		elseif pcs_exhib >= 100 and exhibitionQW > 2:
			'You will have to wait until the end of the day for the trait level to update.'
		end
	else
		'You have this trait at level 3.'
		'This is the highest level of this trait.'
		'This trait grants you a large amount of excitement from exposing yourself.'
	end
	
	*nl
	
	if pcs_traits['nerd_status'] = 0:
		'<center><b>Likes learning</b></center>'
		'You don''t have this trait but have <<pcs_traits[''nerd_points'']>> points. You need to earn <<40 - pcs_traits[''nerd_points'']>> more points to get level 1 of this trait.'
	elseif pcs_traits['nerd_status'] = 1:
		'<center><b>Likes learning</b></center>'
		'You have level 1 of this trait and <<pcs_traits[''nerd_points'']>> points. You need to earn <<60 - pcs_traits[''nerd_points'']>> more points to get level 2 of this trait. If you fall below 20 points, you''ll lose this trait.'
	elseif pcs_traits['nerd_status'] = 2:
		'<center><b>Loves to learn</b></center>'
		'You have level 2 of this trait and <<pcs_traits[''nerd_points'']>> points. You need to earn <<80 - pcs_traits[''nerd_points'']>> more points to get level 3 of this trait. If you fall below 40 points, you''ll fall back to level 1.'		
	elseif pcs_traits['nerd_status'] = 3:
		'<center><b>Teacher''s pet</b></center>'
		'You have level 3 of this trait and <<pcs_traits[''nerd_points'']>> points. If you fall below 60 points, you''ll fall back to level 2.'		
	end
	'Listening to more than 80% of lessons and doing your homework regularly earns you points for this trait, but you''ll lose points if you listen to less than 60% of lessons or if you don''t do your homework.'
	
	*nl
	
	'<center><b>Addictive Personality</b></center>'
	if addictive_trait_lvl = 0 and addictive_cheat = 0:
		'You do not have this trait.'
		'To gain this trait, you have to use 2 different types of drugs several times. At the moment, you have <<addictive_exp>> out of 2 points towards level 1.'
	elseif addictive_trait_lvl = 1:
		'You have this trait at level 1.'
		'You have some experience with taking drugs, and it becomes harder for you to refuse to take them.'
		'To increase this trait, you have to use 3 different types of drugs several times. At the moment, you have <<addictive_exp>> out of 3 points towards level 2.'
	elseif addictive_trait_lvl = 2:
		'You have this trait at level 2.'
		'Taking drugs has become something normal, and that makes it even harder for you to refuse to take them.'
		'To increase this trait, you have to use 4 different types of drugs several times. At the moment, you have <<addictive_exp>> out of 4 points towards level 3.'
	elseif addictive_trait_lvl = 3:
		'You have this trait at level 3.'
		'Taking drugs is a normal part of your life, which makes it difficult for you to refuse to take them.'
		'This is the highest level of this trait.'
	end
	
	*nl
	
	'<center><b>Cumeater</b></center>'
	if pcs_traits['cumeater'] = 0 and cumeater_cheat = 0:
		'You do not have this trait.'
		'To gain this trait, you must swallow cum 10 times.'
		'You have swallowed cum <<stat[''swallow'']>> times.'
	elseif pcs_traits['cumeater'] = 0 and cumeater_cheat = 1:
		'You do not have this trait.'
	else
		'You have this trait.'
		'It allows you to remove cum from certain locations and eat it'
		'This trait cannot be lost.'
	end
	
	*nl
	if pcs_traits['commando_exp'] > 0 or pcs_traits['commando_lvl'] > 0:'<center><b>Commando</b></center>'
	if pcs_traits['commando_lvl'] = 0 and pcs_traits['commando_exp'] > 0:
		'You need to gain more experience not wearing panties with clothing to gain this trait.'
	elseif pcs_traits['commando_lvl'] = 1:
		'You have this trait at level 1.'
		'You''re starting to get used to not wearing panties. Skirts are quite comfortable without them, but you still find the friction of pants to be a bit irritating.'
	elseif pcs_traits['commando_lvl'] = 2:
		'You have this trait at level 2.'
		'You are perfectly comfortable wearing any kind of clothing without panties. Your pussy is no longer irritated when wearing pants without panties.'
	elseif pcs_traits['commando_lvl'] = 3:
		'You have this trait at level 3.'
		'You are more comfortable without panties than with them. In fact, you <i>hate</i> wearing them! They''re restrictive and annoying. You suffer mood penalties when wearing panties.'
	end
	
	*nl

	if trait['braless_exp'] > 0 or trait['braless_lvl'] > 0:'<center><b>Braless</b></center>'
	if trait['braless_lvl'] = 0 and trait['braless_exp'] > 0:
		'You need to gain more experience not wearing bras with clothing to gain this trait.'
	elseif trait['braless_lvl'] = 1:
		'You have this trait at level 1.'
		'You''re starting to get used to not wearing bras. Most types of tops doesn''t cause any irritation, but some still does cause irritation'
	elseif trait['braless_lvl'] = 2:
		'You have this trait at level 2.'
		'You are perfectly comfortable wearing any kind of clothing without bras. Your nipples are no longer irritated when wearing non revealing upper body clothing without bras.'
	elseif trait['braless_lvl'] = 3:
		'You have this trait at level 3.'
		'You are more comfortable without bras than with them. In fact, you <i>hate</i> wearing them! They''re restrictive and the straps causes you pain. You suffer mood penalties when wearing bras.'
	end
	
	*nl
	
	if pcs_traits['alko_status'] = -1:
		'<center><b>Lightweight</b></center>'
		'It doesn''t take much for you to get drunk. You don''t have to drink as much to feel the effects of alcohol.'
	elseif pcs_traits['alko_status'] = 1:
		'<center><b>Heavyweight</b></center>'
		'You''ve built up a tolerance, making it harder for you to feel the effects of alcohol.'
	end

	*nl

	!!exp earned from anal sex but degrades over time. Level 3 can be lost but lvl1 and 2 cannot
	'<center><b>Buttslut</b></center>'
	if pcs_traits['buttslut_lvl'] = 0:
		'You need to have more anal orgasms to gain this trait. To reach lvl 1 you need to have more than 10 anal orgasms.'
		'You currently have had <<orgasm_anal>> anal orgasms.'
	elseif pcs_traits['buttslut_lvl'] = 1:
		'You have this trait at level 1. To reach lvl 2 you need to gain more anal orgasm exp.'
		'You currently have <<pcs_traits[''buttslut_exp'']>> experience. Having more anal orgasms will increase this, otherwise it will degrade over time.'
		'You''re starting to enjoy anal sex ' + iif(stat['think_virgin'] = 0, 'almost as much as regular sex.', 'more than before.')
	elseif pcs_traits['buttslut_lvl'] = 2:
		'You have this trait at level 2. To reach lvl 3 you need to gain more anal orgasm exp.'
		'You currently have <<pcs_traits[''buttslut_exp'']>> experience. Having more anal orgasms will increase this, otherwise it will degrade over time.'
		'You''re enjoy anal sex ' + iif(stat['think_virgin'] = 0, 'as much as regular sex.', 'a great deal.')
	elseif pcs_traits['buttslut_lvl'] = 3:
		'You have this trait at level 3. This is the highest level.'
		'You currently have <<pcs_traits[''buttslut_exp'']>> experience. Having more anal orgasms will increase this, otherwise it will degrade over time.'
		if stat['think_virgin'] = 0:
			'You now enjoy anal sex more than regular sex.'
		else
			'You find anal sex to be extremely gratifying.'
		end
	end

	act 'Exit the menu': gt $loc, $loc_arg
	'</td></tr></table></center>'
end

if $ARGS[0] = 'hourly':
	if stat['swallow'] >= 10 and pcs_traits['cumeater'] = 0 and cumeater_cheat = 0:
		pcs_traits['cumeater'] = 1
		msg 'You have gained the trait "Cumeater"'
	end
end

if $ARGS[0] = 'creampie_fetish':
	pcs_traits['creampie_fetish'] = 1
	msg 'You have gained the Creampie Fetish trait! Your desire for creampies are so strong that you can''t help but orgasm when a big load of spunk is poured into your pussy, whether you asked for it or not ;)'
end

if $ARGS[0] = 'fitness_freak':
	pcs_traits['fitness_freak'] = 1
	msg '"You don''t know if it''s something you learned or something is just wrong with your brain. You love exercise. It feels good. *Really* good. Yeah. *That* kind of good. You get turned on when you exercise and the people around you can subconsciously sense it.'
	
	'Exercise increases your arousal and for a short time after, you ignore the appearance penalties of sweat, adding them as a bonus to your appearance instead."'
end

if $ARGS[0] = 'stiff_nipples':
	pcs_traits['pokies'] = 1
	msg 'You have particularly stiff nipples. They''re always hard, even when you''re not aroused. So hard that they''ll give you pokies through a bra that other girls would get away with without one.'
end

if $ARGS[0] = 'wet_pussy':
	pcs_traits['wet_pussy'] = 1
	msg 'You get wetter than other girls, especially when aroused.'
end

if $ARGS[0] = 'overnight':
	!!pcs_traits['alko_status']: light weight (-1), normal (0), heavy weight (+1)
	!!pcs_traits['alko_points']: between -100 and 100, tracks if sveta is a light or heavy wight
	!!pcs_traits['alko_day']: amount of alko sveta has drunk today
	
	!!Gains/Decay
	if pcs_traits['alko_day'] > 0:
		if pcs_traits['alko_day'] > 9:
			pcs_traits['alko_points'] += 9
		else
			pcs_traits['alko_points'] += pcs_traits['alko_day']
		end
	elseif pcs_traits['alko_day'] = 0:
		pcs_traits['alko_points'] -= 2
	end
	
	if kanikuli = 0 and week < 6:
		if lernHome > 0:
			pcs_traits['nerd_lernHome'] = 0
			pcs_traits['nerd_points'] -= 1
		elseif lernHome = 0 and pcs_traits['nerd_lernHome'] < 5:
			pcs_traits['nerd_lernHome'] += 1
		elseif pcs_traits['nerd_lernHome'] = 5:
			pcs_traits['nerd_points'] += 1
		end
	elseif kanikuli = 0 and week = 6:
		!!This check has to be changed if the number of non-sport lessons ever changes (27 right now)
		if pcs_traits['nerd_lessons'] > 20:
			pcs_traits['nerd_points'] += pcs_traits['nerd_lessons'] - 17
		elseif pcs_traits['nerd_lessons'] < 14:
			pcs_traits['nerd_points'] -= iif(pcs_traits['nerd_status'] > 0, 5, 10)
		end
		pcs_traits['nerd_lessons'] = 0
	elseif university['semester_week'] > 0 and university['student'] = 1 and week = 5:
		!!This is for being a university student, with only 9 weekly classes and no homework the gain is a little more aggressive from classes.
		if pcs_traits['nerd_lessons'] > 7:
			pcs_traits['nerd_points'] += (pcs_traits['nerd_lessons']-7)*5
		elseif pcs_traits['nerd_lessons'] < 4:
			pcs_traits['nerd_points'] -= iif(pcs_traits['nerd_status'] > 0, 5, 10)
		end
		pcs_traits['nerd_lessons'] = 0	
	end	
	
	!!Trait selection
	if pcs_traits['alko_points'] > 50 and pcs_traits['alko_status'] < 1:
		pcs_traits['alko_status'] = 1
		msg 'You have gained the trait ''Heavyweight''.'
	elseif pcs_traits['alko_points'] < -50 and pcs_traits['alko_status'] > -1:
		pcs_traits['alko_status'] = -1	
		msg 'You have gained the trait ''Lightweight''.'
	elseif pcs_traits['alko_status'] = -1 and pcs_traits['alko_points'] > 0:
		pcs_traits['alko_status'] = 0
		msg 'You have lost the trait ''Lightweight''.'
	elseif pcs_traits['alko_status'] = 1 and pcs_traits['alko_points'] < 0:
		pcs_traits['alko_status'] = 0
		msg 'You have lost the trait ''Heavyweight''.'
	end
	
	if pcs_traits['nerd_points'] > 80 and pcs_traits['nerd_status'] < 3:
		pcs_traits['nerd_status'] = 3
		msg 'You have gained the trait ''Teacher''s pet''.'
	elseif pcs_traits['nerd_points'] > 60 and pcs_traits['nerd_status'] < 2:
		pcs_traits['nerd_status'] = 2
		msg 'You have gained the trait ''Loves to learn''.'		
	elseif pcs_traits['nerd_points'] > 40 and pcs_traits['nerd_status'] < 1:
		pcs_traits['nerd_status'] = 1
		msg 'You have gained the trait ''Likes learning''.'
	elseif pcs_traits['nerd_points'] < 60 and pcs_traits['nerd_status'] = 3:
		pcs_traits['nerd_status'] = 2
		msg 'You have lost the trait ''Teacher''s pet''.'
	elseif pcs_traits['nerd_points'] < 40 and pcs_traits['nerd_status'] = 2:
		pcs_traits['nerd_status'] = 1
		msg 'You have lost the trait ''Loves to learn''.'	
	elseif pcs_traits['nerd_points'] < 20 and pcs_traits['nerd_status'] = 1:
		pcs_traits['nerd_status'] = 0
		msg 'You have lost the trait ''Likes learning''.'		
	end
	
	!!Trait effects
	if pcs_traits['nerd_status'] = 3:
		grupvalue[1] -= 1
		grupvalue[3] += rand(1,2)
		grupvalue[4] -= rand(1,2)		
	elseif pcs_traits['nerd_status'] = 2:
		grupvalue[3] += 1
		grupvalue[4] -= 1
	elseif pcs_traits['nerd_status'] = 1:
		grupvalue[3] += rand(0,1)
	end

	!!Cleanup
	pcs_traits['alko_day'] = 0
	if pcs_traits['alko_points'] > 100: 
		pcs_traits['alko_points'] = 100
	elseif pcs_traits['alko_points'] < -100: 
		pcs_traits['alko_points'] = -100
	end
	
	if pcs_traits['nerd_points'] > 100:
		pcs_traits['nerd_points'] = 100
	elseif pcs_traits['nerd_points'] < -100:
		pcs_traits['nerd_points'] = -100
	end
end

if $ARGS[0] = 'addictive_personality':
	!!Addictive Personality Trait
	if addictive_cheat = 0:
		addictive_exp = smoke_exp + joint_exp + heroin_exp + cocaine_exp + alcohol_exp + amphetamine_exp

		if addictive_exp = 2 and addictive_trait_lvl < 1:
			addictive_trait_lvl = 1
			if add_trait_msg_1 = 0: add_trait_msg_1 = 1 & msg 'You have gained the trait ''Addictive Personality''.'
		elseif addictive_exp = 3 and addictive_trait_lvl < 2:
			addictive_trait_lvl = 2
			if add_trait_msg_2 = 0: add_trait_msg_2 = 1 & msg 'You have increased the level of your ''Addictive Personality'' trait to 2.'
		elseif addictive_exp >= 4 or (heroin_exp = 1 and cocaine_exp = 1) and addictive_trait_lvl < 3:
			addictive_trait_lvl = 3
			if add_trait_msg_3 = 0: add_trait_msg_3 = 1 & msg 'You have increased the level of your ''Addictive Personality'' trait to 3.'
		end
	end
end

--- traits ---------------------------------