# enemy
!!Calculation of the enemy`s attack
if $ARGS[0] = 'start':
	cla
	!in this block is selected on the basis of the variable program enemy attacks
	if program = 0:
		!Action Programme simple attacker fizuhoy
		xgt 'enemy', 'fighter'
	elseif program = 1:
		!Action Programme fizuha and knives
		xgt 'enemy', 'fighter2'
	elseif program = 2:
		!Action Programme fizuha, knives, fog
		xgt 'enemy', 'fighter3'
	elseif program = 3:
		!Action Programme fizuha, knives, fog, Clones
		xgt 'enemy', 'fighter4'
	elseif program = 4:
		!Action Programme fizuha, knives, fog, Clones, paralysis
		xgt 'enemy', 'fighter5'
	elseif program = 5:
		!Action Programme Kisame
		xgt 'enemy', 'kisame'
	elseif program = 6:
		!Action Programme Toby
		xgt 'enemy', 'tobi'
	elseif program = 7:
		!Action Programme Toby
		xgt 'enemy', 'gedomazo'
	elseif program = 8:
		!program of action firearms
		xgt 'enemy', 'gun'
	elseif program = 9:
		!Action Programme Sasori
		xgt 'enemy', 'sasori'
	elseif program = 10:
		!Action Programme Conan
		xgt 'enemy', 'konan'
	elseif program = 11:
		!Action Programme Hidan
		xgt 'enemy', 'hidan'
	end
end

if $ARGS[0] = 'hidan':
	cla

	if zerkaloV > 0:barierV = 0
	if zerkaloV <= 0:barierV = 5500
	if healthV < vitalV * 10 + strenV * 5:healthV = vitalV * 10 + strenV * 5

	if zerkaloV > 0:
		healthV = vitalV * 10 + strenV * 5
		mannaV = intelV * magikV + magikV * 100 + vitalV * 10
		willpowerV = willV * 10
		health -= 400
		manna -= 500
		'<b><font color="red"><<$nameV>> yells "RITUAL BEGINS!" and stands in a circle inscribed in blood on the ground.</font></b>'
		'<b><font color="red">He stabs himself and you feel like the pain pierces the body.</font></b>'
		xgt 'fight', 'sta'
		exit
	elseif zerkaloV <= 0 and defence > 0:
		damTipV = 5000
		bonusShV = 100
		hidanAtk = 1
		'<b><font color="red"><<$nameV>> yells "Your existence offends DZHASHINA MY GOD!" and throws you in his scythe trehlezviynuyu driving it by a line.</font></b>'

		if klon > 0:klon = klon / 2 & '<b><font color="red"><<$nameV>> yells "Mraz I slaughter YOU LIKE A PIG!"</font></b>'

		xgt 'atakA1', 'atak'
		exit
	elseif zerkaloV <= 0 and defence <= 0:
		damTipV = 300
		bonusShV = 100
		hidanAtk = 1
		'<b><font color="red"><<$nameV>> yells "You will die a blasphemer!" and throws you in his scythe trehlezviynuyu driving it by a line.</font></b>'

		if klon > 0:klon = 0 & '<b><font color="red">Your clones turned into steam from the blow spit. <<$nameV>> yells "I IMMORTAL Ravager! And YOU SHIT!"</font></b>'
		if tuman > 0:tuman = 0 & '<b><font color="red"><<$nameV>> yells "You´re pathetic in their vain attempts SPRYATATSYA FROM ME!"</font></b>'

		xgt 'atakA1', 'atak'
		exit
	end
end

if $ARGS[0] = 'konan':
	cla

	if round < 6:
		mannaV -= 10
		damTipV = 500
		'<b><font color="red"><<$nameV>> adds signs hands and you are flying sheets of paper.</font></b>'

		if klon > 0:klon = 0 & '<b><font color="red">Your clones turned into steam from hitting the paper.</font></b>'

		xgt 'atakA1', 'atak'
		exit
	elseif round >= 6:
		if unmaterialV > 5 and defence > 0:
			mannaV -= 250
			damTipV = 15000
			bonusShV = 100
			'<b><font color="red"><<$nameV>> takes to the air on the white wings and pulled out from her wings paper falls on you in a flood of flying with terrible speed paper swords.</font></b>'

			if klon > 0:klon = 0 & '<b><font color="red">Your clones turned into steam from hitting the paper.</font></b>'

			xgt 'atakA1', 'atak'
			exit
		elseif unmaterialV > 5 and defence <= 0:
			mannaV -= 20
			damTipV = 450
			'<b><font color="red"><<$nameV>> creates a paper boomerangs that fly in your direction.</font></b>'
			xgt 'atakA1', 'atak'
			exit
		elseif defenceV <= 0 and unmaterialV <= 5:
			mannaV -= 250
			defenceV += 3000
			defenceMV += 3000
			defenceWV += 3000
			'<b><font color="red">Conan shoots up to its paper wings like an angel. Around it starts spinning paper creating her protection.</font></b>'
			xgt 'fight', 'sta'
			exit
		elseif unmaterialV <= 2 and konanD < 3:
			mannaV -= 150
			konanD += 1
			'<b><font color="red">Conan stops meditating in the air.</font></b>'
			xgt 'fight', 'sta'
			exit
		elseif konanD >= 3:
			mannaV -= 250
			konanD = 0
			unmaterialV = 20
			'<b><font color="red">Conan crumbles in the air for thousands of sheets of paper.</font></b>'
			xgt 'fight', 'sta'
			exit
		end
	end
end

if $ARGS[0] = 'sasori':
	cla

	if SasoriBody > 1:damTipV = 1000
	if SasoriBody = 1:damTipV = 2000

	poisonAV = 1
	defenceV += 10
	defenceMV += 20
	defenceWV += 50
	mannaV -= 10

	if SasoriBody = 1 and defence > 0:
		defSasori = defence * 20 / 100
		defence -= defSasori
		'<b><font color="red">of rain falls on top of steel needles greatly weaken your defenses.</font></b>'
	end

	'<b><font color="red"><<$nameV>> shoots at you the whole cloud of poisonous spines.</font></b>'

	if klon > 0:klon = 0 & '<b><font color="red">Your clones turned into steam from the blow needle.</font></b>'

	xgt 'atakA1', 'atak'
end

if $ARGS[0] = 'gedomazo':
	cla

	if klon <= 0 and tuman <= 0:
		magweapbonusV = 5000
		'<b><font color="red"><<$nameV>> with a furious roar of effort on you for its huge stone fist.</font></b>'
		xgt 'atak', 'enemy'
		exit
	elseif klon > 0 or tuman > 0:
		klon = 0
		tuman = 0
		mannaV -= 500
		'<b><font color="red"><<$nameV>> makes a terrible roar and air shock wave sweeps over the battlefield.</font></b>'
		xgt 'fight', 'sta'
		exit
	end
end

if $ARGS[0] = 'tobi':
	cla

	!!program attacks Toby
	if unmaterialV <= 0 and IzanagiV = 0 and GedoMazo = 0:
		*clr
		'<b><font color="red"><<$nameV>> fingers to his lips and said quietly, "KUCHIE SAINT BUT JITSU."</font></b>'
		'<b><font color="red">you will see Huge stone statue of a demon, and you rushed to the attack.</font></b>'
		GedoMazo = 1
		$nameV = 'Gedo Mazo'
		!!stats
		strenV = 1000
		speedV = 100
		agilV = 90
		reactV = 100
		vitalV = 5000
		intelV = 50
		willV = 50
		!!skills
		magikV = 1
		boxingV = 100
		shootV = 100
		!!parameters
		healthV = vitalV * 10 + strenV * 5
		mannaV = intelV * magikV + magikV * 100 + vitalV * 10
		willpowerV = willV * 10
		BonusAtakV = 0
		BonusDefV = 0
		!!Programme of Action
		barierV = 1500
		program = 7
		xgt 'fight', 'start'
		exit
	elseif unmaterialV <= 2 and IzanagiV = 0 and GedoMazo > 0 and TobiStena = 0:
		mannaV -= 500
		TobiStena = 1
		defenceV += 25000
		'<b><font color="red"><<$nameV>> makes Arcanum and reinforcing the skin blackens his body and creating protection of 25,000 units.</font></b>'
		barierV = 2000
		xgt 'fight', 'sta'
		exit
	elseif unmaterialV <= 2 and IzanagiV = 0 and GedoMazo > 0 and TobiStena = 1:
		mannaV += 6000
		TobiStena = 2
		'<b><font color="red"><<$nameV>> makes the magic sign and you feel like it´s magical energy increases sharply.</font></b>'
		xgt 'fight', 'sta'
		exit
	elseif stun > 0:
		magweapbonusV = 2000
		'<b><font color="red"><<$nameV>> triumphantly said, "Now you´re dead."</font></b>'
		'<b><font color="red">He grabs you by the throat and lifts his hand in the air.</font></b>'
		'<b><font color="red">His fingers like steel and they squeeze your throat with terrible force.</font></b>'
		xgt 'atak', 'enemy'
		exit
	elseif defence >= 5000:
		defence = 0
		defenceM = 0
		defenceActPar = 0
		defenceActParM = 0
		defenceAct = 0
		defenceActM = 0
		defAtk = 0
		mannaV -= 100
		stunV = 1
		'<b><font color="red"><<$nameV>> close your eyes and you saw of him as a tear ran down a drop of blood.</font></b>'
		'<b><font color="red">He opened his eyes become completely red with black veins and said Amaterasu</font></b>'
		'<b><font color="red">In your face rushed black devouring flames destroy your lightning protection.</font></b>'
		xgt 'fight', 'sta'
		exit
	elseif tuman > 0:
		tumanV += tuman
		tuman = 0
		'<b><font color="red"><<$nameV>> adds the magic signs your hands and mist coming under his control enveloping the review of you.</font></b>'
		'<b><font color="red">He will attack you.</font></b>'
		xgt 'atak', 'enemy'
		exit
	elseif unmaterialV > 0 and klon <= 0:
		stunnerV = 1
		mannaV -= 20
		magweapbonusV = 800
		'<b><font color="red"><<$nameV>> attacks you gathered the manna in the hand.</font></b>'
		xgt 'atak', 'enemy'
		exit
	elseif unmaterialV > 0 and klon > 0:
		klon = 0
		stunV = 1
		'<b><font color="red"><<$nameV>> adds signs hands and all your clones just turn into steam.</font></b>'
		xgt 'atak', 'enemy'
		exit
	elseif unmaterialV <= 0 and tobizanagi < 2:
		mannaV -= 250
		tobizanagi += 1
		!!unmaterialV = 10
		'<b><font color="red"><<$nameV>> adds the characters by hand.</font></b>'
		xgt 'fight', 'sta'
		exit
	elseif unmaterialV <= 0 and tobizanagi = 2:
		mannaV -= 250
		tobizanagi = 0
		unmaterialV = 20
		stunV = 1
		'<b><font color="red"><<$nameV>> folds his hands and marks around his eyes twisted vortex.</font></b>'
		xgt 'fight', 'sta'
		exit
	end
end

if $ARGS[0] = 'kisame':
	cla
	!!program attack Kisame

	if defenceV <= 0 and kisamePro = 0:
		kisamePro = 1
		mannaV -= 150
		defenceV += 1500
		defenceMV += 1500
		defenceWV += 1500
		defenceActParV = 500
		defenceActParMV = 500
		defenceActV = 10
		defenceActMV = 10
		'<b><font color="red"><<$nameV>> adds the marks around his hands and formed water sphere protecting it from damage.</font></b>'
		xgt 'fight', 'sta'
		exit
	elseif defenceV <= 1000 and kisamePro > 0:
		mannaV -= 500
		defenceV += 5000
		defenceMV += 5000
		defenceWV += 5000
		defenceActParV = 500
		defenceActParMV = 500
		defenceActV = 10
		defenceActMV = 10
		defAtkMV = 10
		'<b><font color="red"><<$nameV>> adds the marks and the space around the hands begins pogruzhatsya water.</font></b>'

		if klon > 0:klon = 0 & '<b><font color="red">Your clones turned into steam from hitting the water.</font></b>'

		xgt 'fight', 'sta'
		exit
	elseif defenceV > 1000:
		kisamerand= rand(0, 3)

		if kisamerand= 0:
			klonV += 3
			'<b><font color="red"><<$nameV>> adds the characters by hand.</font></b>'
			xgt 'fight', 'sta'
			exit
		elseif kisamerand> 0:
			mannaV -= 250
			damTipV = 1500
			damTipMV = 2500
			bonusShV = 50
			'<b><font color="red"><<$nameV>> adds the characters in the hands and fly sharks have created from the water.</font></b>'

			if klon > 0:klon = 0 & '<b><font color="red">Your clones turned into steam from hitting the water.</font></b>'

			xgt 'atakA1', 'atak'
			exit
		end
	end

	'<b><font color="red"><<$nameV>> attacks.</font></b>'
	xgt 'enemy', 'fighter'
end

if $ARGS[0] = 'gun':
	cla
	!!program directly attack
	!!gs 'atak'
	damTipV = 1500
	'<b><font color="red"><<$nameV>> shoots at you.</font></b>'
	xgt 'atakA1', 'atak'
end

if $ARGS[0] = 'fighter':
	cla
	!!program directly attack
	!!gs 'atak'
	xgt 'atak', 'enemy'
end

if $ARGS[0] = 'fighter2':
	cla
	!!program directly attack
	deystrand = rand(0, 1)

	if deystrand = 0:
		xgt 'atak', 'enemy'
	elseif deystrand = 1:
		knifeV = rand(1, 3)
		'<b><font color="red"><<$nameV>> have a throws <<knifeV>> the blades</font></b>'
		xgt 'atak', 'enemy'
	end
end

if $ARGS[0] = 'fighter3':
	cla

	!!program directly attack
	if tuman = 0 and tumanV < 5 and mannaV > 10:
		mannaV -= 10
		tumanV += 10
		'<b><font color="red"><<$nameV>> produces a fog on the battlefield.</font></b>'
		xgt 'fight', 'sta'
		exit
	end

	deystrand = rand(0, 1)

	if deystrand = 0:
		xgt 'atak', 'enemy'
	elseif deystrand = 1:
		knifeV = rand(1, 3)
		'<b><font color="red"><<$nameV>> have a throws <<knifeV>> the blades</font></b>'
		xgt 'atak', 'enemy'
	end
end

if $ARGS[0] = 'fighter4':
	cla

	!!program directly attack
	if tuman = 0 and tumanV < 5 and mannaV > 10:
		mannaV -= 10
		tumanV += 10
		'<b><font color="red"><<$nameV>> produces a fog on the battlefield.</font></b>'
		xgt 'fight', 'sta'
		exit
	elseif klonV < 1 and mannaV > 15:
		mannaV -= 15
		klonV += 1
		'<b><font color="green">is washed</font></b>'
		xgt 'fight', 'sta'
		exit
	end

	deystrand = rand(0, 1)

	if deystrand = 0:
		xgt 'atak', 'enemy'
	elseif deystrand = 1:
		knifeV = rand(1, 3)
		'<b><font color="red"><<$nameV>> have a throws <<knifeV>> the blades</font></b>'
		xgt 'atak', 'enemy'
	end
end

if $ARGS[0] = 'fighter5':
	cla

	!!program directly attack
	if tuman = 0 and tumanV < 5 and mannaV > 10:
		mannaV -= 10
		tumanV += 10
		'<b><font color="red"><<$nameV>> produces a fog on the battlefield.</font></b>'
		xgt 'fight', 'sta'
		exit
	elseif klonV < 1 and mannaV > 15:
		mannaV -= 15
		klonV += 1
		'<b><font color="green">is washed</font></b>'
		xgt 'fight', 'sta'
		exit
	elseif stun < 1 and manna > 20:
		stunnerV = 1
		mannaV -= 20
		'<b><font color="red"><<$nameV>> attacks you Gouge.</font></b>'
		xgt 'atak', 'enemy'
	end

	deystrand = rand(0, 1)

	if deystrand = 0:
		xgt 'atak', 'enemy'
	elseif deystrand = 1:
		knifeV = rand(1, 3)
		'<b><font color="red"><<$nameV>> have a throws <<knifeV>> the blades</font></b>'
		xgt 'atak', 'enemy'
	end
end

--- enemy ---------------------------------