# city_mansion_residence_2

if $ARGS[0] = 'yliving':
	$loc = 'city_mansion_residence_2'
	$loc_arg = 'yliving'
	$menu_loc = 'city_mansion_residence_2'
	$menu_arg = 'yliving'
	$location_type = 'private'
	$locclass = 'livingr'
	
	menu_off = 0
	minut += 1
	gs 'stat'
	
	*clr & cla
	'<center><b><font color="maroon">Living Room</font></b></center>'
	if ymanrem[7] = 2:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/y_living.jpg"></center>'
	elseif ymanrem[7] = 1:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_finished.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_unfinished.jpg"></center>'
	end
	act 'Leave the room': gt 'city_mansion_residence_1', 'yfoyer'

	if ymanrem[7] = 2:
		'A large room where you can watch <a href="exec:gt ''TV'',''start''">TV</a>, or relax on your luxury <a href="exec:gt ''divan'', ''start''">leather sofa</a>.'
		if $ml_guitar['location'] = $loc: 'Your guitar rests on its stand next to the sofa.'
		gs 'subkid'
		gs 'music_actions', 'music_icon'
	end
end

if $ARGS[0] = 'ylounge':
	$loc = 'city_mansion_residence_2'
	$loc_arg = 'ylounge'
	$menu_loc = 'city_mansion_residence_2'
	$menu_arg = 'ylounge'
	$location_type = 'private'
	
	menu_off = 0
	minut += 1
	gs 'stat'
	
	*clr & cla
	'<center><b><font color="maroon">Lounge</font></b></center>'
	if ymanrem[8] = 2:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/y_lounge.jpg"></center>'
	elseif ymanrem[8] = 1:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_finished.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_unfinished.jpg"></center>'
	end
	
	act 'Leave the room': gt 'city_mansion_residence_1', 'yfoyer'

	if ymanrem[8] = 2:
		'The lounge, where you can work on your tapestries and relax in front of the fireplace.'

		if mc_inventory['sewing_kit'] = 1:
			'Your <a href="exec:gt ''sewing'',''start''">sewing kit</a> is stored next to your favorite chair.'
			*nl
			if gobelen > 0:
				'You have completed <<gobelen>> tapestries.'
				*nl
			end
			if mc_inventory['sewing_fabric'] <= 0:
				'You do not have any fabric.'
			else
				if pcs_sewng < 40:
					'You have <<mc_inventory[''sewing_fabric'']>> pieces of sewing fabric left.'
				elseif pcs_sewng < 80:
					'You have enough fabric for <<mc_inventory[''sewing_fabric'']>> lessons.'
				else
					if newgobelen = 0:
						act'Start a new tapestry (00:15)':
							*clr & cla
							menu_off = 1
							mc_inventory['sewing_fabric'] -= 1
							newgobelen = 1
							minut += 15
							gs'stat'
							'You spend 15 minutes at the embroidery frame, preparing the fabric and outlining the pattern for the tapestry.'

							act'Set the tapestry aside':gt 'city_mansion_residence_2', 'ylounge'
						end
					end
				end
			end	
			if newgobelen >= 1:
				'Your tapestry is <<newgobelen/10>> percent finished.'
				act'Work on the tapestry (01:00)':
					*clr & cla
					menu_off = 1
					minut += 60
					gs 'exp_gain', 'sewng', rand(pcs_intel/10, pcs_intel/5)
					gobramax = (pcs_sewng - 70) * 6
					gobramin = (pcs_sewng - 70) * 2
					newgobelen += rand(gobramin,gobramax)
					gs'stat'
					if newgobelen < 1000:'You spend an hour working on your tapestry, which is now <<newgobelen/10>> percent finished.'
						if newgobelen >= 1000:
						newgobelen = 0
						gobelen += 1
						'Your work on the tapestry is done.'
					end
					act'Set the tapestry aside':gt 'city_mansion_residence_2', 'ylounge'
				end
			end
		end
	end
end

if $ARGS[0] = 'ylibrary':
	$loc = 'city_mansion_residence_2'
	$loc_arg = 'ylibrary'
	$menu_loc = 'city_mansion_residence_2'
	$menu_arg = 'ylibrary'
	$location_type = 'private'
	
	menu_off = 0
	minut += 1
	gs 'stat'
	
	*clr & cla
	'<center><b><font color="maroon">Library</font></b></center>'
	if ymanrem[10] = 2:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/y_library.jpg"></center>'
	elseif ymanrem[10] = 1:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_finished.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_unfinished.jpg"></center>'
	end

	act 'Leave the room': gt 'city_mansion_residence_1', 'yfoyer'
	
	if ymanrem[10] = 2:
		killvar '$downlibrary'
		$downlibrary['read'] = {
			*clr & cla
			menu_off = 1
			if blizoruk = 500 or glassqw = 1:
				glassqw = 1
				msg '	The text blurs across the page. It seems you have poor eyesight. Maybe you should visit an ophthalmologist?'
				gt 'city_mansion_residence_2', 'ylibrary'
			end
			if pcs_nerd > 0:
				lastread = totminut
				lastreadday = daystart
				pcs_nerd += 1
			end
			minut += 60
			blizoruk += 1
		}

		'A huge collection of books are neatly placed on the bookshelves.'
		act 'Read a book on science (1:00)':
			dynamic $downlibrary['read']
			gs 'exp_gain', 'intel', rand(3,6) + (mentats_dose - rand(0,mentats_dose))
			grupvalue[3] +=1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/science1.jpg"></center>'
			'You spend an hour reading, trying to make sense of all the clever propositions writen inside and to finally understand the subject it describes.'
			
			act 'Put the book back': gt 'city_mansion_residence_2', 'ylibrary'
		end

		act 'Read an adventure novel (1:00)':
			dynamic $downlibrary['read']
			pcs_mood = 100
			grupvalue[3] +=1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/fiction' + rand(1,2) + '.jpg"></center>'
			'You spend an hour reading an adventure novel, immersing yourself in daring deeds and awesome twists.'
			
			act 'Put the book back': gt 'city_mansion_residence_2', 'ylibrary'
		end

		act 'Read a fantasy novel (1:00)':
			dynamic $downlibrary['read']
			pcs_mood = 100
			grupvalue[3] +=1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/fantasy' + rand(1,9) + '.jpg"></center>'
			'You spend an hour reading a fantasy novel, rescuing damsels from dragons, digging for jewels with dwarves and performing word changing magic alongside elves and druids.'

			act 'Put the book back': gt 'city_mansion_residence_2', 'ylibrary'
		end

		act 'Read a science fiction novel (1:00)':
			dynamic $downlibrary['read']
			pcs_mood = 100
			grupvalue[3] += 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/scifi' + rand(1,6) + '.jpg"></center>'
			'You spend an hour reading a science fiction novel - flying off into space, travelling though time, running from rogue AI''s and creating monsters with your hunchbacked assistant.'

			act 'Put the book back': gt 'city_mansion_residence_2', 'ylibrary'
		end

		act 'Read a romance novel (1:00)':
			dynamic $downlibrary['read']
			pcs_mood = 100
			pcs_horny += 20
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/romance' + rand(1,20) + '.jpg"></center>'
			'You spend a very short hour reading a romance novel - choosing between a vampire or a werewolf, falling in love with an obscenely wealthy Grey... several of the scenes are very steamy and you find yourself getting quite aroused.'

			act 'Put the book back': gt 'city_mansion_residence_2', 'ylibrary'
		end

		temp = pcs_intel * 2 + pcs_sprt
		if temp < 100:
			$diff = 'hard'
		elseif temp < 150:
			$diff = 'medium'
		else
			$diff = 'easy'
		end
		gs 'willpower', 'misc', 'self', $diff
		if will_cost <= pcs_willpwr:
			act 'Read from the collected works of Leo Tolstoy (1:00) (<<will_cost>> Willpower)':
				gs 'willpower', 'pay', 'self'
				killvar 'will_cost'

				dynamic $downlibrary['read']
				gs 'exp_gain', 'sprt', rand(3,6)
				grupvalue[3] += 2
				gs 'stat'

				'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/tolstoy.jpg"></center>'
				'You read the book for an hour. Tolstoy is certainly a classic writer, no one denies this, but he used a shit-load of words.'

				act 'Put the book back': gt 'city_mansion_residence_2', 'ylibrary'
			end
		else
			act 'Read from the collected works of Leo Tolstoy (1:00) (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	end
end

if $ARGS[0] = 'yoffice':
	$loc = 'city_mansion_residence_2'
	$loc_arg = 'yoffice'
	$menu_loc = 'city_mansion_residence_2'
	$menu_arg = 'yoffice'
	$locM = 'city_mansion_residence_2'
	$locM_arg = 'yoffice'
	$location_type = 'private'
	
	menu_off = 0
	minut += 1
	gs 'stat'
	
	*clr & cla
	'<center><b><font color="maroon">Office</font></b></center>'
	if ymanrem[12] = 2:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/y_office.jpg"></center>'
	elseif ymanrem[12] = 1:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_finished.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_unfinished.jpg"></center>'
	end

	act 'Leave the room': gt 'city_mansion_residence_1', 'yfoyer'

	if ymanrem[12] = 2:
		'Your work room where you spend most of the time signing important papers and handling your business needs.'
		!!TODO: Code to check if Sveta is not alone
		gs 'internet_mobile', 'get_access'
		'There''s a <a href="exec:gt ''Komp'', ''start''">computer</a> sitting on your antique <a href="exec:gt ''stol'', ''start''">desk</a>.'

	!! IMPORTANT: if there is anything added later that could mean that others are in the room, gs 'music_actions', 'not_alone' should be added with the correct conditions.
	gs 'music_actions', 'music_icon'
		
	end
end

if $ARGS[0] = 'ynursery':
	$loc = 'city_mansion_residence_2'
	$loc_arg = 'ynursery'
	$menu_loc = 'city_mansion_residence_2'
	$menu_arg = 'ynursery'
	$location_type = 'private'
	
	menu_off = 0
	minut += 1
	gs 'stat'
	
	*clr & cla
	'<center><b><font color="maroon">Nursery</font></b></center>'
	if ymanrem[9] = 2:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/y_nursery.jpg"></center>'
		'<center>The neatly designed nursery room, only the best for your children.</center>'
	elseif ymanrem[9] = 1:
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_finished.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/i_unfinished.jpg"></center>'
	end

	act 'Leave the room': gt 'city_mansion_residence_1', 'yfoyer'

	if ymanrem[9] = 2: gs 'subkid'
end

--- city_mansion_residence_2 ---------------------------------

