# mod_wlife_warehouse

$loc = 'mod_wlife_warehouse'
$locM = 'mod_wlife_warehouse'
$menu_loc = 'mod_wlife_warehouse'

if $ARGS[0] = 'street':	
	$metka = 'street'
	$menu_arg = 'street'
	menu_off = 0
	
	$location_type = 'public_outdoors'

	*clr & cla
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/warehouse/street_'+iif(daystage = 5, 'night', 'day')+'.jpg"></center>'
	'Vadim Bely''s old warehouse is in a remote part of the industrial area. One of the most run-down parts of Pavlovsk. The house next to it is also part of his operation, but the only entrance is inside the warehouse.'
		
	act 'Go back to the industrial area': minut += 5 & gt 'pav_industrial'

	if (week = 7 and hour > 19) or (week = 1 and hour < 6):
		'<br>Several windows of the house and the warehouse are lit, some members of the gang must be inside.'
		if week = 7 and wl_georgiy['timer_day'] ! daystart:
			if wl_shura['status'] < 11: iif(wl_shura['status'] > 0, 'Shura', 'A guy')+' is sitting outside the warehouse smoking a cigarette. '+iif(wl_shura['status'] > 0, '"Georgiy is waiting for you inside," he says pointing at the door.', 'He completely ignores you.')
			
			act 'Go inside the warehouse': minut += 1 & gt 'mod_wlife_warehouse', 'warehouse'
		elseif wl_georgiy['timer_day'] >= (daystart - 1) and wl_shura['status'] < 11:
			gs 'mod_wlife_warehouse', 'shura_actions'
		end	
	elseif week < 7 and wl_iosif['status'] = 0:
		act 'Go inside the warehouse': gt 'mod_wlife_iosif', 'first_meet'
	elseif ((week = 2 and hour > 19) or (week = 3 and hour < 6)) and wl_shura['status'] > 1 and wl_shura['status'] < 11:
		gs 'mod_wlife_warehouse', 'shura_actions'
	elseif ((week = 2 and hour > 19) or (week = 3 and hour < 6)) and wl_shura['status'] = 11 and wl_shura['ignore_day'] ! daystart:
		wl_shura['ignore_day'] = daystart
		if wl_shura['ignore_counter'] < 3 and wl_shura['ignore_day'] ! daystart:
			wl_shura['ignore_counter'] += 1
			'<br>Shura is nowhere to be seen.'	
		elseif wl_shura['ignore_counter'] < 6:
			wl_shura['ignore_counter'] += 1
			'<br>There''s still no sign of Shura outside the warehouse.'
		elseif wl_shura['ignore_counter'] < 7:
			'<br>Still no Shura in sight. Maybe you should ask somebody if something happened to him?'
		elseif wl_shura['ignore_counter'] = 7:
			wl_shura['status'] = 12
			'<br><b>Developer Note: Shura will return, but for now he doesn''t want to talk to you</b>.'
		end
	elseif week < 7 and wl_iosif['status'] > 0:
		'You aren''t allowed to go inside the warehouse except for your weekly check-in with Georgiy.'
	else
		'<br>There is nobody outside and the entrance to the warehouse is locked. Somebody who wouldn''t know that it belongs to the Belys, would assume it was abandoned years ago by its owner. Maybe you should return later.'	
	end
	if wl_iosif['timer'] = 1 and hour = 23:	act 'Go to Iosif': gt 'mod_wlife_iosif', 'warehouse_prostitution'
	if wl_homeless['status'] > 0: act 'Go to the homeless': minut += 3 & gt 'mod_wlife_warehouse', 'homeless_outside'
	act 'Wait':gs 'obj_din', 'wait'
end

if $ARGS[0] = 'shura_actions':
	if wl_shura['timer'] < (daystart - 1) and wl_shura['status'] ! 4: 
		iif(wl_shura['status'] > 1, 'Shura', 'A guy')+' is '+iif(temper < 10 or sunWeather = 0, 'standing outside the warehouse smoking a cigarette.', 'sitting outside the warehouse in an old armchair.')
	elseif wl_shura['timer'] < (daystart - 1) and wl_shura['status'] = 4:
		'Shura is sitting next to the curb drinking vodka.'
	end
		
	if wl_shura['status'] = 0:
		act 'Approach him': menu_off = 1 & gt 'mod_wlife_shura', 'first_meet_0'
	elseif wl_shura['status'] = 2 and wl_shura_temp = 0 and wl_shura['timer'] < (daystart - 1):
		act 'Talk to Shura': menu_off = 1 & gt 'mod_wlife_shura', 'second_meet_0'
	elseif wl_shura['status'] = 2 and wl_shura_temp = 1 and wl_shura['timer'] < (daystart - 1):
		act 'Talk to Shura': menu_off = 1 & gt 'mod_wlife_shura', 'second_meet_joint_refused'
	elseif wl_shura['status'] = 3 and wl_shura['timer'] < (daystart - 1):
		act 'Talk to Shura': menu_off = 1 & gt 'mod_wlife_shura', 'third_meet_0'
	elseif wl_shura['status'] = 4 and wl_shura['timer'] < (daystart - 1):
		act 'Talk to Shura': menu_off = 1 & wl_shura['status'] = 5 & gt 'mod_wlife_shura', 'regular_outside_0'				
	elseif wl_shura['status'] = 5 and wl_shura_temp < 2 and wl_shura['timer'] < (daystart - 1):
		act 'Talk to Shura': menu_off = 1 & gt 'mod_wlife_shura', 'inside_first_0'
	elseif wl_shura['status'] = 5 and wl_shura_temp = 2 and wl_shura['timer'] < (daystart - 1):
		act 'Talk to Shura': menu_off = 1 & wl_shura_temp = 1 & gt 'mod_wlife_shura', 'regular_outside_0'				
	elseif wl_shura['status'] > 5 and wl_shura['status'] < 9 and wl_shura['timer'] < (daystart - 1):
		act 'Talk to Shura': menu_off = 1 & gt 'mod_wlife_shura', 'cuckold_aftermath_0'
	elseif wl_shura['status'] > 8 and wl_shura['timer'] < (daystart - 1):
		act 'Visit Shura': 
			menu_off = 1
			
			if wl_shura['status'] = 10 and wl_shura['party'] = 0 and wl_status['main'] > 8 and wl_shura['party_timer'] > rand(1,4) and wl_sacha['status'] = 2:
				gt 'mod_wlife_shura', 'party_0'
			elseif wl_shura['status'] = 10 and wl_shura['party'] = 0 and wl_status['main'] > 8 and wl_sacha['status'] = 2:
				wl_shura['party_timer'] += 1
			end
			
			if sunWeather = 0 or temper < 10:
				gt 'mod_wlife_shura', 'regular_inside_0'
			else
				gt 'mod_wlife_shura', 'regular_outside_0'	
			end
		end
	end
end

if $ARGS[0] = 'homeless_outside':
	*clr & cla
	$metka = 'homeless_outside'
	$menu_arg = 'homeless_outside'
	menu_off = 0
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/homeless/outside_'+iif(daystage = 5, 'night', 'day')+'.jpg"></center>'
	'Only a few minutes away from the warehouse is the old run-down factory building that is occupied by the <a href="exec: gt ''mod_wlife_warehouse'', ''homeless''">homeless</a> of Pavlovsk.'
!!	if $wl_homeless['counter'] > 5: iif(wl_katharina_status = 0, 'A young <a href="exec: gt ''mod_wlife_warehouse'', ''katharina''">woman</a> attracts your attention. She throws you pitying looks every now and then.', '')
		
	act 'Leave': 
		if wl_status['main'] > -1:
			minut += 3 & gt 'mod_wlife_warehouse', 'street'
		elseif wl_status['main'] = -1:
			minut += 8 & gt 'pav_industrial'
		end
	end
	
	if $wl_homeless['like'] > 0 and wl_homeless['timer'] ! daystart and $wl_homeless['counter'] < 10:
		if $wl_homeless['counter'] < 3:
			'<br>You haven''t gotten used to having sex with homeless men and are very hesitant to fuck them.'
			gs 'willpower', iif($wl_homeless['like'] = 2, 'prostitution', 'sex'), 'self', 'hard'
		elseif $wl_homeless['counter'] < 6:
			'<br>You haven''t accepted selling yourself to the homeless, but you are slowly getting used to it.'
			gs 'willpower', iif($wl_homeless['like'] = 2, 'prostitution', 'sex'), 'self', 'medium'
		else
			'<br>You haven''t fully accepted selling yourself to the homeless, but you are getting there.'
			gs 'willpower', iif($wl_homeless['like'] = 2, 'prostitution', 'sex'), 'self', 'easy'
		end
		if will_cost <= pcs_willpwr:
			act 'Do ''community service'' (<<will_cost>> Willpower)': 
				gs 'willpower', 'pay', 'self'
				$wl_homeless['sex'] = 'freely'
				gt 'mod_wlife_punishment', 'homeless_regular'
			end
		else
			act 'Do ''community service'' (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	elseif $wl_homeless['like'] > 0 and wl_homeless['timer'] ! daystart and $wl_homeless['counter'] >= 10:
		act 'Do ''community service'' ': 
			$wl_homeless['sex'] = 'freely'
			gt 'mod_wlife_punishment', 'homeless_regular'
		end
	end	 
end

if $ARGS[0] = 'homeless':
	*clr & cla
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/homeless/homeless_'+iif(daystage = 5, 'night', 'day')+'.jpg"></center>'
	'Mostly men but also some women are living inside the abandoned building if you can call that living. Empty vodka bottles and used needles are everywhere, most of the homeless seem to be either alcoholics, drug addicts or both.'
	
	act 'Leave': minut += 3 & gt 'mod_wlife_warehouse', 'street'
end

if $ARGS[0] = 'katharina':
	*clr & cla
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/characters/katharina.jpg"></center>'	
!!ToDo:	only a few years older than you ... kathrina ... scratches her arm/drug use, she knows what sveta is doing, fucking homeless 
end

if $ARGS[0] = 'warehouse':
	CLOSE ALL
	$metka = 'warehouse'
	$menu_arg = 'warehouse'
	menu_off = 0
	
	$location_type = 'privat'
	
	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/warehouse/warehouse.jpg"></center>'
	'The interior of the warehouse is as run-down as the rest of the area. Car parts are everywhere, the roof is leaking and some of the metal parts are rusty. There is a door leading out of the warehouse into the adjacent house.'	
	
	if week = 7 and wl_georgiy['timer_day'] ! daystart and (wl_timer['startday'] + 14) < daystart and hour < 23 and (rand(0,2) < 2 or wl_gang['status'] = 0):
		gt 'mod_wlife_gang', 'random_warehouse'
	elseif week = 7 and wl_georgiy['timer_day'] ! daystart: 
		'The warehouse is empty except for Georgiy Bely who is chatting with one of his guys.'
		act 'Check in with Georgiy': gt 'mod_wlife_georgiy', 'check_in'
	else
		act 'Go outside': minut += 1 & gt 'mod_wlife_warehouse', 'street'
		act 'Go to the adjacent house': minut += 1 & gt 'mod_wlife_warehouse', 'hallway'
	end
end

if $ARGS[0] = 'hallway':
	$metka = 'hallway'
	$menu_arg = 'hallway'
	menu_off = 0
	
	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/warehouse/hallway.jpg"></center>'
	'The hallway of the old house has seen better days. The paint is peeling off the walls and you aren''t sure, but that looks like mold on one of the walls.'
	
	act 'Go back to the warehouse': minut += 1 & gt 'mod_wlife_warehouse', 'warehouse'
	act 'Go the bathroom': minut += 1 & gt 'mod_wlife_warehouse', 'bathroom'
	act 'Go to the common room': minut += 1 & gt 'mod_wlife_warehouse', 'common_room'
	act 'Go to the kitchen': minut += 1 & gt 'mod_wlife_warehouse', 'kitchen'
	act 'Go to the pantry': minut += 1 & gt 'mod_wlife_warehouse', 'pantry'
	
!!	ToDo: Rooms
!!	bedrooms???
!! 	attic
end

if $ARGS[0] = 'kitchen':
	$metka = 'kitchen'
	$menu_arg = 'kitchen'
	menu_off = 0

	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/warehouse/kitchen.jpg"></center>'	
!!ToDo: Description	
!!	'...'	
	act 'Leave': minut += 1 & gt 'mod_wlife_warehouse', 'hallway'
end

if $ARGS[0] = 'common_room':
	$metka = 'common_room'
	$menu_arg = 'common_room'
	menu_off = 0

	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/warehouse/common_room.jpg"></center>'
	'The room is in the same condition as the rest of the house. The TV is probably the most expensive thing in the whole house and worth more than it.'
	
!!ToDo: Watch TV, guys watching something
	
	act 'Leave': minut += 1 & gt 'mod_wlife_warehouse', 'hallway'
end

if $ARGS[0] = 'pantry':
	$metka = 'pantry'
	$menu_arg = 'pantry'
	menu_off = 0

	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/warehouse/pantry.jpg"></center>'
	'Vodka, bourbon, more vodka and even some wine is stored inside the small room. You don''t see any food, only some water.'
			
	act 'Leave': minut += 1 & gt 'mod_wlife_warehouse', 'hallway'
	if bottle = 0:
		act 'Take a bottle of water':
			*clr & cla
			minut += 1
			bottle = 1
			'<center><img <<$set_imgh>> src="mod/wlife/images/objects/water.jpg"></center>'
			'You take a bottle of water with you.'
			gs 'stat'
			
			act 'Continue': gt 'mod_wlife_warehouse', 'pantry'
		end
	end
end

if $ARGS[0] = 'bathroom':
	$metka = 'bathroom'
	$metkaM = 'bathroom'
	$menu_arg = 'bathroom'	
	menu_off = 0
	
	$location_type = 'bathroom'
	
	*clr & cla	
	if stanok > 0 and stanok_storage = 0: stanok_storage = stanok & stanok = 2
	gs 'stat'
	
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/warehouse/bathroom.jpg"></center>'
	'The bathroom is surprisingly clean but old. It has a small shower.'
	'There are some razors lying around. You could shave yourself or try a new <a href="exec: gs ''din_van'', ''shave_options''">style</a> for your pubic hair.'
	*nl
	'A <a href="exec:gt ''mirror'',''start''">mirror</a> hangs over the sink, where you can '+iif(pcs_hairbsh = 0,'<a href="exec: gt ''mirror'',''brush''">brush</a>','brush')+' your hair.'
	*nl
	'The door is missing a key and lacks another way to lock it.'
	
	if wl_status['main'] > 0 and (wl_status['main'] ! 6 or (wl_status['main'] = 6 and cumloc[4] = 0)):
		act 'Leave':
			minut += 2
			stanok = 0
			
			if stanok_storage > 0:
				stanok = stanok_storage
				stanok_storage = 0
			end
						
			if wl_status['main'] = 1:
				gt 'mod_wlife_story', 'start_aftermath_volya'
			elseif wl_status['main'] = 7:
				gt 'mod_wlife_story', 'police_aftermath_georgiy'
			else
				gt 'mod_wlife_warehouse', 'hallway'
			end			
		end
	elseif wl_status['main'] < 1:
		*nl
		'Your body is still covered in degrading writing.'
	elseif wl_status['main'] = 6 and cumloc[4] > 0:
		*nl
		'Your body is still covered in cum.'
	end
	
	act 'Take a shower (0:15)':
		*clr & cla
		menu_off = 1
		minut += 15

		if wl_status['main'] < 1: 
			wl_status['main'] = 1
		elseif wl_status['main'] = 6: 
			wl_status['main'] = 7
		end
		
		if shampoo < 0: shampoo = 0
		if frost > 0: frost = 0

		dynamic $showerdin

		body_write = 0
		face_write = 0

		'<center><video autoplay loop src="images/shared/home/bathroom/dush.mp4"></center>'
		*nl
		'You undress and turn on the water in the shower. When it hits the right temperature you enter the shower and let the warm water rain down on you.'
		'You carefully soap yourself trying not to miss any spot and then wash off.'
		if hypnoAddict > 0:'You have no reason to, but you carefully avoid cleaning out your pussy and ass.'
		pcs_horny += rand(0,2)
		
		if btwarn > 0:
			if btwarn = 1: $weightwarn = 'losing'
			if btwarn = 2: $weightwarn = 'gaining'
			'<font color="red"><b>You seem to be <<$weightwarn>> weight.</b></font>'
			killvar '$weightwarn' & btwarn = 0
		end
		
		if lactation['active'] > 0 and pain['nipples'] < 60 and pcs_knowsaboutlactation <= 0:
			if pcs_usedbreastpumponherself > 0 and pcs_massagedherbreasts <= 0:
				'During showering you clean your breasts and something catches your eye. White drops come from your nipples. It is milk.<br>Using the breast pump regularily probably made you lactate!'
				lactation['induced'] = 1
			elseif pcs_usedbreastpumponherself <= 0 and pcs_massagedherbreasts > 0:
				'During showering you clean your breasts and something catches your eye. White drops come from your nipples. It is milk. Regularily massaging your breasts probably made you lactate!<br>'
				lactation['induced'] = 1
			elseif pcs_usedbreastpumponherself > 0 and pcs_massagedherbreasts > 0:
				'During showering you clean your breasts and something catches your eye. White drops come from your nipples. It is milk. All that pumping and massaging your breasts probably caused you to lactate!<br>'
				lactation['induced'] = 1
			else
				'During showering you clean your breasts and something catches your eye. White drops come from your nipples. To your surprise it is milk. You started lactating!<br>'
				if thinkpreg = 1 or knowpreg = 1:
					'This is probably happening because you are pregnant.'
				else
					'You should have this checked out by a doctor. You could be pregnant.'
				end
				lactation['induced'] = 0
			end
			pcs_usedbreastpumponherself = 0
			pcs_massagedherbreasts = 0
			pcs_knowsaboutlactation = 1
		end
		
		gs 'stat'
		
		if pcs_horny >= 40:
			act 'Use the shower head on your pussy':
				*clr & cla
				if rand(0, 5) = 0 and obdysh = 1:gt 'vann', 'v4'
				'<center><video src="images/shared/home/bathroom/wash2.mp4"></center>'
				*nl
				'You place the shower head onto your pussy and a powerful jet of warm water begins to caress you.'

				if pcs_inhib < 30:inhib_exp += rand(1,3)
				pcs_mood += 15
				$orgasm_or = 'yes'
				gs 'arousal', 'masturbate', 10
				gs 'arousal', 'end'

				if hypnoAddict ! 0:
					'You unconsciously avoid spraying water into your vagina.'
				else
					cumspclnt = 8
					gs 'cum_cleanup'
				end

				dynamic $dryOff
			end
		end
		dynamic $dryOff
		dynamic $brit
	end
	
	if wl_status['main'] >= 1 and wl_status['main'] ! 6:
		dynamic $brit
		gs 'din_van', 'prvt_pee'
		dynamic $enema
		dynamic $tampon
		dynamic $quickwash
		dynamic $basin
		if breastpump > 0 and bp_unbox >= 1: act 'Use breast pump' :gt 'lact_lib', 'bp_milking'
	end
end

--- mod_wlife_warehouse ---------------------------------
