# mod_wlife_hotelroom

CLOSE ALL
if $ARGS[0] = 'room':
	*clr & cla	
	$location_type = 'private'
	$metkaM = 'room'
	$locM = 'mod_wlife_hotelroom'
	$metka = 'room'
	$loc = 'mod_wlife_hotelroom'
	$prevloc = 'HotelRoom'
	$menu_loc = 'mod_wlife_hotelroom'
	$menu_arg = 'room'
	menu_off = 0
	
	gs 'themes', 'indoors'
	gs 'stat'
		
	'<center><b><font color = maroon>Your hotel room</font></b></center>'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/room.jpg"></center>'
	'Your hotel room is not very large, but it has everything you need and is quite stylish. The large <a href="exec:gt ''bed2''">double bed</a> takes up most of the room. Your <a href="exec:gt ''budilnik'', ''start''">alarm clock</a> stands on the bedside table. A <a href="exec:gt ''mod_wlife_hotelroom'',''safe''">safe</a> is at the bottom of a modern <a href="exec:gt ''wardrobe'', ''start''">wardrobe</a> (where you can <a href="exec: quick_dress = 1 & gt ''wardrobe'', ''default''">choose outfits</a> and organize your clothing) stands near the entrance of the room.'
	*nl
	'Next to the wardrobe is a small <a href="exec:gt ''mod_wlife_hotelroom'', ''desk''">desk</a> and a huge <a href="exec:gt ''mirror'',''start''">mirror</a> mirror hangs in the small hallway. The door to the <a href="exec: minut += 1 & gt ''mod_wlife_hotelroom'',''bathroom''">bathroom</a> is to the right.'
	*nl
	'Your hotel room also has <a href="exec:gt ''mod_wlife_hotelroom'',''beverage_tray''">tray</a> with beverages and a <a href="exec:gt ''mod_wlife_hotelroom'',''tv''">TV</a> is mounted on the wall.'+iif(komp = 1, ' Your <a href="exec: gt ''Komp'',''start''">laptop</a> is on the desk. The hotel offers all guests free Wi-Fi.', '')
	if wl_status['hotel_bill'] > 0:
		*nl
		'This week your bill amounts to <<wl_status[''hotel_bill'']>> <b>₽</b>. It will be debited from your bank account on Monday. If you don''t have enough money in your account it will be added to your debt.'
	end
	
	act'Go to the hotel lobby':
		if $clothingworntype ! 'nude':
			gt'hotelHole'
		else
			msg'<b><font color = red>You need to get dressed before leaving your hotel room.</font></b>'
			gt 'mod_wlife_hotelroom', 'start'
		end
	end

	act 'Order room service':
		*clr & cla
		killvar '$_drink'
		killvar '$_eat'
		menu_off = 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/roomservice.jpg"></center>'
		
		gs 'mod_wlife_hotelroom', 'roomservice_items'
		gs 'food_menu', 'mod'
	end
	
	*nl & gs 'exercise', 'start'
end

if $ARGS[0] = 'roomservice_items':
	$_eat['0,name'] = 'Vegetarian Piroshki'
	$_eat['0,type'] = 'pirosh'
	$_eat['0,price'] = 100
	$_eat['1,name'] = 'Herring Blini'
	$_eat['1,type'] = 'blini'
	$_eat['1,price'] = 190
	$_eat['2,name'] = 'Golubtsy'
	$_eat['2,type'] = 'golub'
	$_eat['2,price'] = 210
	$_eat['3,name'] = 'Pozharsky Cutlets'
	$_eat['3,type'] = 'pozhar'
	$_eat['3,price'] = 290
	$_eat['4,name'] = 'Rueben Sandwich'
	$_eat['4,type'] = 'reuben'
	$_eat['4,price'] = 340

	$_drink['0,name'] = 'Beer on tap'
	$_drink['0,type'] = 'bev_bee'
	$_drink['0,price'] = 60
	$_drink['1,name'] = 'Vodka'
	$_drink['1,type'] = 'bev_vod'
	$_drink['1,price'] = 120
	$_drink['2,name'] = 'Scotch'
	$_drink['2,type'] = 'bev_sco'
	$_drink['2,price'] = 140
	$_drink['3,name'] = 'Glass of Wine'
	$_drink['3,type'] = 'bev_win'
	$_drink['3,price'] = 160
	$_drink['4,name'] = 'Black Russian'
	$_drink['4,type'] = 'bev_bla'
	$_drink['4,price'] = 250
end

if $ARGS[0] = 'safe':
	*clr & cla
	$metka = 'safe'
	$menu_arg = 'safe'
	menu_off = 0
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/safe.jpg"></center>'
	'You can store money in the hotel safe.'+iif(wl_status['money_safe'] > 0, ' There are <<wl_status[''money_safe'']>> <b>₽</b> inside the safe.', '')
	
	act 'Close the safe': gt 'mod_wlife_hotelroom', 'room'
	
	if money > 0:
		act 'Put some money in the safe':
			cla
			minut += 1
			menu_off = 1
			gs 'stat'
			wl_temp = input ("How much money do you want to put into the safe? (Your purse contains <<money>> <b>₽</b>.)")

			if wl_temp <= 0 or wl_temp > money:
				'You can''t put this amount into the drawer.'
			else
				wl_status['money_safe'] += wl_temp
				money -= wl_temp
			end

			killvar 'wl_temp'
			
			gt 'mod_wlife_hotelroom', 'safe'
		end
	end

	if wl_status['money_safe']> 0:
		act 'Take some money from the safe':
			cla
			minut += 1
			menu_off = 1
			gs 'stat'
			wl_temp = input ("How much money do you want to take from the safe? (There is <<wl_status['money_safe']>> <b>₽</b> in the safe.)")

			if wl_temp <= 0 or wl_temp > wl_status['money_safe']:
				'You can''t take this amount from your drawer.'
			else
				wl_status['money_safe'] -= wl_temp
				money += wl_temp
			end

			killvar 'wl_temp'
			
			gt 'mod_wlife_hotelroom', 'safe'
		end
	end
end

if $ARGS[0] = 'desk':
	*clr & cla
	$metka = 'desk'
	$menu_arg = 'desk'
	menu_off = 0
	gs'stat'
	'<center><h1>Desk</h1></center>'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/room.jpg"></center>'
	'You sit down at the desk.'
	if mentats_have > 0: '<a href="exec:dynamic $use_mentats & gt ''mod_wlife_hotelroom'', ''desk''"><b>Take neurobooster pill.</b></a> Uses left: <<mentats_have>>. Warning on the box says not to take more than one per day.'
	if steroid_have > 0: '<a href="exec:dynamic $use_steroids & gt ''mod_wlife_hotelroom'', ''desk''"><b>Take steroids.</b></a> Uses left: <<steroid_have>>.'
	if aphrodisiac_have > 0: '<a href="exec:dynamic $use_aphrodisiac & gt ''mod_wlife_hotelroom'', ''desk''"><b>Chew aphrodisiac gum.</b></a> Uses left: <<aphrodisiac_have>>.'
	
	act 'Get up': gt 'mod_wlife_hotelroom', 'room'
	
	act 'Check your birth control': gt 'mod_wlife_hotelroom', 'birth_control'
	if strapon = 1:
		if dildo + middildo + largedildo + bigdildo + extradildo + superdildo + maddildo > 0:
			act 'Check out your strapon harness': gt 'mod_wlife_hotelroom', 'strapon'
		else
			act 'Check out your strapon harness': '<br>You don''t have any dildos to attach to your strapon harness'
		end
	end	
	
	if SchoolAtestat = 0 and SchoolBlock = 0:
	
		gs 'willpower', 'misc', 'self', iif(grupTipe = 4 and traits['nerd_status'] = 0, 'hard', iif(traits['nerd_status'] > 0, 'easy', 'medium'))
		if traits['nerd_status'] = 2: will_cost = will_cost / 2
		if lernHome > 0 and (will_cost <= pcs_willpwr or traits['nerd_status'] = 3):
			'<br>You have to your homework. Finishing everything will take <<lernHome>> hours.'
			act 'Do your homework (1:00'+iif(traits['nerd_status'] = 3, '', ' and <<will_cost>> Willpower')+')':
				cla & *clr
				'<center><img <<$set_imgh>> src="images/locations/shared/apartment/homework.jpg"></center>'
				minut += 60
				pcs_mood += 5 * traits['nerd_status']
				lernHome -= 1
				lern += 1
				gs 'willpower', 'misc', 'self', iif(grupTipe = 4, 'hard', iif(traits['nerd_status'] > 0, 'easy', 'medium'))
				if traits['nerd_status'] = 2: will_cost = will_cost / 2
				if traits['nerd_status'] < 3: gs 'willpower', 'pay', 'self'
				gs'stat'
				'It took you one hour to '+iif(lernHome = 0, 'complete', 'do a part of')+' your homework.'
				
				act 'Continue':	gt 'mod_wlife_hotelroom', 'desk'
			end
		elseif lernHome > 0 and will_cost > pcs_willpwr:
			act 'Do your homework (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
		
		will_cost = will_cost * lernHome
		if lernHome > 1 and (will_cost <= pcs_willpwr or traits['nerd_status'] = 3):
			act 'Finish all of your homework (<<lernHome>>:00'+iif(traits['nerd_status'] = 3, '', ' and <<will_cost>> Willpower')+')':
				cla & *clr
				'<center><img <<$set_imgh>> src="images/locations/shared/apartment/homework.jpg"></center>'
				'It took you <<lernHome>> hours to complete your homework.'
				minut += 60 * lernHome
				pcs_mood += 5 * traits['nerd_status'] *lernHome
				lern += 1 + lernHome/2
				lernHome = 0
				if traits['nerd_status'] < 3: gs 'willpower', 'pay', 'self'
				gs'stat'
				
				act 'Continue': gt 'mod_wlife_hotelroom', 'desk'
			end
		elseif lernHome > 1 and will_cost > pcs_willpwr:
			act 'Finish all of your homework (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	end
end 

if $ARGS[0] = 'strapon':
	*clr & cla
	$metka = 'strapon'
	$menu_arg = 'strapon'
	menu_off = 0
	gs'stat'
	'<center><h1>Desk</h1></center>'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/room.jpg"></center>'
	if strapnumber = 0: 'Your strapon harness doesn''t have a dildo attached to it.'
	*nl
	if dildo = 1: iif(strapnumber = 1, 'Your 10cm dildo is attached to your strapon harness.', '<a href="exec:strapnumber = 1 & gt ''mod_wlife_hotelroom'', ''strapon''">Attach</a> your 10cm long dildo.')
	if middildo = 1: iif(strapnumber = 2, 'Your 15cm dildo is attached to your strapon harness.','<a href="exec:strapnumber = 2 & gt ''mod_wlife_hotelroom'', ''strapon''">Attach</a> your 15cm long dildo.')
	if largedildo = 1: iif(strapnumber = 3, 'Your 20cm dildo is attached to your strapon harness.','<a href="exec:strapnumber = 3 & gt ''mod_wlife_hotelroom'', ''strapon''">Attach</a> your 20cm long dildo.')
	if bigdildo = 1: iif(strapnumber = 4, 'Your 25cm dildo is attached to your strapon harness.','<a href="exec:strapnumber = 4 & gt ''mod_wlife_hotelroom'', ''strapon''">Attach</a> your 25cm long dildo.')
	if extradildo = 1: iif(strapnumber = 5, 'Your 30cm dildo is attached to your strapon harness.','<a href="exec:strapnumber = 5 & gt ''mod_wlife_hotelroom'', ''strapon''">Attach</a> your 30cm long dildo.')
	if superdildo = 1: iif(strapnumber = 6, 'Your 35cm dildo is attached to your strapon harness.','<a href="exec:strapnumber = 6 & gt ''mod_wlife_hotelroom'', ''strapon''">Attach</a> your 35cm long dildo.')
	if maddildo = 1: iif(strapnumber = 7, 'Your 40cm dildo is attached to your strapon harness.','<a href="exec:strapnumber = 7 & gt ''mod_wlife_hotelroom'', ''strapon''">Attach</a> your 40cm long dildo.')
	
	act 'Put your strapon harness away': gt 'mod_wlife_hotelroom', 'desk'
end

if $ARGS[0] = 'birth_control':
	*clr & cla
	$metka = 'birth_control'
	$menu_arg = 'birth_control'
	menu_off = 0
	gs'stat'
	gs 'din_bad'
	'<center><h1>Desk</h1></center>'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/room.jpg"></center>'
	'You store your birth control in one of the drawers of your desk.'
	
	act 'Close the drawer':gt 'mod_wlife_hotelroom', 'desk'
	
	if prezik + prezikcount + preziksabo > 0:
		if preziktype = 2 or preziksabo > 0:
			'You have <<iif(preziktype = 2, prezikcount, prezikcount+prezik)>> normal, and <<iif(preziktype = 2, prezik+preziksabo, preziksabo)>> sabotaged <a href="exec:dynamic $din_Table_Condom_Menu"><b>condoms.</b></a>'
		elseif preziktype < 2 and preziksabo = 0:
			'You have <<prezik+prezikcount>> <a href="exec:dynamic $din_Table_Condom_Menu"><b>condoms.</b></a>'
		end
		*nl
	else
		'You are out of condoms.'
	end
	
	if tabletki > 0 and pillsleft[ptype] > 0:
		'You have <<tabletki>> unopened packages of <a href="exec:dynamic $d_tabletkiedt">birth control pills</a> and <<pillsleft[ptype]>> pills left in your opened package.</b>'
	elseif tabletki	= 0 and pillsleft[ptype] > 0:
		'You have <<pillsleft[ptype]>> <a href="exec:dynamic $d_tabletkiedt">birth control pills</a> left.</b>'
	elseif tabletki > 0 and pillsleft[ptype] = 0:
		'You have <<tabletki>> unopened packages of <a href="exec:dynamic $d_tabletkiedt">birth control pills</a>.'
	else
		'You are out of birth control pills.'
	end
end

if $ARGS[0] = 'beverage_tray':
	*clr & cla
	$metka = 'beverage_tray'
	$menu_arg = 'beverage_tray'
	menu_off = 0
	gs'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/beverage_tray_'+iif(wl_status['coffee_maker'] < 2, 0, 1)+'.jpg"></center>'
	'On the tray is is a small selection of different types of tea and an electric kettle to boil water.'+iif(wl_status['coffee_maker'] = 2, '', ' Your coffee maker stands next to it. You have '+iif(wl_status['coffee'] = 0, 'no pods left.', 'pods for <<wl_status[''coffee'']>> cups of coffee.'))
	
	if wl_status['coffee_maker'] = 0:
		wl_status['coffee_maker'] = 1
		msg 'There is enough space next to the tray for a coffee maker. The shop sells coffee makers and pods if you like coffee.'
	end
	
	act 'Step back from the tray': gt 'mod_wlife_hotelroom', 'room'
	
	dynamic $driwater
	if wl_status['coffee'] > 0: act 'Have a coffee (0:05)': gt 'mod_wlife_hotelroom', 'coffee'	
	act 'Have a cup of tea (0:05)': dynamic $dritea
	dynamic $fill_bottle
	dynamic $fatdel
	dynamic $lekarstvo
	dynamic $vitamin
end

if $ARGS[0] = 'coffee':
	*clr & cla
	frost = 0
	if alko > 0: alko -= 1
	minut += 10
	wl_status['coffee'] -= 1
	pcs_health += 5
	pcs_mood += 20
	pcs_energy += 20
	if pcs_hydra >= 100:
		pcs_hydra += 20
	else
		pcs_hydra += 40
	end
	cumspclnt = 2
	gs 'cum_cleanup'
	pcs_breath = 0
	gs 'beverage', 'afterdrink'

	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/coffee.jpg"></center>'
	'You enjoy a hot coffee, and<<$mtxt>>'
	gs 'stat'
	killvar '$_drink'

	act 'Finish': gt 'mod_wlife_hotelroom', 'beverage_tray'
end

if $ARGS[0] = 'bathroom':
	*clr & cla
	$metkaM = 'bathroom'
	$locM = 'mod_wlife_hotelroom'
	$metka = 'bathroom'
	$loc = 'mod_wlife_hotelroom'	
	$menu_arg = 'bathroom'
	$location_type = 'bathroom'
	hotelShampoo = 1
	gs 'themes', 'indoors'
	gs'stat'
	
	'<center><b><font color = maroon>Bathroom</font></b></center>'
	'<center><img <<$set_imgh>> src="mod/wlife/images/locations/hotelroom/bathroom.jpg"></center>'
	'A small and unpretentious bathroom, that is nevertheless quite stylish and has everything you need.'
	
	act 'Leave the bathroom': hotelShampoo = 0 & gt 'mod_wlife_hotelroom', 'room'
	
	gs 'din_van', 'private', 'hotelroom'
end

if $ARGS[0] = 'tv':
	*clr & cla
	gs'stat'

	'<center><img <<$set_imgh>> src="mod/wlife/images/player/watch_tv.jpg"></center>'
	'You turn on the TV and make yourself comfortable on the bed.'

	act 'Get up from the bed': gt 'mod_wlife_hotelroom', 'room'
	act 'Watch TV (1:00)': gt 'mod_wlife_hotelroom', 'watch_tv'
end

if $ARGS[0] = 'watch_tv':
	*clr & cla
	minut += 60
	pcs_mood += rand(10,20)
	gs'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/hotel/tv0,'+rand(0,4)+'.jpg"></center>'
	'You are watching the country''s main television channel. None of their programs are really worth watching, but the distraction is welcome anyway.'

	act 'Get up from the bed': gt 'mod_wlife_hotelroom', 'room'
	act 'Watch TV (1:00)': gt 'mod_wlife_hotelroom', 'watch_tv'
end

--- mod_wlife_hotelroom ---------------------------------

