# unicoursework
!2021/04/26
$unicourseworkloc[0] = $ARGS[1]
$unicourseworkloc[1] = $ARGS[2]

if $ARGS[0] = 'start':
	if func('uniutil', 'student', 'enrolled') and func('uniutil', 'assignment_progress', 'is_not_finished'):
		if $unicourseworkloc[0] = 'komp':
			'You should do some of your <a href="exec:gt ''unicoursework'', ''do_coursework'', $unicourseworkloc[0], $unicourseworkloc[1]">coursework</a>.'
		else
			act 'Do some coursework (1:00)':
				gt 'unicoursework', 'do_coursework', $unicourseworkloc[0], $unicourseworkloc[1]
			end
		end
	end
end

if $ARGS[0] = 'do_coursework':
    *clr & cla
    menu_off = 1
    minut += 60

    if $ARGS[1] = 'komp':
    	elektro += 3
    	internet -= 1
    	compskl_exp += 1
    end

    gs 'uniutil', 'assignment_progress', 'update'

    pcs_mood -= 10
    gs 'stat'

    if $ARGS[1] = 'komp':
    	'<center><b>Coursework</b></center>'
    	'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/kursak.jpg"></center>'
    else
    	'<center><img <<$set_imgh>> src="images/pc/activities/study.jpg"></center>'
    end

    if $ARGS[1] = 'komp':
    	'It may be boring, but it still needs doing! You spend an hour doing your coursework and '+func('uniutil', 'assignment_progress', 'get')+'% of it is now finished.'
    elseif $ARGS[1] = 'sitr2x':
    	'You managed to complete some of your coursework. You are now '+func('uniutil', 'assignment_progress', 'get')+'% done.'
    elseif $ARGS[1] = 'sitr':
    	'You work on your course''s homework and are about '+func('uniutil', 'assignment_progress', 'get')+'% done.'
    elseif $ARGS[1] = 'pav_shared_apt':
    	'You sit down on the sofa bed and do some of your coursework. You''ve finished '+func('uniutil', 'assignment_progress', 'get')+'% of it.'
    elseif $ARGS[1] = 'nichBedroomServant':
    	'You work on your coursework and have now completed '+func('uniutil', 'assignment_progress', 'get')+'%.'
    elseif $ARGS[1] = 'bedrPar':
    	'You sit down at your desk and do some of your coursework. You''ve finished '+func('uniutil', 'assignment_progress', 'get')+'% of it.'
    else
    	'You sit for an hour and do some of your work for class. You''ve finished '+func('uniutil', 'assignment_progress', 'get')+'% of the work.'
    end

    if func('uniutil', 'assignment_progress', 'is_not_finished'):
    	act 'Do some more coursework (1:00)':
    		gt 'unicoursework', 'do_coursework', $unicourseworkloc[0], $unicourseworkloc[1]
    	end
    end

    act 'Stop':
    	gt $unicourseworkloc[0], $unicourseworkloc[1]
    end
end

--- unicoursework ---------------------------------
