# shop_flamingos
!!2022/03/12
if $ARGS[0] = 'start':
	killvar 'clothingfilter'
	$loc_arg = $ARGS[0]
	$loc = 'shop_flamingos'
    $location_type = 'public_indoors'
	$menu_loc = 'shop_flamingos'
	$menu_arg = 'start'
	menu_off = 0
	*clr & cla

	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Flamingo''s</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/flamingos/shop.jpg"></center>'
	*nl
	'Flamingos is trendy and modern while still keeping the prices low enough for the large student population on the Island. It mimics the latest fashions for young adults but cuts costs on material and manufacturing. This suits the clients who are likely to grow bored of an outfit before it falls apart and that''s why it''s always busy.'

	act 'Leave the flamingos': minut += 3 & gt 'pushkin_sq'
	
	act 'View dresses': minut += 5 & gt 'shop_flamingos', 'dresses'

	act 'View other clothing': minut += 5 & gt 'shop_flamingos', 'clothes'

	act 'View purses': minut += 5 & gt 'shop_flamingos', 'purses'
end

if $ARGS[0] = 'dresses':
	$loc_arg = 'dresses'
	$loc = 'shop_flamingos'
	$menu_loc = 'shop_flamingos'
	$menu_arg = 'dresses'
	menu_off = 0
	*clr & cla
	gs'stat'
	'<center><b><font color="maroon">Viewing Flamingo''s dresses</font></b></center>'
	*nl

	gs 'clothing_QV', 'shop_filter_header'
	gs 'clothing', 'totals', 'flamingos_dress'

	act 'Return': minut += 1 & gt 'shop_flamingos', 'start'

	!!To filter just this set
	clo_i = 0
	:loopflamingos_dress_filter

		if Clothingstock > 15:
			i = 1
		elseif Clothingstock > 7:
			i = 2
		else
			i = 3
		end

		:loopflamingos_dress
			if flamingos_dress[i] = 0:
				gs 'clothing_attributes', 'flamingos_dress', i
				gs 'clothing_QV', 'shop_filter'

				!!sort by filter
				if (clothingfilter['quality'] = 0 and CloQuality = clo_i) or (clothingfilter['inhibition'] = 0 and CloInhibit = clo_i) or clothingfilter['number'] = 0:
					if clothingfilter['inc'] = 1 and clothingfilter['only'] = 1: *p '<a href="exec: i = <<i>> & gt ''shop_flamingos'', ''flamingos_dress''"><img src="images/pc/items/flamingos/dress/<<i>>.jpg" 	height="250" /></a>'
				end
			end
			i += 3
		if i <= total:jump 'loopflamingos_dress'

	clo_i += 1
	if clothingfilter['quality'] = 0 and clo_i <= 7:
		jump 'loopflamingos_dress_filter'
	elseif clothingfilter['inhibition'] = 0 and clo_i <= 50:
		jump 'loopflamingos_dress_filter'
	end
end

if $ARGS[0] = 'flamingos_dress':
	cla
	menu_off = 1
	if flamingos_dress[i] ! 0:
		msg 'You already own this dress.'
		gt 'shop_flamingos', 'dresses'
	end

	gt 'clothing', 'view_clothing_item', 'flamingos_dress',i, 3000, 'shop'
end

if $ARGS[0] = 'clothes':
	$loc_arg = 'clothes'
	$loc = 'shop_flamingos'
	$menu_loc = 'shop_flamingos'
	$menu_arg = 'clothes'
	menu_off = 0
	*clr & cla
	gs'stat'
	'<center><b><font color="maroon">Viewing Flamingo''s outfits</font></b></center>'
	*nl

	gs 'clothing_QV', 'shop_filter_header'
	gs 'clothing', 'totals', 'flamingos_outfits'

	act 'Return': minut += 1 & gt 'shop_flamingos', 'start'

	!!To filter just this set
	clo_i = 0
	:loopflamingos_filter

		if Clothingstock > 11:
			i = 1
		else
			i = 2
		end

		:loopflamingos
			if flamingos_outfits[i] = 0:
				gs 'clothing_attributes', 'flamingos_outfits', i
				gs 'clothing_QV', 'shop_filter'

				!!sort by filter
				if (clothingfilter['quality'] = 0 and CloQuality = clo_i) or (clothingfilter['inhibition'] = 0 and CloInhibit = clo_i) or clothingfilter['number'] = 0:
					if clothingfilter['inc'] = 1 and clothingfilter['only'] = 1: *p '<a href="exec: i = <<i>> & gt ''shop_flamingos'', ''flamingos_outfits''"><img src="images/pc/items/flamingos/outfits/<<i>>.jpg" 	height="250" /></a>'
				end
			end
			i += 2
		if i <= total:jump 'loopflamingos'

	clo_i += 1
	if clothingfilter['quality'] = 0 and clo_i <= 7:
		jump 'loopflamingos_filter'
	elseif clothingfilter['inhibition'] = 0 and clo_i <= 50:
		jump 'loopflamingos_filter'
	end
end

if $ARGS[0] = 'flamingos_outfits':
	cla
	menu_off = 1
	if flamingos_outfits[i] ! 0:
		msg 'You already own this outfit.'
		gt 'shop_flamingos', 'clothes'
	end

	gt 'clothing', 'view_clothing_item', 'flamingos_outfits',i, 3000, 'shop'

end

if $ARGS[0] = 'purses':
	$loc_arg = 'purses'
	$loc = 'shop_flamingos'
	$menu_arg = 'purses'
	$menu_loc = 'shop_flamingos'
	menu_off = 0
	*clr & cla
	gs'stat'

	act 'Return':
		cla
		minut += 5
		gt 'shop_flamingos', 'start'
	end

	i = 1

	:loopflamingos_purses
		if flamingos_purses[i] = 0:*p '<a href="exec: i = <<i>> & gt ''shop_flamingos'', ''purses2''"><img src="images/pc/items/flamingos/purses/<<i>>.jpg" height="250" /></a>'
		i += 1
	if i <= 20:jump 'loopflamingos_purses'
end

if $ARGS[0] = 'purses2': gt 'purses', 'view_purse_item', 'shop', 'flamingos',i, 2000

--- shop_flamingos ---------------------------------

