broodseal_mod/locations/mod_broodseal.qsrc

# mod_broodseal
!input mod entry point here. this will be checked on every location, please keep it clean and brief to avoid game lag

if mod_broodseal_init ! 1:
	mod_broodseal_init = 1
	mod_broodseal_speed = 1
	mod_broodseal = 0
	mod_broodseal_hour = 0
	mod_broodseal_day = 0
	mod_broodseal_debt = 0
	mod_broodseal_n = 0
	mod_broodseal_lottery = 0
	mod_broodseal_org = 0
	mod_broodseal_pwr = 0
	mod_broodseal_level = 0
	mod_broodseal_preg = 0
end

if fairycurse >= daystart and mod_broodseal < 1:
	mod_broodseal_day = daystart
	mod_broodseal_org = orgasm
	mod_broodseal = 1
	'In an instant you feel great magical forces gathering, making the air seem... charged. Before you have the chance to comprehend the situation, you feel your abdomen heating up while it feels like all that energy starts flowing into your lower belly.'
	$orgasm_or = 'yes'
	gs 'arousal', 'vaginal_finger', -5, 'exhibitionism'
	'You feel... alive! All you can think of is to share this wonderful feeling! To spread this joy of life! To party! To love! To fuck and get fucked!'
	'You want to keep feeling this way and to share it!'
	'To feel loved and to feel love flow into you, to feel the crescendo of love explode deep within you! To get impaled by hard cock, to lock your legs behind your lover and to ensure you receive all the seeds of love! The idea of nurturing the seed within your body to bring forth more and more life into the world imprints itself in your mind and the thought alone makes you cum again.'
	$orgasm_or = 'yes'
	gs 'arousal', 'vaginal_finger', -5, 'exhibitionism'
	'Suddenly you jerk awake from this waking daydream, startled. Deep in your subconscious the idea of having kids taking root and somehow you can tell that your body is onboard with the plan. Feeling a mixture of excitement and fear, you realize you can probably never climax again without thinking of creating new life.'
	if tatvag = 0: 
		tatvag = 969
		tattCount += 1
		'During your hazy ordeal a strange glowing mark has appeared on the skin of your abdomen.'
		'<center><img src="images/pc/body/tattoos/pubic/tatvag969.jpg"></center>'
	end
	gs 'arousal', 'vaginal_finger', -60, 'exhibitionism'
	mod_broodseal_org = orgasm
	if mod_broodseal_level < 1: mod_broodseal_level = 1
end

if mod_broodseal_day < daystart and mod_broodseal > 0:
	mod_broodseal_day = daystart
	mod_broodseal_hour = rand(6,12)
	if mod_broodseal_org < orgasm:
		mod_broodseal_pwr = (orgasm - mod_broodseal_org) * (2 + mod_broodseal_level) * 2
	else
		mod_broodseal_pwr = 0
	end
	mod_broodseal_pwr += kid
	if mod_broodseal_debt < 1: mod_broodseal_org = orgasm

	mod_broodseal_debt += daystart - mod_broodseal_day
	mod_broodseal_debt += rand(0,mod_broodseal_level)

	if preg > 0: 
		mod_broodseal_preg = 1
	elseif mod_broodseal_preg = 1:
		mod_broodseal_preg = 0
		mod_broodseal_level += 1
	end
	if pregspeedcheat <= mod_broodseal_level and mod_broodseal_speed > 0:
		if mod_broodseal_level < 7:
			pregspeedcheat = mod_broodseal_level 
		else
			pregspeedcheat = 6
		end
	end
	if bimbolevel <= 0: supnatvnesh = 3 * mod_broodseal_level
	if bimbolevel < 2: 
		extra_supnatvnesh = mod_broodseal_pwr
		if preg = 0: extra_supnatvnesh += 15
	end
end

if mod_broodseal_debt > 0 and hour >= mod_broodseal_hour:
	'<font color="red"><b>The cursed seal pulses!</b></font>'

	mod_broodseal_debt -= 1
	if mod_broodseal_debt > 0: mod_broodseal_hour += rand(0,3)

	mod_broodseal_n = 50 + ((pcs_intel + pcs_sprt + willpower_percent + (3 * (100 - pcs_inhib))) / 6) - mod_broodseal_pwr - mod_broodseal_level
	if mod_broodseal_n < 15: mod_broodseal_n = 15
	mod_broodseal_lottery = rand(0,mod_broodseal_n)

!! First tier effects
	if mod_broodseal_lottery < 75:
		gs 'arousal', 'vaginal_finger', -2, 'exhibitionism'

!! Second tier effects - each tier stacks with effects from previous tier
		if mod_broodseal_lottery < 50:
			gs 'arousal', 'vaginal_finger', -3, 'exhibitionism'
			mod_broodseal_n = mod_broodseal_level + mod_broodseal_pwr
			EggRH += rand(0,mod_broodseal_n)
			if preg > 0:
				pcs_mood += rand(0,mod_broodseal_n) * 2
				pcs_health += rand(0,mod_broodseal_n) * 5
			end

!! Third tier effects
			if mod_broodseal_lottery < 25:
				gs 'arousal', 'vaginal_finger', -5, 'exhibitionism'
				EggRH += rand(0,mod_broodseal_n)

!! Fourth tier effects
				if mod_broodseal_lottery < 10:
					gs 'arousal', 'vaginal_finger', -10, 'exhibitionism'
					EggRH += rand(0,mod_broodseal_n)
					if pillcon > 0: pillcon = pillcon * 9/(9 + mod_broodseal_level + mod_broodseal_pwr)
					if RecovH > 0: RecovH = RecovH * 9/(9 + mod_broodseal_level + mod_broodseal_pwr)
					if tabletkishot > 0: 
						tabletkishot -= (mod_broodseal_pwr + mod_broodseal_level)
						if tabletkishot < 0: tabletkishot = 0
					end
					if birth_control['implant_status'] > 1: 
						if rand(0,49) + mod_broodseal_pwr + mod_broodseal_level > 50:
							birth_control['implant_timer'] = 1
						else
							birth_control['implant_timer'] -= mod_broodseal_pwr * mod_broodseal_level * 3
							if birth_control['implant_timer'] < 1: birth_control['implant_timer'] = 1
						end
					end

!! Fifth tier effects - most severe
					if mod_broodseal_lottery < 5:
						if ovulate > 0 and mod_broodseal_pwr > 0: UnfertEgg += min(rand(0,mod_broodseal_level),3)
						gs 'arousal', 'vaginal_finger', -mod_broodseal_n, 'exhibitionism'
						if pillcon > 0 and rand(0,2) = 0: pillcon = (1 + pillcon) / (1 + mod_broodseal_pwr)
						if rand(0,4) = 0: fairycurse = daystart
						if stallionQ < 5: stallionQ = 3
						if prezik > 0 and preziktype = 0:
							if rand(0,mod_broodseal_level) > 0:
								if preziksabo >= 1:
									prezikcount = prezik
								else
									preziksabo = 1
									prezikcount = prezik - 1
								end
								prezik = preziksabo
								preziksabo = 0
								preziktype = 2
							end
						end
						if rand(0,15) + mod_broodseal_level > 15:
							if ptype ! 5 and pillsleft[ptype] > 0:
								mod_pilltrick = pillsleft[ptype]
								pillsleft[ptype] = 0
								ptype = 5
								pillsleft[ptype] = mod_pilltrick
							end
						end
						if tabletki > 0:
							if rand(0,15) + mod_broodseal_level > 15:
								if tabletki > (tabletkiold + tabletkifake + tabletkirej + tabletkisug + tabletkifert):
									if tabletkifert < 1:
										tabletkifert = 1
									else
										tabletkifert += 1
									end
								end
							end
						end
					end
				end
			end
		end
	end
end
--- mod_broodseal ---------------------------------