WLife-New/locations/mod_wlife_clinic.qsrc

# mod_wlife_clinic

if $ARGS[0] = 'first_visit':
	*clr & cla
	minut += 10
	menu_off = 1
	gs 'stat'
	'<center><video autoplay src="mod/wlife/images/locations/clinic/walk_in.mp4"></video></center>'
	'After filling out a form with your personal information like your name, age and so on you only have to wait ten minutes, before an old nurse points you towards the office of Doctor Mikhailov. You knock and at once a deep voices sounds through the door, "come on in."'
	*nl
	'"Miss...," he looks down on the completed form, "<<$pcs_lastname>> nice to meet you," he continues and holds his hand out to you over the table. His hand feels surprisingly soft for a man of his age. His gray hair and beard, the kind eyes and his demeanor reminds you more of Santa than an evil doctor who treats '+iif(age < 18, 'underage', 'young')+' girls who are coerced into prostitution. "Please take a seat," he says and continues to speak as you sit down. "Let''s clear the air before we start. I know why you''re here and please don''t assume I''m not sympathizing with you or your situation, but I can''t change anything about that. So please refrain from pleading for my help, it will only lead to awkward conversations none of us wants to have."'
	'"Uhm... OK." He ignores that your words sound more like a question than an answer and instead claps his hands once and flashes a bright smile. "Great, than let us get to work."'

	act 'Talk with him':
		*clr & cla
		minut += 10
		wl_medical['picture'] = 0
		gs 'stat'
		'<center><video autoplay src="mod/wlife/images/locations/clinic/talk_0.mp4"></video></center>'
		'"Before we delve into your medical and sexual history we have to talk about two organizational issues. You don''t have to pay for an appointment, but if I have to perform a procedure or prescribe some medicine, you''ll have to pay for it. I can''t hide this from the clinic. If you can''t afford it, the Bely''s will cover the cost, but you''ll have to pay them back at some point. You''ll also have to check in with me every two weeks. If you don''t, I will have to report that to Mr. Bely," he tells you with a serious expression. You nod and the smile returns to his face. "Alright, then why don''t you tell me a bit about your history." For the next few minutes you tell him everything that you know about your own and the medical history of your family, before telling him that you '+iif(pcs_vag = 0, 'are', 'aren''t')+' a virgin'+iif(pcs_vag = 0, ' ', ' anymore ')+'and'+iif(anal = 0, ' never ', ' ')+'had anal sex.'+iif(SchoolAtestat = 0 and motherKnowSpravka = 0 and func('homes_properties', 'is_current_home', 'parents_home') ! 0, ' You also tell him about your mother and the monthly referrals you have to show her to prove your virginity. He has no problem to provide you with a referral, when you need it.', '')
		*nl
		if pcs_vag > 0: '"Are you or have you ever been pregnant?" he inquires after you''re done talking. '+iif(kid = 0 and knowpreg = 0 and thinkpreg = 0, '"Not that I know of."', '"Yes,'+iif(kid > 0, ' I have a child' +iif(knowpreg > 0 or thinkpreg > 0, ' and ', '.'), ' ')+iif(knowpreg > 0 or thinkpreg > 0, 'I think I''m pregnant."', '"'))+' He nods and scribbles a note onto a piece of paper.'

		act 'Continue':
			*clr & cla
			'<center><img <<$set_imgh>> src="mod/wlife/images/objects/info.gif"></center>'
			'Developer Note: I will not write special events or reactions for pregnancies since dealing with it get''s way to complicated. You can now decide how the mod should handle pregnancies. You can either choose that abortions are mandatory or not. You''ll be able to change that decision later in the cheatmenu'+iif(wl_status['main'] < 5, ' (which can be found in the phone, when it becomes available).', '.')

			act 'No, abortions aren''t mandatory':
				*clr & cla
				$wl_status['abortions'] = 'no'
				'<center><video autoplay src="mod/wlife/images/locations/clinic/talk_0.mp4"></video></center>'
				iif(pcs_vag > 0, '"Since we are already talking about pregnancies.', '"There is one other thing we have to talk about and that''s pregnancies.')+' You should get on the pill and always use a condom to protect yourself from STDs, but if you ever get pregnant and have to deal with it, I can perform the abortion here." You don''t know how to respond to that. Hearing him talking about pregnancies and abortions makes your head spin. Doctor Mikhailov has to say your name several times to get your attention back. "Miss <<$pcs_lastname>>?" He asks one last time and continue, when you nod, "it''s time to have a closer look."'

				act 'Take a seat on the gynecological chair': gt 'mod_wlife_clinic', 'exam'
			end

			act 'Yes, abortions are mandatory':
				*clr & cla
				$wl_status['abortions'] = 'yes'
				'<center><video autoplay src="mod/wlife/images/locations/clinic/talk_0.mp4"></video></center>'
				iif(pcs_vag > 0, '"Since we are already talking about pregnancies.', '"There is one other thing we have to talk about and that''s pregnancies.')+' You should get on the pill and always use a condom to protect yourself from STDs, but if you ever get pregnant I''ll have to perform an abortion. You can''t do your job efficiently, when you''re pregnant. The Bely''s won''t tolerate it." You don''t know how to respond to that. Hearing him talking about pregnancies and forced abortions makes your head spin. Doctor Mikhailov has to say your name several times to get your attention back. "Miss <<$pcs_lastname>>?" He asks one last time and continue, when you nod, "it''s time to have a closer look."'

				act 'Get on the examination table': gt 'mod_wlife_clinic', 'exam'
			end
		end
	end
end

if $ARGS[0] = 'check':
	*clr & cla
	minut += 5
	menu_off = 1
	gs 'stat'
	'<center><video autoplay src="mod/wlife/images/locations/clinic/talk_0.mp4"></video></center>'
	if wl_temp = 0 or wl_temp = 1:
		'"Miss <<$pcs_lastname>>, please come on in," he says and points at a chair in front of his desk. '+iif(wl_medical['timer_week'] = 2, '"I guess you aren''t here for your medical exam?"', '"Is it already time for your exam?"')+' You '+iif(wl_temp = 0, 'nod. "Yes, exactly."', 'shake your head and sit down. "No, but I''m not feeling very well."')
		'"Alright, '+iif(wl_temp = 1, 'let''s find out what the problem is. P', 'p')+'lease undress and sit down on the gynecological chair."'

		act 'Do it': gt 'mod_wlife_clinic', 'exam'
	elseif wl_temp = 2:
		'"Miss <<$pcs_lastname>>, please come on in," he says and points at a chair in front of his desk. '+iif(wl_medical['timer_week'] = 2, '"I guess you aren''t here for your medical exam?"', '"Is it already time for your exam?"')+' You shake your head and sit down. "No, I need an abortion. "No problem," he responds without batting an eye. "Please undress and sit down on the gynecological chair and we''ll quickly take care of that issue."'

		act 'Do it': gt 'mod_wlife_clinic', 'abortion'
	else
		Gspravka = 30
		GspravkaT = 1
		Gspassed = 1
		'"Miss <<$pcs_lastname>>, please come on in," he says and points at a chair in front of his desk. '+iif(wl_medical['timer_week'] = 2, '"I guess you aren''t here for your medical exam?"', '"Is it already time for your exam?"')+' You shake your head and sit down. "No, I need a referral for my mother that I''m still a virgin," you explain to him.'
		'"That won''t take long," he replies and grabs an empty form from his deck. He hands you the completed form, after checking the correct boxes and stamping the document to make it official. "Here you go."'

		act 'Take the referral and leave': gt 'pav_clinic'
	end
	killvar 'wl_temp'
end

if $ARGS[0] = 'exam':
	*clr & cla
	minut += 30
	wl_medical['timer_week'] = 2
	cumspclnt = 15
	gs 'cum_cleanup'
	$orgasm_or = 'no'
	gs 'arousal', 'vaginal_finger', -2
	gs 'arousal', 'anal_finger', -2
	'<center><video autoplay loop src="mod/wlife/images/locations/clinic/exam_'+wl_medical['picture']+iif(wl_medical['picture'] = 1 or wl_medical['picture'] > 3, rand(0,1), '')+'.mp4"></video></center>'
	'The whole examination takes roughly half an hour. First he cleans out your vagina, before he visually inspects your pussy lips and your anus. Afterwards he carefully inserts two fingers into your vagina to check for any irregularities and repeats the procedure with your anus. The next step consists of him inserting a speculum into your pussy to be able to have a look at your cervix. His touches don''t feel sexual, instead you get the feeling that he''s a professional who does his job to the best of his abilities and not someone to ogle and touch naked women.'

	if (wl_medical['picture'] < 5 and $wl_fetish['pissing'] = 'yes') or (wl_medical['picture'] < 4 and $wl_fetish['pissing'] = 'blocked') or wl_medical['status'] = 1:
		wl_medical['picture'] += 1
	else
		wl_medical['picture'] = 0
	end

	if wl_medical['status'] = 1:
		act 'Continue':
			*clr & cla
			wl_medical['status'] = 2
			'<center><video autoplay loop src="mod/wlife/images/locations/clinic/exam_piss_0.mp4"></video></center>'
			'"OK, we are nearly done. I only need a urine sample," he tells you and takes a big plastic box. Not really something you would have used for it, but at least the exam will be over soon. "Where is the bathroom?" you ask, but he shakes his head. "That won''t be necessary. You would have to get dressed and that would be a hassle. You can do it here," he explains and puts the box on the floor on top a small water absorbent mat.'
			'"Uhm..., what?" you ask and look horrified at the box on the floor. "You.. You want me to do it here?" He nods. "Sure, don''t worry. I won''t look," he reassures you.'
			'He can''t be serious. Your old gynecologist never expected you to squat down in the examination room and just pee into a box. He always gave you a small container to take into the bathroom. "No, no, no," you say and shake your head. "Please, let me take it to the bathroom. I''ll be quick."'
			'"I can''t let you do that. What if you switch out the sample with somebody else''s urine? I need to make sure that everything is properly examined. The Bely''s won''t tolerate any deception."'
			'"But what could I possibly hide from them?" you ask him while you keep looking at the plastic box on the floor. "You could for example hide a pregnancy from them."'

			'<br><font color="red">Content Warning: Pissing girl</font>'

			act 'Squat down':
				*clr & cla
				$wl_fetish['pissing'] = 'no'
				gs 'arousal', 'foreplay', 2, 'humiliation'
				gs 'stat'
				'<center><video autoplay loop src="mod/wlife/images/locations/clinic/exam_piss_1.mp4"></video></center>'
				'"Fine," you sigh and get of the gynecological chair. "But please, don''t look," you say and he turns around demonstratively. "Of course, I''m a professional Miss <<$pcs_lastname>>." You''re starting to seriously doubt that and squat down on the floor steading yourself with one hand on a nearby examination table.'
				'You can''t stop yourself from thinking about how humiliating this is and you can feel a blush creeping up your neck. One second passes, one more, ten more, but nothing happens. You look up, but he''s still looking at a nearby wall. He really isn''t watching, you think and relax a bit. This opens the flood gate and the first spurt of piss lands inside the box.'

				act 'Piss':
					*clr & cla
					gs 'arousal', 'foreplay', 2, 'humiliation'
					gs 'arousal', 'end'
					'<center><video autoplay loop src="mod/wlife/images/locations/clinic/exam_50.mp4"></video></center>'
					'There is nothing that could stop you once you have started. Your piss fills the box more and more, the feeling of shame subsides at the same rate as if you''re pissing it out of your body. A few seconds more and it will all be over. He can hear you do it, but since he wasn''t looking it''s not as bad as you had suspected. Near the end you take another look at Doctor Mikhailov and as promised he isn''t looking, because what he''s is doing can''t be described as looking. He''s staring at you. His hungry eyes are fixated on the urine that''s pouring out of you. "WHAT THE FUCK?!" you shout, but he doesn''t even flinch and keeps staring. "It''s alright Miss <<$pcs_lastname>>, you''re nearly done," he says calmly while your head turns red rapidly. "Please, look away," you plead, but he shakes his head as the last drops of urine land inside the box. "Why? You''re already finished," he says and takes a step towards you, before you can say anything else. "May I?" he asks and picks up the box without waiting for a response. He walks out of the room and leaves you behind shocked, confused and horrified.'
					*nl
					'You wipe your pussy clean and get dressed as you think about what happened. Should you say something or not? You ponder the question, but in the end you decide against it. He''s clearly in a position of power and could tell the Bely''s everything he wants.'
					*nl
					'"Everything alright?" he asks, when he returns. His professional attitude is back as if nothing has happened. "Sure, everything is fine," you reply and sit down next to his desk.'

					act 'Hear the results': gt 'mod_wlife_clinic', 'results'
				end
			end

			act '<font color="red">Block this type of content</font>':
				cla & *nl
				$wl_fetish['pissing'] = 'blocked'
				'Suddenly Doctor Mikhailov changes his mind and hands you a smaller plastic container. You quickly go to the bathroom, before handing him the sample and finish your examination.'

				act 'Get dressed and wait for the results': gt 'mod_wlife_clinic', 'results'
			end
		end
	else
		if $wl_fetish['pissing'] ! 'blocked':
			gs 'arousal', 'foreplay', iif($wl_fetish['pissing'] = 'no', -1, -8)
			'But the professionalism instantly vanishes again, when you have to supply another urine sample. His eyes are fixed on your pussy and especially on the urine that pours out of it. '+iif($wl_fetish['pissing'] = 'no', 'It''s an uncomfortable and humiliating experience you wish you didn''t have to go through.', 'It feels like his burning eyes are transferring their heat directly into your pussy and you can feel yourself getting aroused by getting watched.')
		end
		gs 'arousal', 'end'

		act 'Get dressed and wait for the results': gt 'mod_wlife_clinic', 'results'
	end
	gs 'stat'
end

if $ARGS[0] = 'results':
	*clr & cla
	$wl_medical['status'] = ''

	if cumcondslip > 0:
		minut += 5
		cumcondslip = 0
		$wl_medical['status'] = '"I found a condom inside you and removed it. If you were feeling sick, it should slowly subside," he explains. '
		gs 'cum_cleanup', 'cleanloc', 17
	end

	if venera > 0:
		$wl_medical['status'] += '"You'+iif($wl_medical['status'] ! '', ' also ', ' ')+'have a sexually transmitted disease," he takes a short pause to have a closer look at the results.'+iif(GerpesOnce = 1, ' "You have genital herpes'+iif(Gerpes > -3, '. Unfortunately, the complete cure for this disease is very expensive and I can''t cure it here. On the upside, herpes is dormant most of the time and is quite manageable, if you take good care of your body. I will give you a shot with a new drug that''s a bit more expensive than the old stuff, but more effective and you won''t have to wait several days, before it takes effect.', ', but it''s currently in it''s dormant state.')+'Taking vitamins regularly will make sure it won''t show itself.', '')+iif(SifacOnce = 1, ' You'+iif(GerpesOnce = 1, ' also ', ' ')+'have syphilis. The cure for this disease used to be expensive. However, this deadly disease can now be with a single shot. I''ll give it you after we are done here.', '')+iif(TriperOnce = 1, ' I'+iif(SifacOnce = 1 or GerpesOnce = 1, ' also ', ' ')+'found gonorrhea. Fortunately, I can cure this disease. I''ll give you something that will take care of it. It''s a bit more expensive than the usual stuff we hand out at the clinic, but it''s more potent and you won''t have to wait several days for your symptoms to subside.', '')+iif(KandidozOnce = 1, ' You'+iif(SifacOnce = 1 or GerpesOnce = 1 or TriperOnce = 1, ' also ', ' ')+'have thrush'+iif(Kandidoz > 25, '. Unfortunately, the complete cure for this disease is very expensive and we can''t cure it here. On the upside, thrush is not that harmful and can be treated easily to the point where it won''t trouble you. I''ll give you a pill that will take care of it for the moment. When it''s dormant, taking vitamins regularly will make sure it won''t show itself."', ', but it''s currently in it''s dormant state.'), '')
		iif(vitamin < 5 and (KandidozOnce = 1 or GerpesOnce = 1), '"Do you have some vitamins at home?" he asks. "'+iif(wl_vitamin = 0, 'No', 'Only a few')+'," you reply and shake your head at the same time. "OK, I''ll give you enough for the next month," he tells you', '')

		if GerpesOnce = 1:
			if Gerpes > -3:
				minut += 5
				GerpesNapr = 0
				Gerpes = rand(-15,-10)
				wl_total_price += 1650
			end
			if vitamin < 5: vitamin += 30 & wl_total_price += 130
		end

		if SifacOnce = 1:
			minut += 5
			SifNapr = 0
			SifacOnce = 0
			Sifilis = 0
			Venera -= 1
			wl_total_price += 1000
		end

		if TriperOnce = 1:
			minut += 5
			TriperNapr = 0
			TriperOral = 0
			TriperOnce = 0
			TriperOralSigns = 0
			Triper = 0
			Venera -= 1
			wl_total_price += 4250
		end

		if KandidozOnce = 1:
			if Kandidoz > 25:
				minut += 5
				Kandidoz = 0
				KandidNapr = 0
				wl_total_price += 1050
			end
			if vitamin < 5: vitamin += 30 & wl_total_price += 130
		end
	end

	if preg > 0:
		thinkpreg = 1
		knowpreg = 1
		if $wl_medical['status'] ! '': $wl_medical['status'] += '<br>'
		$wl_medical['status'] += 'He frowns for a moment, when he studies the result. "It seems you are pregnant Miss <<$pcs_lastname>>. '+iif($wl_status['abortions'] = 'yes', 'You know what that means, we should terminate it immediately so that it doesn''t become a problem and interferes with your work. Please get back on the chair."', 'If you want, we can terminate it today."')
	end
	gs 'stat'

	'<center><video autoplay src="mod/wlife/images/locations/clinic/talk_1.mp4"></video></center>'
	if $wl_medical['status'] = '':
		'"You''re perfectly healthy Miss <<$pcs_lastname>>," Doctor Mikhailov smiles, when he gives you the good news. "If you keep using protection'+iif(vitamin = 0, ' and maybe take a daily vitamin,', ',')+' it should stay this way."'
	else
		$wl_medical['status']
	end

	if SchoolAtestat = 0 and Gspravka < 3 and motherKnowSpravka = 0 and func('homes_properties', 'is_current_home', 'parents_home') ! 0:
		*nl
		minut += 5
		Gspravka = 30
		GspravkaT = 1
		Gspassed = 1
		'"I will also need a referral for my mother that I''m still a virgin," you explain to him.'
		'"That won''t take long," he replies and grabs an empty form from his deck. He hands you the completed form, after checking the correct boxes and stamping the document to make it official. "Here you go."'
	end

	if preg = 1 and pregchem < 1863 and $wl_status['abortions'] = 'yes':
		act 'Get back on the gynecological chair': gt 'mod_wlife_clinic', 'abortion'
	else
		act 'Get ready to leave': gt 'mod_wlife_clinic', 'payment'
		if preg = 1 and pregchem < 1863 and $wl_status['abortions'] = 'no':
			act 'Get an abortion': gt 'mod_wlife_clinic', 'abortion'
		elseif preg = 0 and birth_control['implant_status'] < 3 and tabletkishot < 5:
			act 'Talk with him about birth control': gt 'mod_wlife_clinic', 'birth_control'
		end
	end
end

if $ARGS[0] = 'abortion':
	*clr & cla
	minut += 30
	menu_off = 1
	wl_stats['abortions'] += 1
	wl_total_price += 15000
	gs 'mod_wlife_functions','abortion'
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/clinic/abortion.jpg"></center>'
	'You spread out on a gynecological chair, from which angle you''ll be able to see everything that''s going on. It takes roughly half an hour for Doctor Mikhailov to remove the fetus.'

	act 'Get ready to leave': gt 'mod_wlife_clinic', 'payment'
	if birth_control['implant_status'] < 3 and tabletkishot < 5: act 'Talk with him about birth control': gt 'mod_wlife_clinic', 'birth_control'
end

if $ARGS[0] = 'birth_control':
	*clr & cla
	'<center><video autoplay src="mod/wlife/images/locations/clinic/talk_1.mp4"></video></center>'
	if wl_medical['bc_talk'] = 0:
		wl_medical['bc_talk'] = 1
		'"I have a question about birth control," you say and with a quick gesture he tells you to continue. "Is there a method you can recommend?"'
		'He leans back into his chair and ponders the question for a moment. "You obviously should use condoms, because no other method protects you from STDs. If you want a backup to protect you from getting pregnant, you could either go with the pill, getting a shot or an implant. I personally would recommend the implant. It''s expensive in the short-run, but it''s cheaper in the long-run and you won''t have to worry about kids for three years. Most woman stop having their periods after some time, which could be an additional benefit in your situation. You also don''t have to worry about taking the pill every morning or renewing the shot every three months. I can insert the implant or give you the shot here. You would need to buy the pill at the pharmacy."'
	else
		'"I have a question about birth control," you say and with a quick gesture he tells you to continue.'
	end

	act 'Change your mind and get ready to leave': gt 'mod_wlife_clinic', 'payment'

	act 'Get a birth control shot for 2750 <b>₽</b> (0:15)':
		cla & *nl
		minut += 5
		wl_total_price += 2750
		gs 'medical_din','birthControlShot'
		gs 'stat'
		'"I take the shot," you say.'
		'"Alright, give me a second," he leaves his office and returns a few minutes later, before he gives you a reassuring smile as he sticks a needle in your arm, and depresses the plunger. Seconds later he explains. "All done! You should be good to go for three months, give or take. It depends a bit from person to person. Body type, hormone levels, and so on. If you want to be perfectly safe, I recommend you come back for another treatment one week before the three months are over and remember it doesn''t protect you from STDs"'

		act 'Get ready to leave': gt 'mod_wlife_clinic', 'payment'
	end

	act ''+iif(birth_control['implant_status'] = 0, 'Get a', 'Renew your')+' birth control implant for 19,650 <b>₽</b> (0:35)':
		cla & *nl
		minut += 35
		wl_total_price += 19650
		'"I take the implant," you say.'
		'"Alright, give me a second," he leaves his office and returns a few minutes later. "Please lie down, the procedure won''t take long," he says and points at the gynecological chair.'
		'He numbs part of your upper arm with a local anesthetic. You have to wait for a few minutes for it to take a effect, before he makes a tiny incision'+iif(birth_control['implant_status'] = 0, ' ', ', takes out your old implant ')+'and pushes a '+iif(birth_control['implant_status'] = 0, 'small tube', 'new implant')+' inside your arm. It isn''t bigger than a matchstick.'
		'"All done! You should be good to go for three years, but it will take a few days before you will be fully protected and remember it doesn''t protect you from STDs."'

		birth_control['implant_status'] = 3
		birth_control['implant_timer'] = 1095
		pillcon += ((pillcon + 15000) / 25) + 4000
		pillcon2 += ((pillcon2 + 15000) / 25) + 4000

		act 'Get ready to leave': gt 'mod_wlife_clinic', 'payment'
	end
end

if $ARGS[0] = 'payment':
	if wl_total_price = 0:
		minut += 3
		gt 'pav_clinic'
	else
		*clr & cla
		minut += 2
		gs 'stat'
		'<center><video autoplay src="mod/wlife/images/locations/clinic/talk_1.mp4"></video></center>'
		'"OK, that''s it," he says without looking up. He writes down some numbers. "You owe the clinic <<wl_total_price>> <b>₽</b>. How do you want to pay?"'

		act 'Let the Bely''s pay and increase your debt':
			cla & *nl
			wl_debt['amount'] += wl_total_price
			iif(karta + money < wl_total_price, '"I can''t afford it, the', '"The')+' Bely''s will have to pay for it," you reply. "Alright, I''ll send them the bill. Have a nice day Miss <<$pcs_lastname>>."'
			'"Thanks likewise Doctor Mikhailov," you say and leave his office.'

			act 'Continue':
				minut += 3
				killvar 'wl_total_price'
				gt 'pav_clinic'
			end
		end

		if karta + money >= wl_total_price:
			act 'Pay for it yourself':
				cla & *nl
				if karta >= wl_total_price:
					karta -= wl_total_price
				elseif money >= wl_total_price:
					money -= wl_total_price
				else
					wl_total_price -= karta
					karta = 0
					money -= wl_total_price
				end
				gs 'stat'
				'"Alright, have a nice day Miss <<$pcs_lastname>>," he wishes you after you paid your bill. "Likewise Doctor Mikhailov," you say and leave his office.'

				act 'Continue':
					minut += 3
					killvar 'wl_total_price'
					gt 'pav_clinic'
				end
			end
		end
	end
end

--- mod_wlife_clinic ---------------------------------