# gschool

!Outside school building
if $ARGS[0] = 'start':
	CLOSE ALL

	$loc = $CURLOC
	$metka = $ARGS[0]
	gs 'stat'
	gs 'outdoors'
	'<center><b><font color="maroon">School</font></b></center>'
	'<center><img src="images/qwest/alter/gschool.jpg"></center>'
	'Pavlovsk''s only school, all the local children go here for their education.'
	if hour >= 9 and hour < 18 and SchoolAtestat = 0 and kanikuli = 0:
		'With the school open you can go to the <a href="exec:GT ''clothing_QV'',''list''">changing rooms</a> by the gym and pick an outfit to wear.'
	end

	act 'Return to town':gt 'pavResidential'

	if zverRageQW = 1:gt 'gschool', 'KristinaFight'


	if day = 31 and month = 12 and age <= 17 and StoryLine = 1 and SchoolAtestat = 0 and SchoolBlock ! 1:
		if hour = 14:
			'All the boys and girls are standing near the school. Everyone did their best to look good today, wearing their nicest clothes. Someone calls out to you, "Hey <<$name>>, are you coming to the New Year''s Eve party or not? You didn''t pay the 1000 <b>₽</b> entry fee yet!"'

			if money >= 1000:act 'Go to the party (1,000 <b>₽</b>)':money -= 1000 & snyqw = 0 & gt 'sny'
		end
	end

	if week = 6 and schoolSorev = 2 and hour = 10:
		'Athletic students of your school and other schools in the area have gathered at the athletics track near your school. Everyone is getting ready for the running competition.'

		act 'Participate in the 400m sprint event':gt 'gschool', 'SchoolRun2'
	end

	if week = 6 and schoolSorev = 1 and hour = 10:
		'Athletic students of your school and other schools in the area have gathered at the athletics track near your school. Everyone is getting ready for the running competition.'

		act 'Participate in the 400m sprint race':gt 'gschool', 'SchoolRun'
	end

	if hour <= 8 and week < 6 and StoryLine > 0 and SchoolAtestat = 0 and kanikuli = 6:
		'Today is graduation day! The school prom is tonight as well.'

		act 'Go to your graduation':
			cls
			SchoolAtestat = 1
			intel += 10
			gs 'stat'
			'Everyone from your year is assembled in the classroom. Your teachers have gathered in front of the class, and congratulate all of you on completing high school. As they hand everyone their well-earned diplomas, they wish you luck for the future.'

			act 'Return to town':gt 'pavResidential'

			act 'Go to the prom party':
				cls
				minut += 120
				alko += 5
				cumspclnt = 2
				gs 'cum_cleanup'
				fbreath = 0
				tanga = 0
				gs 'stat'
				gs 'clothing', 'strip'
!gee gee, no normal outlet
				'After the official graduation, everyone gets hammered at the prom party. You don''t remember much of what happened, only recalling a few flashbacks of going skinny dipping in the town fountain with a group of friends. When you wake up somewhere in the town center, all of your clothes are missing and you are completely naked.'

				act 'Go home':gt 'korrPar'
			end
		end
	end

	if week < 6 and StoryLine > 0 and SchoolAtestat = 0 and kanikuli = 0:
		if hour < 7 :
			'It''s too early for school now.'
		elseif hour < 10 :
			if $clothingworntype = 'school' or Enable_sforma = 1:

				act 'Go to school':
					!one line late from 1.2.4, timerange check by illume
					if hour >= 9: late=1
					gt 'gschool2', 'start'
				end
			else
				'You''re not allowed to attend any classes at school if you''re not wearing your school uniform.'
			end
		elseif hour < 16 :
			'It''s too late for school now. You absent from school today'
		end
	end

	if hour >= 16 and GorSlut >= 3 and SchoolGossip > 0 and afterschoolday ! daystart:gt 'gschool', 'suck'

	if week = 1 and kanikuli = 0 and arthakQW = 10 and apmeetday ! daystart and hour >= 16:gt 'artgar'

	if hour = 16 and week < 6 and kanikuli = 0:

		if LinaSlut > 0:
			if rand(1,10) < 3:'You see Lina, Dan and Vasily leaving the school together.'
		end

		if Enable_tablemap = 0:
			if LariskaHomeIn > 0:'<a href="exec:minut += 1 & GT ''LariskaGo''">Larissa Gruzdev</a> impatiently walks back and fourth across the courtyard, as if she''s waiting for someone.'
			if JuliaMilLernQW >= 1:'<a href="exec:minut += 1 & gt ''JuliaMilGo''">Julia Milova</a> is sitting somewhere on the school courtyard, reading a book.'
			if NatBelLernQW >= 1:'<a href="exec:minut += 1 & gt ''NatBelGo''">Natasha Belova</a> is standing in a corner.'
			if artemLernQW >= 1 and artemVitokQW ! 2:'<a href="exec:minut += 15 & gt ''artemEv'', ''start''">Artem Chebotarev</a> is waiting for you near the school entrance.'

			if katjaMeynoldday ! daystart and meynoldQW >= 2:'<a href="exec:minut += 15 & gt ''katjaEv''">Katja Meynold</a> is walking across the school courtyard, getting ready to go home.'
			if DimaBeHomeOnce = 1 and DimaRudeBlock = 0:
				'<a href="exec:minut += 15 & gt ''dimaGoHome2''">Dimka Nosov</a> is deep in thought, as he leans against a lamp post.'
			elseif DimaRudeQW > 0 and dimarudeday ! daystart and DimaRudeBlock = 0:
				'<a href="exec:minut += 15 & gt ''dimaRudeEv''">Dimka Nosov</a> is deep in thought, as he leans against a lamp post.'
			end
			if IgorLoverQW > 0 and igorkruglovday ! daystart and IdorBlock = 0:'<a href="exec:minut += 15 & gt ''IgorEv''">Igor Kruglov</a> is talking to some of his friends on the courtyard.'
			if fedorKozlovQW >= 10:'<a href="exec:minut += 15 & gt ''FedorEv''">Fedor Kozlov</a> is standing by himself, far away from the school entrance. When he sees you, he happily waves you over to him.'
		else
			!display friends in table if switch is on. 
			st_count=0 & $show_table=''
			if LariskaHomeIn > 0:gs'show_table','<a href="exec:minut += 1 & GT ''LariskaGo''">Lariska Gruzdev</a>.','5'
			if JuliaMilLernQW >= 1:gs'show_table','<a href="exec:minut += 1 & gt ''JuliaMilGo''">Julia Milov</a>.','5'
			if NatBelLernQW >= 1:gs'show_table','<a href="exec:minut += 1 & gt ''NatBelGo''">Natasha Belova</a>.','5'
			if artemLernQW >= 1 and artemVitokQW ! 2:gs'show_table','<a href="exec:minut += 15 & gt ''artemEv'', ''start''">Artem Chebotarev</a>.','5'
			if katjaMeynoldday ! daystart and meynoldQW >= 2:gs'show_table','<a href="exec:minut += 15 & gt ''katjaEv''">Katja Meynold</a>.','5'
			if DimaBeHomeOnce = 1 and DimaRudeBlock = 0:
				gs'show_table','<a href="exec:minut += 15 & gt ''dimaGoHome2''">Dimka Nosov</a>','5'
			elseif DimaRudeQW > 0 and dimarudeday ! daystart and DimaRudeBlock = 0:
				gs'show_table','<a href="exec:minut += 15 & gt ''dimaRudeEv''">Dimka Nosov</a>','5'
			end
			if IgorLoverQW > 0 and igorkruglovday ! daystart and IdorBlock = 0:gs'show_table','<a href="exec:minut += 15 & gt ''IgorEv''">Igor Kruglov</a>.','5'
			if st_count > 0 :'Near school yard, you see <TABLE BORDER=1><<$show_table>></TR></TABLE>'
		end
		if albinaCarday ! daystart:
			if AlbFrend >= 1 and albrideday ! daystart:'<a href="exec:minut += 15 & gt ''albinaRide''">Albina Barlovskaya</a> is waiting behind the wheel of a large black SUV, parked near the school.'
		end
	end

	if strelaDay ! daystart and strelaQW = 1 and hour = 16:
		cls
		gs 'stat'
		'A Mitsubishi Pajero and a BMW drive up to the school gates. Strong, muscular guys in leather jackets and tracksuits get out of the cars. They have came to meet Vitek, Dan and Vasily. You watch them talk about something, though you''re not close enough to hear what it''s about. Then you notice Fedor Kozlov leaving school; his face all swollen and bruised. Fedor waves his hand at you, "<<$name>>! Come here, you''re my witness!"'

		act 'Go and see what he needs':gt 'strela'

		exit
	end

	gs 'family'
end

if $ARGS[0] = 'KristinaFight':
	cls
	gs 'stat'
	gs 'outdoors'
	zverRageQW = 2
	'As you cross the school yard after school, you are surprised by a powerful kick in your back. You fall to your hands and knees and rub your sore back for a second, before you turn around and see Christina Zvereva, her face contorted with rage. She yells at you, "You fucking bitch! How dare you spread shit about me like that? I''ll break your fucking face!"'
	$boy = 'Christina'
	!!stats
	strenV = 85
	speedV = 75
	agilV = 75
	reactV = 75
	vitalV = 95
	intelV = 45
	willV = 45
	!Skills
	magikV = 95
	boxingV = 35
	shootV = 95
	!Parameters
	healthV = vitalV*10 + strenV*5
	mannaV = intelV*10 + magikV*10
	willpowerV = willV*10
	BonusAtakV = 0
	BonusDefV = 0
	!Action Programme
	program = 0
	ZverevaFight = 1

	if spellavtoklon = 1:klon = 3
	if spellbefshild = 1:defence = 500

	round = 0

	act 'fight':gt 'fight','start'
end

if $ARGS[0] = 'SchoolRun2':
	cls
	minut += 30
	gs 'stat'
	'You think you might be able to win, and sign up to participate in the competition. After quickly changing into your running gear you return to the track. The guys are having their race first, and you watch them as you prepare. As expected, Ivan Prokhorov wins. When the guys have finished, it is the girls'' turn.'

	if swinbeggor = 0:
		'Getting ready at the start is Christina Zvereva, one of the girls in your class. She scoffs at you, "You''ll never beat me!"'
	elseif swinbeggor = 1:
		'Getting ready at the start is Christina Zvereva, one of the girls in your class. She looks at you angrily and says, "You beat me once, but never again!"'
	elseif swinbeggor = 2:
		'Getting ready at the start is Christina Zvereva, one of the girls in your class. She looks at you with hatred, "You again, bitch? You''re going down this time, I promise you!"'
	end

	act 'Go to the start':
		cls
		kolsorev += 1
		minut += 30
		schoolSorev = 0
		gs 'stat'
		'<center><img src="images/etogame/begsor.jpg"></center>'
		'The 400m sprint event for girls is up next. You take off your jacket and go the starting line, mentally preparing yourself for the race.'
		wait 725
		'On your marks...'
		wait 725
		'Get set...'
		wait 725
		'Go!'
		wait 725

		begresult = beg + speed + vital + rand(1, 20) - salo/2 - rand(1, 20)

		if begresult <= 0:
			'You barely manage to reach the finish line at all. There''s no point in checking where you finished, you already know you were last by quite a large margin.'
		elseif begresult < 70:
			'You struggle to keep up with the other girls, and finish in last place.'
		elseif begresult < 80:
			'You run as fast as you can, but only manage to finish second to last.'
		elseif begresult < 90:
			'You run as fast as you can, but only manage to take 6th place.'
		elseif begresult < 100:
			'You run as fast as you can, but only manage to take 5th place.'
		elseif begresult < 110:
			'You run as fast as you can, but only manage to take 4th place.'
		elseif begresult < 120:
			'You run as fast as you can, and manage to take 3rd place. Mr. Pavlovich, the P.E. teacher at your school, congratulates you.'
		elseif begresult < 130:
			'You run as fast as you can, and manage to take 2nd place. Mr. Pavlovich, the P.E. teacher at your school, congratulates you on your achievement.'
		else
			swinbeggor += 1
			dom += 1
			'You run as fast as you can, and manage to reach the finish line before anyone else. First place! Mr. Pavlovich, the P.E. teacher at your school, congratulates you on winning the competition yet again while you walk around with your arms raised in triumph.'
		end

		beg += 1
		fat -= 10

		if swinbeggor = 3 and razradbeg = 1:
			razradbeg = 2
			grupNPC[18] = 0
			zverevaQW = 1
			'You have won the competition three more times and mr. Pavlovich awards you the second tier sports trophy in running. Christina Zvereva stands nearby glaring at you the whole time, her hands balled into fists. She''s seething with rage, realizing she cannot beat you.'
		elseif swinbeggor = 2 and begresult >= 130:
			grupNPC[18] = 0
			'Christina Zvereva is gasping for breath at the finish line. She was unable to overtake you, and came second again. Christina avoids your gaze, not wanting to look you in the eye.'
		elseif swinbeggor = 1 and begresult >= 130:
			grupNPC[18] = 0
			'Christina Zvereva is gasping for breath at the finish line. She was unable to overtake you, and came second yet again. You just flash her a teethy grin and continue your victory lap. Through clenched teeth Christina growls at you, "You bitch!"'
		end

		gs 'stat'

		act 'Leave':gt 'pavResidential'
	end
end

if $ARGS[0] = 'SchoolRun':
	cls
	minut += 30
	gs 'stat'
	'You think you might be able to win, and sign up to participate in the competition. After quickly changing into your running gear you return to the track. The guys are having their race first, and you watch them as you prepare. As expected, Ivan Prokhorov wins. When the guys have finished, it is the girls'' turn.'

	act 'Go to the start':
		cls
		minut += 30
		schoolSorev = 0
		kolsorev += 1
		gs 'stat'
		'<center><img src="images/etogame/begsor.jpg"></center>'
		'The 400m sprint event for girls is up next. You take off your jacket and go the starting line, mentally preparing yourself for the race.'
		wait 725
		'On your marks...'
		wait 725
		'Get set...'
		wait 725
		'Go!'
		wait 725

		begresult = beg + speed + vital + rand(1, 20) - salo/2 - rand(1, 20)

		if begresult <= 0:
			'You barely manage to reach the finish line at all. There''s no point in checking where you finished, you already know you were last by quite a large margin.'
		elseif begresult < 10:
			'You struggle to keep up with the other girls, and finish in last place.'
		elseif begresult < 20:
			'You run as fast as you can, but only manage to finish second to last.'
		elseif begresult < 30:
			'You run as fast as you can, but only manage to take 6th place.'
		elseif begresult < 40:
			'You run as fast as you can, but only manage to take 5th place.'
		elseif begresult < 50:
			'You run as fast as you can, but only manage to take 4th place.'
		elseif begresult < 60:
			'You run as fast as you can, and manage to take 3rd place. Mr. Pavlovich, the P.E. teacher at your school, congratulates you.'
		elseif begresult < 70:
			'You run as fast as you can, and manage to take 2nd place. Mr. Pavlovich, the P.E. teacher at your school, congratulates you on your achievement.'
		else
			swinbeg += 1
			dom += 1
			'You run as fast as you can, and manage to reach the finish line before anyone else. First place! Mr. Pavlovich, the P.E. teacher at your school, congratulates you on winning the competition, as you walk around with your arms raised in triumph.'
		end

		beg += 1
		fat -= 10

		if swinbeg = 3 and razradbeg = 0:
			razradbeg = 1
			'You have won the school running competition three times now and Mr. Pavlovich, the P.E. teacher at your school, announces that your success has not gone unnoticed. He smiles and awards you the third tier sports trophy in running, which you proudly accept and show to everyone.'
		end

		gs 'stat'

		act 'Return to town':gt 'pavResidential'
	end
end

if $ARGS[0] = 'suck':
	aftgopbjrand = rand(0, 2)

	if aftgopbjrand ! 0:
		afterschoolday = daystart
		gt 'gschool', 'start'
	else
		cla
		'Vitek and his friends are waiting for you by the school exit. "Hold on, <<$name>>. Everyone in school says you''re a great cocksucker. Do you want to put that mouth of yours to work? Come back to school with us, let''s have some fun."'

		act 'Return to school':
			cls
			afterschoolday = daystart
			SchoolGossip += 1
			minut += 15
			gs 'stat'
			'You return to school with the guys, sometimes feeling a hand on your ass as you walk through the hallway. You pretend to ignore it and just keep walking, but in the meantime your heart is racing. The guys pull you into the men''s room and tell you to get on your knees.'

			act 'Suck Vitek''s cock':
				cls
				minut += 15
				bj += 3

				if npcSex[9] = 0:npcSex[9] = 1 & guy += 1
				if npcSex[10] = 0:npcSex[10] = 1 & guy += 1
				if npcSex[11] = 0:npcSex[11] = 1 & guy += 1

				sub += 1
				gs 'stat'
				'<center><img src="images/qwest/alter/Ev/toiletBJtreesome.jpg"></center>'
				'You obediently squat and pull Vitek''s member out of his sweatpants. You rub his hard cock against your <<$liptalk3>>, and then open your mouth and begin to suck him off. After making sure no one is coming, Dan and Vasily also approach you and take out their members, pointing them at you expectantly. Now sucking the dicks of all three boys in turns, you do your best to still please the ones you''re not sucking on by caressing them with your hands.'

				act 'Take their cum on your face':
					cls
					minut += 15
					bj += 3
					spafinloc = 12
					gs 'cum_manage'
					spafinloc = 11
					gs 'cum_manage'
					spafinloc = 7
					gs 'cum_manage'
					sub += 1
					gs 'stat'
					'<center><img src="images/qwest/alter/Ev/toiletBJcum.jpg"></center>'
					'You close your eyes to fully focus on what you''re doing, and a few minutes later you feel the dick that''s currently in your mouth spasm. Several ropes of cum hit your tongue; it tastes rather bitter. Carefully opening one eye, you see that it is Vitek''s. The other two guys tell you to keep your eyes closed, and Dan shoots his load on your face before you can even comply. Luckily, he didn''t hit the eye that was open. You obediently close them, and a few seconds later you feel Vasily''s cum splattering against your eye lids and cheek. You hear the click of a camera, and open your eyes after carefully wiping the cum off your eye lids. They pull up their pants and leave, laughing at how much of a slut you are and how they had never thought you would actually come with them.'

					act 'Leave the school building':gt 'gschool', 'start'
				end
			end
		end

		!new act:excuse from 1.2.4
		act 'Excuses':
			cls 
			minut +=1
			! false, pizdezh and provocation, lpp
			:ReCheck
			lpp = rand(0,3) 
			!twice in a row the same shit does not roll, so:
			if lastlpp!0 and lastlpp=lpp: jump 'ReCheck'
			$textlpp[0]='- Boys... I got to the dentist, the tooth hurts very much, please release!
- Who cares? Suck quickly and you may go.
- I`ll miss the reception, lamentably meet you.
- Another time you go!
Frantically inventing excuses, you remember he had seen on television advertising:
- Okay... You Fuckers have?
- What?! You Shmarov, generally swollen.?!
- Well, you me to the dentist is not allowed, and I got the bacteria that cause inflammation...'
			$textlpp[1]='- I can`t, I think I have herpes jumps...'
			$textlpp[2]='
The list of excuses against suction is small, and you frantically think of anything to say.
- I can... I`m sick... - you`re mumbling a lot, holding his stomach, presenting himself as a sucking stinky dick.
Your face is naturally green.
- Really I was going to throw up, ` growled someone from the boys.'
			$textlpp[3]='- I think I might have tonsillitis... Throat hurts, no strength, - feigning a hoarse voice, you say.'
*pl $textlpp[lpp]
'- Fu fuck, you get out there now. Then work doubly realized?
- Yes! - voskliknula you. In my head flashed the thought "Here motherfuckers..."'
			lastlpp = lpp
			afterschoolday = daystart
			killvar '$textlpp'
			killvar 'lpp'
			act 'Leave': gt 'gschool' , 'start'
		end
	end
end

--- gschool ---------------------------------

