WLife-New/locations/mod_wlife_functions.qsrc

# mod_wlife_functions

!!Family Dog
if $ARGS[0] = 'rex_status':
	rex['timer_day'] = daystart

	!!Daily decay
	rex['relationship'] -= 1

	!!Chores
	if wl_cheat['dog_rel'] = 0 and rex['gadukino_day'] ! daystart:
		npc_rel['A29'] -= iif(rex['count_walk'] + rex['count_feed'] = 0, -1, (rex['count_walk'] + rex['count_feed']))
		rex['relationship'] -= iif(rex['count_walk'] + rex['count_feed'] = 0, -1, (rex['count_walk'] + rex['count_feed']))
	end
	rex['count_run'] = 0
	rex['count_walk'] = rex['count_walk_base']
	rex['timer_walk'] = 0
	rex['count_feed'] = rex['count_feed_base']
	rex['timer_feed'] = 0

	if week = 1:
		if wl_cheat['dog_rel'] = 0:
			npc_rel['A29'] -= rex['count_bath']
			rex['relationship'] -= (rex['count_bath'] * 5)
		end
		rex['count_bath'] = rex['count_bath_base']
	end

	!!Love
	if rex['love'] >= 100 or wl_cheat['dog_rel'] = 1:
		rex['relationship'] = 100
	elseif rex['relationship'] < 20:
		rex['love'] -= 1
	elseif rex['relationship'] < 40:
		rex['love'] -= rand(0,1)
	elseif rex['relationship'] < 60:
		rex['love'] += rand(0,1)
	elseif rex['relationship'] < 80:
		rex['love'] += 1
	else
		rex['love'] += rand(1,2)
	end

	if rex['love'] > 100 or wl_cheat['dog_rel'] = 1:
		rex['love'] = 100
	elseif rex['love'] < -100:
		rex['love'] = -100
	end
end

!!Cocaine
if $ARGS[0] = 'cocaine':
	if dur > 0 and narkday ! daystart:
		act 'Do a line of cocaine (0:05)':
			*clr & cla
			menu_off = 1
			narkday = daystart
			gs 'drugs', 'cocaine'
			minut += 5
			gs 'stat'
			'<center><img <<$set_imgh>> src="mod/wlife/images/player/cocaine.jpg"></center>'
			'You snort some cocaine, feeling dizzy for just a moment. After that you feel fantastic, horny and full of energy.'

			act 'Continue': gt $loc, $loc_arg
		end
	end
end

!!Willpower
if $ARGS[0] = 'will_unprotected':
	gs 'willpower', 'calc'
	will_cost = 0
	if missCum >= timeTresh: will_calc += 100
	if $ARGS[1] = 'resist':
		if wl_stats['unprotected'] <= 90:
			will_cost = (10 + wl_stats['unprotected'] + will_calc) / 10
		else
			will_cost = (100 + will_calc)/10
		end
	else
		if wl_stats['unprotected'] <= 90:
			will_cost = (100 - wl_stats['unprotected'] + will_calc) / 10
		else
			will_cost = (10 + will_calc)/10
		end
	end
	gs 'willpower', 'difficulty', '<<$ARGS[2]>>'
end

if $ARGS[0] = 'will_rimming':
	gs 'willpower', 'calc'

	if $ARGS[1] = 'self':
		if stat['rimming_give'] <= 90:
			will_cost = (100 - stat['rimming_give'] + will_calc)/10
		else
			will_cost = (10 + will_calc)/10
		end
	elseif $ARGS[1] = 'force':
		if stat['rimming_give'] <= 40:
			will_cost = (110 - will_enforced - stat['rimming_give'] + will_calc)/10
		else
			will_cost = (70 - will_enforced + will_calc)/10
		end
	else
		if stat['rimming_give'] <= 90:
			will_cost = (10 + stat['rimming_give'] + will_calc)/10
		else
			will_cost = (100 + will_calc)/10
		end
	end
	gs 'willpower', 'difficulty', '<<$ARGS[2]>>'
end

if $ARGS[0] = 'will_atm':
	gs 'willpower', 'calc'

	if $ARGS[1] = 'self':
		if wl_stats['atm'] <= 90:
			will_cost = (100 - wl_stats['atm'] + will_calc)/10
		else
			will_cost = (10 + will_calc)/10
		end
	elseif $ARGS[1] = 'force':
		if wl_stats['atm'] <= 40:
			will_cost = (110 - will_enforced - wl_stats['atm'] + will_calc)/10
		else
			will_cost = (70 - will_enforced + will_calc)/10
		end
	else
		if wl_stats['atm'] <= 90:
			will_cost = (10 + wl_stats['atm'] + will_calc)/10
		else
			will_cost = (100 + will_calc)/10
		end
	end
	gs 'willpower', 'difficulty', '<<$ARGS[2]>>'
end

if $ARGS[0] = 'will_acceptance':
	if $ARGS[1] = 'resist':
		if wl_stats['acceptance'] > 60:
			gs 'willpower', 'prostitution', 'resist', 'hard'
		elseif wl_stats['acceptance'] > 30:
			gs 'willpower', 'prostitution', 'resist', 'medium'
		else
			gs 'willpower', 'prostitution', 'resist', 'easy'
		end
	elseif $ARGS[1] = 'force':
		if wl_stats['acceptance'] < 20:
			gs 'willpower', 'prostitution', 'force', 'hard'
		elseif wl_stats['acceptance'] < 40:
			gs 'willpower', 'prostitution', 'force', 'medium'
		else
			gs 'willpower', 'prostitution', 'force', 'easy'
		end
	else
		if wl_stats['acceptance'] < 20:
			gs 'willpower', 'prostitution', 'self', 'hard'
		elseif wl_stats['acceptance'] < 40:
			gs 'willpower', 'prostitution', 'self', 'medium'
		else
			gs 'willpower', 'prostitution', 'self', 'easy'
		end
	end
end

!! Condoms & STDs
if $ARGS[0] = 'std_check':
	wl_std_check_rand = rand(0,10)
	if protect = 1:
		wl_std_rand = rand(0,1000)
		if wl_std_rand = 1000: gs 'mod_wlife_functions' , 'std_chance'
	else
		if $ARGS[1] = 'high':
			wl_std_rand = rand(-20,120)
		else
			wl_std_rand = rand(-60,100)
		end
		if wl_std_rand >= 80: gs 'mod_wlife_functions' , 'std_chance'
	end
end

if $ARGS[0] = 'std_chance':
	if cheatHealth = 0:
		if wl_std_check_rand = 8:
			!!herpes
			if rand(1, 100) > 90:
				if GerpesOnce = 0:
					GerpesOnce = 1
					Venera += 1
					Gerpes += 1
					GenHerpes = 1
				end
			end
		elseif wl_std_check_rand = 7:
			!!syphilis
			if rand(1, 100) > 95: Venera += 1
			if SifacOnce = 0:
				SifacOnce = 1
				Sifilis += 1
			end
		elseif wl_std_check_rand >= 5 and wl_std_check_rand < 7:
			!!gonorrhea/triper
			if rand(1, 100) > 95: Venera += 1
			if TriperOnce = 0:
				TriperOnce = 1
				Triper += 1
			end
		elseif wl_std_check_rand < 5:
			!!candidiasis/thrush
			if rand(1, 100) > 85:
				if KandidozOnce = 0:
					KandidozOnce = 1
					Kandidoz += 1
				end
			end
		end
	end
end

if $ARGS[0] = 'std_check_oral':
	wl_std_check_rand = rand(0,10)
	if protect = 1:
		wl_std_rand = rand(0,1000)
		if wl_std_rand = 1000: gs 'mod_wlife_functions' , 'std_oral_chance'
	else
		if $ARGS[1] = 'high':
			wl_std_rand = rand(-20,120)
		elseif $ARGS[1] = 'low':
			wl_std_rand = rand(-80,90)
		else
			wl_std_rand = rand(-60,100)
		end
		if wl_std_rand >= 80: gs 'mod_wlife_functions' , 'std_oral_chance'
	end
end

if $ARGS[0] = 'std_oral_chance':
	if cheatHealth = 0:
		if wl_std_check_rand >= 5 and wl_std_check_rand < 7:
			if rand(1, 100) > 95: Venera += 1
			if TriperOnce = 0:
				TriperOnce = 1
				TriperOral += 1
				if rand (0,100) < 15: TriperOralSigns = 1
			end
		elseif wl_std_check_rand = 7:
			if rand(0,1) = 1:
				!!syphilis
				if rand(1, 100) > 95: Venera += 1
				if SifacOnce = 0:
					SifacOnce = 1
					Sifilis += 1
				end
			end
		elseif wl_std_check_rand < 5:
			!!candidiasis/thrush
			if rand(1, 100) > 85:
				if KandidozOnce = 0:
					KandidozOnce = 1
					Kandidoz += 1
				end
			end
		elseif wl_std_check_rand = 8:
			!!herpes
			if rand(1, 100) > 90:
				if GerpesOnce = 0:
					GerpesOnce = 1
					Venera += 1
					Gerpes += 1
					OrHerpes = 1
				end
			end
		end
	end
end

if $ARGS[0] = 'remove_condom':
	if prezik > 0:
		prezik -= 1
	else
		prezikcount -= 1
	end
end

if $ARGS[0] = 'your_condom':
	wl_whore['condom'] = 1
	protect = iif(prezik > 0,1,0)
	if prezik > 0:
		if rand(1,prezik) <= badprezik:
			badprezik -= 1
			noprotect = 1
			sexcontra = 7
		else
			sexcontra = 3
		end
		prezik -= 1
		sexcontra = iif(preziktype = 2,7,sexcontra)
	else
		sexcontra = 0
	end
end

if $ARGS[0] = 'his_condom':
	$bwa_boy = iif($ARGS[1] = '',$boydesc,$ARGS[1])
	protect = 1
	sexcontra = 3
	*p '<<ucase(mid($bwa_boy,1,1))>><<mid($bwa_boy,2,len($bwa_boy)-1)>> takes his condom and puts it on his <<dick>> centimeter dick.'
end

!!Acceptance
if $ARGS[0] = 'acceptance_check':
	if wl_stats['acceptance'] < 20:
		if $ARGS[1] = 'normal':
			pcs_mood -= 20
		else
			pcs_mood -= 10
		end
	elseif wl_stats['acceptance'] >= 20 and wl_stats['acceptance'] < 40:
		if $ARGS[1] = 'normal':
			pcs_mood -= 10
		else
			pcs_mood -= 5
		end
	elseif wl_stats['acceptance'] >= 40 and wl_stats['acceptance'] < 60 and $ARGS[1] = 'normal':
		pcs_mood -= 5
	elseif wl_stats['acceptance'] >= 60 and $ARGS[1] = 'regular':
		pcs_mood += 5
	end
end

!!Background: Black
if $ARGS[0] = 'darkness':
	fcolor = rgb(255, 255, 255)
	bcolor = rgb(0, 0, 0)
	lcolor = rgb(106, 90, 205)
end

if $ARGS[0] = 'parameters':
	!!Reset
	protect = 0
	sexcontra = 0
	$wl_client_condom = 'tbd'
	$wl_client_cumshot = 'tbd'

	!!Client
	gs 'npcgeneratec', 0, 'client', rand(18,65)
	gs 'boyStat', $npclastgenerated

	!!Time
	if hour > 19 or hour < 7:
		$wl_work_time = 'night'
	else
		$wl_work_time = 'day'
	end

	gs 'mod_wlife_functions', 'std_cum_check'

	!!Client Likes/Dislikes
	if rand(1,10) = 10:
		wl_whore['mesec_mod'] = 1
	else
		wl_whore['mesec_mod'] = 0
	end

	if rand(1,100) > 97:
		wl_whore['dirty_anal_mod'] = 1
	else
		wl_whore['dirty_anal_mod'] = 0
	end

	if rand(1,10) = 10:
		wl_whore['cum_visible_mod'] = 1
	else
		wl_whore['cum_visible_mod'] = 0
	end

	!!Age
	if vidage < 18 and rand(1,10) < 7:
		wl_whore['vidage_mod'] = 1
	else
		wl_whore['vidage_mod'] = 0
	end

	!!Scene
	wl_scene_rand = rand(1,100)

	if wl_scene_rand <= 50:
		if mesec = 0 or wl_whore['mesec_mod'] = 1:
			$wl_whore['client_scene'] = 'Vaginal'
		elseif mesec > 0 and wl_whore['mesec_mod'] = 0 and (wl_whore['enema'] = 1 or wl_whore['dirty_anal_mod'] = 1):
			$wl_whore['client_scene'] = 'Anal'
		else
			$wl_whore['client_scene'] = 'Blowjob'
		end
	elseif wl_scene_rand > 50 and wl_scene_rand <= 75:
		if wl_whore['enema'] = 1 or wl_whore['dirty_anal_mod'] = 1:
			$wl_whore['client_scene'] = 'Anal'
		elseif wl_whore['enema'] = 0 and wl_whore['dirty_anal_mod'] = 0 and (mesec = 0 or wl_whore['mesec_mod'] = 1):
			$wl_whore['client_scene'] = 'Vaginal'
		else
			$wl_whore['client_scene'] = 'Blowjob'
		end
	else
		$wl_whore['client_scene'] = 'Blowjob'
	end

	!!Regular Worker
	if wl_whore['customer_total'] < 10:
		wl_whore['regular_chance'] = 0
	elseif wl_whore['customer_total'] >= 10 and wl_whore['customer_total'] <= 25:
		wl_whore['regular_chance'] = 1
	elseif wl_whore['customer_total'] > 25 and wl_whore['customer_total'] <= 50:
		wl_whore['regular_chance'] = 2
	elseif wl_whore['customer_total'] > 50 and wl_whore['customer_total'] <= 100:
		wl_whore['regular_chance'] = 3
	elseif wl_whore['customer_total'] > 100 and wl_whore['customer_total'] <= 250:
		wl_whore['regular_chance'] = 4
	end

	!!Chance to find a client
	wl_whore['client_chance'] = hotcat * 10 + wl_whore['regular_chance'] * 5 + rand(1,100) + wl_whore['pity_counter']
	if $pantyworntype = 'sexshop' and CloSkirtShortness > 4: wl_whore['client_chance'] += 10

	!!Client
	if wl_whore['regular_timer'] ! daystart and $wl_whore['client_scene'] ! 'Blowjob':
		if (wl_whore['regular_chance'] = 1 and rand(1,100) > 95) or (wl_whore['regular_chance'] = 2 and rand(1,100) > 90) or (wl_whore['regular_chance'] = 3 and rand(1,100) > 80) or (wl_whore['regular_chance'] = 4 and rand(1,100) > 60):
			wl_whore['regular'] = 1
		else
			wl_whore['regular'] = 0
		end
	else
		wl_whore['regular'] = 0
	end

!!ToDo: Rough Clients
!!	if wl_whore['regular'] = 0:
!!		if (wl_work_day = 0 and rand(1,100) > 90) or (wl_work_day = 1 and rand(1,100) > 95):
!!			if wl_whore['rough'] = 1
!!		else
!!			wl_whore['rough'] = 0
!!		end
!!	end

	if wl_whore['regular'] = 0 and wl_whore['rough'] = 0 and wl_whore['std_mod'] = 0 and rand(1,100) > iif($wl_brand['text_pubic'] = 'cumslut', 84, 92):
		wl_whore['client_creampie'] = 1
	else
		wl_whore['client_creampie'] = 0
	end

	if wl_whore['rough'] = 1 or (wl_whore['rough'] = 0 and rand(1,100) > 40):
		wl_whore['propose'] = 0
	else
		wl_whore['propose'] = 1
	end
end

if $ARGS[0] = 'payment':
	!!Basic Payment
	if $ARGS[1] = 'pav':
		if $wl_whore['pav_scene'] = 'blowjob':
			wl_whore['payment'] = 425
		elseif $wl_whore['pav_scene'] = 'anal':
			wl_whore['payment'] = 1200
		else
			wl_whore['payment'] = 1000
		end
	else
		if $wl_whore['client_scene'] = 'Blowjob':
			wl_whore['payment'] = 350
			if $ARGS[1] = 'condom_no': wl_whore['payment'] += 75
			if $ARGS[2] = 'inside_yes': wl_whore['payment'] += 50
		elseif $wl_whore['client_scene'] = 'Vaginal':
			wl_whore['payment'] = 700
			if $ARGS[1] = 'condom_no': wl_whore['payment'] += 300
			if $ARGS[2] = 'inside_yes': wl_whore['payment'] += 300
		elseif $wl_whore['client_scene'] = 'Anal':
			wl_whore['payment'] = 900
			if $ARGS[1] = 'condom_no': wl_whore['payment'] += 200
			if $ARGS[2] = 'inside_yes': wl_whore['payment'] += 100
		end
	end

	!!Bonus
	wl_whore['payment_mod'] = hotcat * 10
	if pcs_makeup = 0:
		wl_whore['payment_mod'] -= 20
	elseif pcs_makeup > 1:
		wl_whore['payment_mod'] += pcs_makeup * 10
	end

	if mesec > 0 and $wl_whore['client_scene'] = 'Vaginal':
		if wl_whore['mesec_mod'] = 0:
			wl_whore['payment_mod'] -= 200
		else
			wl_whore['payment_mod'] += 300
		end
	end

	if wl_whore['enema'] = 0 and $wl_whore['client_scene'] = 'Anal':
		if wl_whore['dirty_anal_mod'] = 0:
			if $ARGS[1] = 'condom_no':
				wl_whore['payment_mod'] -= 600
			elseif $ARGS[1] = 'condom_yes':
				wl_whore['payment_mod'] -= 300
			end
		else
			wl_whore['payment_mod'] += 300
		end
	end

	if wl_whore['cum_dressed'] = 1:
		if wl_whore['cum_visible_mod'] = 0:
			wl_whore['payment_mod'] -= 200
		else
			wl_whore['payment_mod'] += 300
		end
	end

	wl_whore['payment_mod'] += pcs_mood - 50

	if $pantyworntype = 'sexshop' and CloSkirtShortness > 4: wl_whore['payment_mod'] += 50

	if wl_whore['vidage_mod'] = 1:
		wl_whore['payment_mod'] += 50 * (18 - vidage)
	else
		wl_whore['payment_mod'] -= 50 * (18 - vidage)
	end

	if ($wl_whore['client_scene'] = 'Blowjob') or ($wl_whore['pav_scene'] = 'blowjob'):
		wl_whore['payment_mod'] = wl_whore['payment_mod'] / 2
		if pirsA = 2:
			wl_whore['payment_mod'] += 50
		elseif pirsA = 4:
			wl_whore['payment_mod'] += 75
		elseif pirsA > 0 and pirsA < 10000:
			wl_whore['payment_mod'] += 25
		end
	end
	wl_whore['payment'] += wl_whore['payment_mod']
	wl_whore['payment_backup'] = wl_whore['payment']

	!!Client Satisfaction
	wl_whore['payment'] = (wl_whore['payment'] * (100 + wl_whore['client_satisfaction'])) / 100

	!!Rounding
	wl_whore['payment'] = func('mod_wlife_functions', 'exact_round', wl_whore['payment'], 10)
	wl_whore['payment_backup'] = func('mod_wlife_functions', 'exact_round', wl_whore['payment_backup'], 10)
end

if $ARGS[0] = 'reputation_check':
	if wl_stats['loyalty'] < -100:
		wl_stats['loyalty'] = -100
	elseif wl_stats['loyalty'] > 100:
		wl_stats['loyalty'] = 100
	end

	if wl_stats['loyalty'] < -60:
		$wl_stats['loyalty'] = 'illoyal'
	elseif wl_stats['loyalty'] < -40:
		$wl_stats['loyalty'] = 'untrustworthy'
	elseif wl_stats['loyalty'] < -20:
		$wl_stats['loyalty'] = 'unreliable'
	elseif wl_stats['loyalty'] < 20:
		$wl_stats['loyalty'] = 'unproven'
	elseif wl_stats['loyalty'] < 40:
		$wl_stats['loyalty'] = 'reliable'
	elseif wl_stats['loyalty'] < 60:
		$wl_stats['loyalty'] = 'trustworthy'
	else
		$wl_stats['loyalty'] = 'loyal'
	end

	if wl_stats['respect'] < -100:
		wl_stats['respect'] = -100
	elseif wl_stats['respect'] > 100:
		wl_stats['respect'] = 100
	end

	if wl_stats['respect'] < -60:
		$wl_stats['respect'] = 'whore'
	elseif wl_stats['respect'] < -30:
		$wl_stats['respect'] = 'slut'
	elseif wl_stats['respect'] < 30:
		$wl_stats['respect'] = 'chick'
	elseif wl_stats['respect'] < 60:
		$wl_stats['respect'] = 'girl'
	else
		$wl_stats['respect'] = 'woman'
	end

	if wl_stats['loyalty'] < -60:
		wl_debt['interest'] = 100
		wl_debt['weekly_interest'] = 15
		$wl_debt['interest'] = '<br>He doesn''t trust you at all and demands na interest rate of <<wl_debt[''interest'']>>%.'
	elseif wl_stats['loyalty'] < -40:
		wl_debt['interest'] = 60
		wl_debt['weekly_interest'] = 15
		$wl_debt['interest'] = '<br>He doesn''t trust you and demands an interest rate of <<wl_debt[''interest'']>>%.'
	elseif wl_stats['loyalty'] < -20:
		wl_debt['interest'] = 40
		wl_debt['weekly_interest'] = 10
		$wl_debt['interest'] = '<br>He''s skeptical about trusting you and demands an interest rate of <<wl_debt[''interest'']>>%.'
	elseif wl_stats['loyalty'] < 20:
		wl_debt['interest'] = 25
		wl_debt['weekly_interest'] = 10
		$wl_debt['interest'] = '<br>He''s a bit skeptical about trusting you and demands an interest rate of <<wl_debt[''interest'']>>%.'
	elseif wl_stats['loyalty'] < 40:
		wl_debt['interest'] = 15
		wl_debt['weekly_interest'] = 5
		$wl_debt['interest'] = '<br>He trusts you and only demands an interest rate of <<wl_debt[''interest'']>>%.'
	else
		wl_debt['interest'] = 10
		wl_debt['weekly_interest'] = 5
		$wl_debt['interest'] = '<br>He trusts you a lot and only demands an interest rate of <<wl_debt[''interest'']>>%.'
	end
end

if $ARGS[0] = 'abortion':
	abort += 1
	abortionbirthdate = daystart

	gs 'medical_din', 'remove_preg'
	knowpregloss = 2

	abortrand = rand(0, 10)
	if age > 18:
		if abortrand < 10:sterilewb += 1
		if abortrand = 10:sterilewb += 10
	else
		if abortrand < 7:sterilewb += 2
		if abortrand >= 7:sterilewb += 10
	end
	killvar 'abortrand'

	pcs_hydra += 20

	if broodcurse > 0: over = 13 & gt'gameover'
end

if $ARGS[0] = 'random_name':

	$wl_boyname[1] = ''
	$wl_boyname[2] = ''

	:wl_rng_jump

	wl_temp = rand(0,23)

	if wl_temp = 0:
		$wl_temp = 'Abram'
	elseif wl_temp = 1:
		$wl_temp = 'Alexei'
	elseif wl_temp = 2:
		$wl_temp = 'Adrian'
	elseif wl_temp = 3:
		$wl_temp = 'Dima'
	elseif wl_temp = 4:
		$wl_temp = 'Dimitri'
	elseif wl_temp = 5:
		$wl_temp = 'Igor'
	elseif wl_temp = 6:
		$wl_temp = 'Leonid'
	elseif wl_temp = 7:
		$wl_temp = 'Petka'
	elseif wl_temp = 8:
		$wl_temp = 'Michail'
	elseif wl_temp = 9:
		$wl_temp = 'Vasily'
	elseif wl_temp = 10:
		$wl_temp = 'Oleg'
	elseif wl_temp = 11:
		$wl_temp = 'Olezka'
	elseif wl_temp = 12:
		$wl_temp = 'Pasha'
	elseif wl_temp = 13:
		$wl_temp = 'Pavel'
	elseif wl_temp = 14:
		$wl_temp = 'Sacha'
	elseif wl_temp = 15:
		$wl_temp = 'Slava'
	elseif wl_temp = 16:
		$wl_temp = 'Ruslan'
	elseif wl_temp = 17:
		$wl_temp = 'Taras'
	elseif wl_temp = 18:
		$wl_temp = 'Timofey'
	elseif wl_temp = 19:
		$wl_temp = 'Vanya'
	elseif wl_temp = 20:
		$wl_temp = 'Viktor'
	elseif wl_temp = 21:
		$wl_temp = 'Vladimir'
	elseif wl_temp = 22:
		$wl_temp = 'Yaromir'
	elseif wl_temp = 23:
		$wl_temp = 'Yevgeni'
	end

	if $wl_boyname[1] = '':
		$wl_boyname[1] = $wl_temp
		jump 'wl_rng_jump'
	elseif $wl_boyname[2] = '':
		$wl_boyname[2] = $wl_temp
	end

	if $wl_boyname[1] = $wl_boyname[2]:
		$wl_boyname[2] = ''
		jump 'wl_rng_jump'
	end

	killvar 'wl_temp'
	killvar '$wl_temp'
end

if $ARGS[0] = 'weed_check':
	gs 'drugs', 'joint'
	wl_drugs['counter_weed'] += 1
	if wl_drugs['counter_weed'] > rand(2,5) and wl_stats['acceptance'] < 100:
		wl_drugs['counter_weed'] = 0
		wl_stats['acceptance'] += 1
		'<br>Your life isn''t so bad, isn''t it? You tell yourself. Shura was right. Sometimes it''s just better to accept what''s happening and not give a shit about it.'
	end
end

if $ARGS[0] = 'tat_pierce_count':
	tattCount = 0

	if tatarm >= 1: tattCount += 1
	if tatass >= 1:	tattCount += 1
	if tatback >= 1: tattCount += 1
	if tatblly >= 1: tattCount += 1
	if tatbrst >= 1: tattCount += 1
	if tatchst >= 1: tattCount += 1
	if tatfce >= 1:	tattCount += 1
	if tatankle >= 1: tattCount += 1
	if tatleg >= 1:	tattCount += 1
	if tatlip >= 1:	tattCount += 1
	if tatneck >= 1: tattCount += 1
	if tatvag >= 1: tattCount += 1
	if tatlech >= 1: tattCount += 1
	if tatside >= 1: tattCount += 1
	if tatupb >= 1: tattCount += 1
	if tatunder >= 1: tattCount += 1
	if tatwrist >= 1: tattCount += 1
	if tathand >= 1: tattCount += 1

	pierWearCount = 0

	if pirsA > 0 and pirsA ! 10000:	pierWearCount += 1
	if pirsB > 0 and pirsB ! 10000:	pierWearCount += 1
	if pirsC > 0 and pirsC ! 10000:	pierWearCount += 1
	if pirsD > 0 and pirsD ! 10000:	pierWearCount += 1
	if pirsE > 0 and pirsE ! 10000:	pierWearCount += 1
	if pirsF > 0 and pirsF ! 10000:	pierWearCount += 1
	if pirsG > 0 and pirsG ! 10000:	pierWearCount += 1
	if pirsN > 0 and pirsN ! 10000:	pierWearCount += 1
end

if $ARGS[0] = 'pav_client':
	!!Reset
	wl_whore['pav_internal'] = 0

	gs 'mod_wlife_functions', 'std_cum_check'

	!!Regular
	if wl_whore['pav_total'] < 10:
		wl_whore['pav_chance'] = 0
	elseif wl_whore['pav_total'] >= 10 and wl_whore['pav_total'] <= 25:
		wl_whore['pav_chance'] = 1
	elseif wl_whore['pav_total'] > 25 and wl_whore['pav_total'] <= 50:
		wl_whore['pav_chance'] = 2
	elseif wl_whore['pav_total'] > 50 and wl_whore['pav_total'] <= 100:
		wl_whore['pav_chance'] = 3
	elseif wl_whore['pav_total'] > 100 and wl_whore['pav_total'] <= 250:
		wl_whore['pav_chance'] = 4
	end

	if ((wl_whore['pav_chance'] = 1 and rand(1,100) > 95) or (wl_whore['pav_chance'] = 2 and rand(1,100) > 90) or (wl_whore['pav_chance'] = 3 and rand(1,100) > 80) or (wl_whore['pav_chance'] = 4 and rand(1,100) > 60)) and (wl_rand ! 8 or (wl_rand = 8 and wl_whore['pav_regular_s8'] = 1)):
		wl_whore['pav_regular'] = 1
!!	elseif wl_whore['pav_chance'] > 0 and rand(1,100) > 92:
!!		wl_whore['pav_regular'] = -1
	else
		wl_whore['pav_regular'] = 0
	end

!!ToDo: Add cheat for this chance
	$wl_whore['client_behavior'] = iif(rand(1,100) < wl_whore['client_behavior_chance'] or wl_whore['pav_regular'] = -1, 'nice', 'abusive')

	!!Scene
	if wl_rand > 7:
		$wl_whore['pav_scene'] = 'anal'
	elseif mesec = 0 and rand(0,100) < 50:
		$wl_whore['pav_scene'] = 'pussy'
	else
		$wl_whore['pav_scene'] = 'blowjob'
	end

	if wl_rand = 0 or wl_rand = 8 or wl_rand = 9 or ((wl_rand = 2 or wl_rand = 3 or (wl_rand = 5 and $wl_whore['client_behavior'] = 'nice') or wl_rand = 6 or wl_rand = 7) and $wl_whore['pav_scene'] = 'pussy'):
		$wl_whore['pav_location'] = 'private'
		if wl_rand = 3 or wl_rand = 8: $wl_whore['client_behavior'] = 'abusive'
	elseif wl_rand = 1 and $wl_whore['pav_scene'] = 'pussy':
		$wl_whore['pav_location'] = iif($wl_whore['client_behavior'] = 'nice', 'private', 'public')
	elseif ((wl_rand = 2 or wl_rand = 3 or wl_rand = 6 or wl_rand = 7) and $wl_whore['pav_scene'] = 'blowjob') or wl_rand = 4 or wl_rand = 5:
		$wl_whore['pav_location'] = 'public'
		if wl_rand = 5: $wl_whore['client_behavior'] = 'abusive'
	else
		gt 'mod_wlife_solicitation', 'rng'
	end

	if wl_whore['pav_regular_s8'] = 1 and wl_rand = 8: wl_whore['pav_regular'] = 1

	if (wl_rand = 3 or wl_rand = 8) and $wl_whore['pav_scene'] = 'private' and wl_whore['pav_regular'] = 1:
		wl_whore['pav_condom_refusal'] = 1
	else
		wl_whore['pav_condom_refusal'] = 0
	end

	!!Generator
	gs 'npcgeneratec', 0, 'pavlovsk client', rand(18,45)
	gs 'boyStat', $npclastgenerated
end

if $ARGS[0] = 'std_cum_check':
	!!STD
	if pcs_apprnc = -10 and rand(1,10) < 8:
		wl_whore['std_mod'] = 1
	else
		wl_whore['std_mod'] = 0
	end

	!!Non-Visible Cum
	if cumloc[0] = 1:
		wl_whore['cum_vaginal_mod'] = 1
	else
		wl_whore['cum_vaginal_mod'] = 0
	end

	if cumloc[3] = 1:
		wl_whore['cum_anal_mod'] = 1
	else
		wl_whore['cum_anal_mod'] = 0
	end

	!!Visible Cum (Dressed)
	if cumloc[7] = 1 or cumloc[11] = 1 or cumloc[13] = 1 or cumloc[15] = 1:
		wl_whore['cum_dressed'] = 1
	else
		wl_whore['cum_dressed'] = 0
	end

	!!Visible Cum (Undressed)
	if cumloc[1] = 1 or cumloc[4] = 1 or cumloc[8] = 1 or cumloc[14] = 1 or cumloc[16] = 1:
		wl_whore['cum_undressed'] = 1
	else
		wl_whore['cum_undressed'] = 0
	end
end

if $ARGS[0] = 'exact_round':
	!! ARGS[1] = value you want divided
	!! ARGS[2] = divider
	!!  func('mod_wlife_functions','exact_round', number, divider)
	!!  func('mod_wlife_functions','exact_round', 12345, 7)
	if ARGS[2] ! 0:
		round_number = ARGS[1]/ARGS[2]
		if (ARGS[2] mod 2 ! 0 and ARGS[1] mod ARGS[2] > ARGS[2]/2) or (ARGS[2] mod 2 = 0 and ARGS[1] mod ARGS[2] >= ARGS[2]/2): round_number += 1
		round_number = round_number * ARGS[2]
		result = round_number
		killvar 'round_number'
	else
		'<b>Developer Note: No division by 0. Please report this and some text from the mainscreen as a bug in the whore life thread.</b>'
	end
end

--- mod_wlife_functions ---------------------------------