# mod_addedflavour_Hunter
	if $ARGS[0] = 'Hunter_Config':
		KILLVAR '$modArr_AF_HunterLocs'
		$modArr_AF_HunterLocs[] = 'pav_residential'
		$modArr_AF_HunterLocs[] = 'pav_complex'
		$modArr_AF_HunterLocs[] = 'pav_commercial'
		$modArr_AF_HunterLocs[] = 'pav_industrial'
		$modArr_AF_HunterLocs[] = 'mod_addedflavour_pav_depot'
		$modArr_AF_HunterLocs[] = 'pav_commcenter'
		$modArr_AF_HunterLocs[] = 'pav_park'
		$modArr_AF_HunterLocs[] = 'liam'
		$modArr_AF_HunterLocs[] = 'liames'
		$modArr_AF_HunterLocs[] = 'pav_train'
		$modArr_AF_HunterLocs[] = 'road'
		modVar_AF_EventOpen['HunterActive'] = 1
		modVar_AF_EventLock['HunterEncounter'] = daystart
	end
	
	if $ARGS[0] = 'Hunter_Chance':
		KILLVAR 'modVar_AF_HunterChance'
		modVar_AF_HunterChance = 10
		if pcs_react >= 50:
			modVar_AF_HunterChance += 5
		else
			modVar_AF_HunterChance += 20
		end
		if pcs_intel >= 60:
			modVar_AF_HunterChance += 5
		else
			modVar_AF_HunterChance += 20
		end
		if hour >= 22 or hour <= 5 : modVar_AF_HunterChance += 50
		if hour <= 17 and hour >= 8 : modVar_AF_HunterChance -= 50
		if hotcat >= 9 : modVar_AF_HunterChance += rand(5,10)
		if difficulty >= 3 : modVar_AF_HunterChance += rand(10,20)
		if $loc = 'pav_park' or $loc = 'road' : modVar_AF_HunterChance += rand(5,10)
		if modVar_AF_HunterChance <= 0 : modVar_AF_HunterChance = 0
		if modVar_AF_HunterChanceForce = 1 : modVar_AF_HunterChance = 100
	end
	
	if $ARGS[0] = 'Hunter_Encounter':
		menu_off = 1
		if modVar_AF_EventProgress['HunterState'] = 0:
			gt 'mod_addedflavour_Hunter' , 'Realise'
		elseif modVar_AF_EventProgress['HunterState'] >= 1:
			KILLVAR '$modArr_AF_Rand'
			modVar_AF_Temp = 0
			:huntervoidloopstart
			$modArr_AF_Rand[] = 'Void'
			modVar_AF_Temp += 1
			if modVar_AF_Temp <= (5 - difficulty) * 3 : jump 'huntervoidloopstart'
			modVar_AF_Temp = 0
			:huntergrabbedloopstart
			$modArr_AF_Rand[] = 'Grabbed'
			modVar_AF_Temp += 1
			if modVar_AF_Temp <= difficulty * 3 : jump 'huntergrabbedloopstart'
			modVar_AF_Temp = 0
			:huntergetawayloopstart
			$modArr_AF_Rand[] = 'GetAway'
			modVar_AF_Temp += 25
			if modVar_AF_Temp <= pcs_react + pcs_intel : jump 'huntergetawayloopstart'
			if modVar_AF_EventProgress['HunterState'] = 2:
				modVar_AF_Temp = 0
				:hunterpoliceloopstart
				$modArr_AF_Rand[] = 'Police'
				modVar_AF_Temp += 1
				if modVar_AF_Temp <= (5 - difficulty) * 3 : jump 'hunterpoliceloopstart'
			end
		end
		modVar_AF_Rand = rand(1,arrsize('$modArr_AF_Rand')) - 1
		$modVar_AF_TempStr = $modArr_AF_Rand[modVar_AF_Rand]
		gt 'mod_addedflavour_Hunter' , 'Hunter_<<$modVar_AF_TempStr>>'
	end
	
	if $ARGS[0] = 'Realise':
		CLOSE ALL
		*clr & cla
		minut += rand(1,3)
		modVar_AF_EventProgress['HunterState'] = 1
		gs 'stat'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="mod/addedflavour/images/shared/Hunter/Void' + iif(hour >= 19 or hour <= 5,'N','') + '.jpg"></center>'
		*nl
		'You turn but you don''t see anyone.  You were sure you heard the sound of someone moving towards you from behind but there is no-one to be seen...'
		act 'Move on' : gt $loc, $loc_arg
	end
	
	if $ARGS[0] = 'Hunter_Void':
		CLOSE ALL
		*clr & cla
		minut += rand(1,3)
		gs 'stat'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="mod/addedflavour/images/shared/Hunter/Void' + iif(hour >= 19 or hour <= 5,'N','') + '.jpg"></center>'
		*nl
		'You turn to face whoever was walking behind you but find that there is no-one there.  You are merely greeted with an empty space and no sign of whatever made the noise...'
		act 'Keep moving' : gt $loc, $loc_arg
	end
	
	if $ARGS[0] = 'Hunter_GetAway':
		CLOSE ALL
		*clr & cla
		minut += rand(2,5)
		gs 'stat'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="mod/addedflavour/images/shared/Hunter/Followed<<rand(1,2)>>.jpg"></center>'
		*nl
		'You quickly move forward.  Whether it be a would-be attacker or oblivious stranger, you decide not to take any chances and move to outrun your mystery evoker.'
		*nl
		'You successfully make it to your destination.'
		act 'Get away' : gt $loc, $loc_arg
	end
	
	if $ARGS[0] = 'Hunter_Police':
		CLOSE ALL
		*clr & cla
		minut += rand(1,3)
		modVar_AF_EventTriggered['HunterPolice'] += 1
		if modVar_AF_EventTriggered['HunterPolice'] >= difficulty * 2 : modVar_AF_EventOpen['HunterActive'] = 0
		gs 'stat'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="mod/addedflavour/images/shared/Hunter/PoliceWalk<<rand(1,2)>>.jpg"></center>'
		*nl
		'Your concerns are allayed by the sight of some police officers walking in your vicinity.  It looks like your report was enough to increase the amount of police walking the streets.'
		*nl
		'<i>I hope it is enough to scare off my stalker...</i>'
		act 'Move on' : gt $loc, $loc_arg
	end
	
	if $ARGS[0] = 'Hunter_Grabbed':
		CLOSE ALL
		*clr & cla
		modVar_AF_EventTriggered['HunterGrabbed'] += 1
		gs 'stat'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="mod/addedflavour/images/shared/Hunter/Grabbed.jpg"></center>'
		*nl
		if modVar_AF_EventTriggered['HunterGrabbed'] = 1:
			'Someone has grabbed you from behind and is holding you in place!'
			*nl
			'"Ah!  What do you want with me?!"'
			*nl
			'<font color="Olive">"I''ll show you what I damn well want with you!"</font>'
			*nl
			'You struggle but he has complete control over you and can do with you as he pleases...'
		elseif modVar_AF_EventTriggered['HunterGrabbed'] = 2:
			'You have once again been grabbed from behind and held in place by an inescapable pair of arms...'
			*nl
			'"What do you want with me?!"'
			*nl
			'<font color="Olive">"What do I want with you!!  I want to make you pay for what you did!</font>'
			*nl
			'You feel his grip tighten as he moves to use your body for his own gratification.'
		elseif modVar_AF_EventTriggered['HunterGrabbed'] = 3:
			'"Why are you doing this to me?!  What could I have done?!"'
			*nl
			'<font color="Olive">"How about arraning to have someone anally raped!  Does that sound like something you would do!"</font>'
			*nl
			'"What?... I didn''t.... wait, is that you Dimka?"'
			*nl
			'<font color="Olive">"Of course it is FUCKING ME!!  You had me raped and recorded it; that footage would destroy my credibility and that is reason enough let alone the payback for the act itself."</font>'
			*nl
			'"But wait... I can give you the footage, you just have to promise me Zinaida wil---"'
			*nl
			'<font color="Olive">"LIKE I GIVE A FUCK ABOUT ZINAIDA!  She was just a bit of fun but at the end of the day all I had was a picture of her fucking tits, what difference would that make if I revealed that, it would just confirm what everyone suspected.  No, this is just about you and you alone..."</font>'
			*nl
			'You struggle but it is in vain as you hear what you assume is him removing his cock from his trousers...'
		else
			'<font color="Olive">"Where do you think you''re going then <<$pcs_firstname>>... you are mine to play with..."</font>'
		end
		act 'Get raped' : gt 'mod_addedflavour_Hunter' , 'Hunter_Rape'
	end
	
	if $ARGS[0] = 'Hunter_Rape':
		*clr & cla
		if modVar_AF_EventTriggered['HunterGrabbed'] >= 3:
			sexpartkno = 1
			gs 'boyStat', 'A1'
		else
			sexpartkno = 0
			gs 'npcgeneratec', 0, 'Unknown Rapist'
			gs 'boyStat', $npclastgenerated
		end
		rape += 1
		spafinloc = 7
		gs 'cum_manage'
		gs 'stat'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="mod/addedflavour/images/shared/Hunter/Assault' + iif(hour >= 8 and hour <= 18,'<<rand(1,2)>>','<<rand(3,6)>>') + iif(modVar_AF_QSPVer = 1,'.gif','.webp') + '"></center>'
		*nl
		'Your assailant keeps hold you but forces your body to be an unwilling vessel to his animal want.  His cock thrusts into your body for an unknown amount of time, for you are lost to pain of the moment, before finally his pleasure relents and he covers your body with his sperm.'
		*nl
		if ((difficulty = 3 and rand(1,10) = 1) or (difficulty = 4 and rand(1,4) = 1)) and modVar_AF_EventTriggered['HunterGrabbed'] > 3:
			'<font color="Olive">"I am done with you <<$pcs_firstname>> and it is time I finish this."</font>'
			*nl
			'You are thrown to the ground but to your surprise, when you look up you can see he has brandished a knife!'
			*nl
			'<font color="Olive">"I cannot abide having someone like you around me, and for your sins I will be rid of you.  No-one will find your body <<$pcs_firstname>>; in fact, no-one will even care that you are gone."</font>'
			*nl
			'You are panicing now!  You need to escape!'
			act 'Escape!' : gt 'mod_addedflavour_Hunter' , 'Hunter_Kill'
		else
			'You are thrown to the ground as if you were a used tissue, discarded onto the trash heap.'
			*nl
			'<font color="Olive">"Look at you... pathetic..."</font>'
			*nl
			'He leaves before you even look up from your dreggs.  You do your best to get yourself back together but it is difficult; you barely manage it but you get back to your feet.'
			if modVar_AF_EventProgress['HunterState'] ! 2:
				*nl
				'<i><b>I need to get to the police...</b></i>'
			end
			act 'Return' : gt $loc, $loc_arg
		end
	end
	
	if $ARGS[0] = 'Hunter_Kill':
		*clr & cla
		gs 'stat'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="images/system/gameover/stab.jpg"</center>'
		*nl
		'You tried but there was nothing you could have done.  Your last feeling is that of his blade penetrating into your flesh before performing the coup-de-grace on your reduced form.  What a waste that it had to end this way...'
		act 'Accept your fate' : gt 'gameover', 'endscreen'
	end
	
	if $ARGS[0] = 'Police_Talk':
		*clr & cla
		minut += rand(10,20)
		gs 'stat'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="mod/addedflavour/images/shared/Hunter/PoliceTalk.jpg"></center>'
		*nl
		if ARGS[1] = 1:
			modVar_AF_EventProgress['HunterState'] = 2
			'"Hello, I don''t know quite what to do but I need to report that someone has started following me and I am worried it will escalate into something much worse..."'
			*nl
			'<font color="Olive">"I understand, young lady.  As it happens we have had a growing number of reports lately about suspicious individuals stalking young women so we are already putting a plan into operation to deal with it.  Don''t worry, you will start seeing a lot more police about from now on."</font>'
			*nl
			'"Thank you officer, that is so re-assuring to hear.  I really didn''t know what I was going to do; I hope it is enough to stop whoever it is."'
		elseif ARGS[1] = 2:
			'"Hello, I don''t know quite what to do but I need to report that someone has started following me and I am worried it will escalate into something much worse..."'
			*nl
			'<font color="Olive">"Let me get this straight; you are here because you THINK someone is following you... but you have no evidence or even confirmation you have even see someone...  I am sorry Miss but you should only come here with REAL crimes."</font>'
			*nl
			'"But...."'
			*nl
			'<font color="Olive">"Please leave now young Miss; there is people behind you waiting..."</font>'
		elseif ARGS[1] = 3:
			modVar_AF_EventProgress['HunterState'] = 2
			'"Umm... I need to report a... a rape..."'
			*nl
			'<font color="Olive">"You were raped?"</font>'
			*nl
			'"...yes"'
			*nl
			'<font color="Olive">"OK; I fully understand your position and don''t worry, we have the upmost discresion here.  We''ll get Police Officers on the streets to hunt down your attacker.  Do you have a description?"</font>'
			*nl
			'"Unfortunately No, he held me down from behind and made sure I didn''t see him..."'
			*nl
			'<font color="Olive">"OK... now, it is important to be on your guard from now on.  If you are being targeted then he will try again but we will have a lot more police walking the streets so if you are in trouble then try and reach one of them."</font>'
			*nl
			'"Thank you sir."'
		end
		act 'Leave' : gt $loc, $loc_arg
	end

--- mod_addedflavour_Hunter ---------------------------------