AddedFlavour/locations/mod_addedflavour.qsrc

# mod_addedflavour
	!$mod_image_folder = 'mod/addedflavour/images/'
	
	!! Location Triggers !!
	if $curloc = 'Gadbana' : gs 'mod_addedflavour_LocationTriggers' , 'GrandparentsBathroom'
	if $curloc = 'gaddvor' : gs 'mod_addedflavour_LocationTriggers' , 'GrandparentsYard'
	if $curloc = 'dolls' or $curloc = 'shop_dolls' : gs 'mod_addedflavour_LocationTriggers' , 'PatchworkDolls'
	if $curloc = 'gadhouse' : gs 'mod_addedflavour_LocationTriggers' , 'GrandparentsHome'
	if $curloc = 'bedr' : gs 'mod_addedflavour_LocationTriggers' , 'CityAptBedroom'
	if $curloc = 'balkon' : gs 'mod_addedflavour_LocationTriggers' , 'CityAptBalcony'
	if $curloc = 'korr' : gs 'mod_addedflavour_LocationTriggers' , 'CityAptCorridor'
	if $curloc = 'kuhr' : gs 'mod_addedflavour_LocationTriggers' , 'CityAptKitchen'
	if $curloc = 'sitr' : gs 'mod_addedflavour_LocationTriggers' , 'CityAptSittingRoom'
	if $curloc = 'vanr' : gs 'mod_addedflavour_LocationTriggers' , 'CityAptBathroom'
	if $curloc = 'city_residential' : gs 'mod_addedflavour_LocationTriggers' , 'CityResidential'
	if $curloc = 'meadow' : gs 'mod_addedflavour_LocationTriggers' , 'GadukinoMeadow'
	if $curloc = 'gadukino' : gs 'mod_addedflavour_LocationTriggers' , 'GadukinoCentre'
	if $curloc = 'bedrPar' : gs 'mod_addedflavour_LocationTriggers' , 'PavBedroom1'
	if $curloc = 'pav_complex' : gs 'mod_addedflavour_LocationTriggers' , 'PavComplex'
	if $curloc = 'korrPar' : gs 'mod_addedflavour_LocationTriggers' , 'PavCorridor'
	if $curloc = 'exhibitionistshop' : gs 'mod_addedflavour_LocationTriggers' , 'ExhibitionistShop'
	if $curloc = 'pav_park' : gs 'mod_addedflavour_LocationTriggers' , 'PavlovskPark'
	if $curloc = 'vanrPar' : gs 'mod_addedflavour_LocationTriggers' , 'PavBathroom'
	if $curloc = 'pav_industrial' and menu_off = 0:
		act 'Walk to the Delivery Depot (0:05)' : minut += 5 & gt 'mod_addedflavour_pav_depot' , 'start'
	end
	if $curloc = 'city_park': gs 'mod_addedflavour_LocationTriggers' , 'CityPark'
	if $curloc = 'torgcentr' : gs 'mod_addedflavour_LocationTriggers' , 'CityMallPrecinct'
	if $loc = 'club' and $curloc ! 'mod_addedflavour_SFLA_NPCInteract' and $menu_loc = 'club' and $menu_arg = 'inside' and menu_off = 0: gs 'mod_addedflavour_LocationTriggers' , 'CityNightClub'
	if $curloc = 'city_center' : gs 'mod_addedflavour_LocationTriggers' , 'CityCentre'
	if $curloc = 'univer' : gs 'mod_addedflavour_LocationTriggers' , 'CityUniversity'
	if $curloc = 'city_island' : gs 'mod_addedflavour_LocationTriggers' , 'CityIsland'
	if $curloc = 'city_library' : gs 'mod_addedflavour_LocationTriggers' , 'CityLibrary'
	if $curloc = 'shopdacha' : gs 'mod_addedflavour_LocationTriggers' , 'CityMallWorkshop'
	if $curloc = 'foto' : gs 'mod_addedflavour_LocationTriggers' , 'CityPhotoAgency'
	if $curloc = 'dorm' : gs 'mod_addedflavour_LocationTriggers' , 'CityUniversityDorms'
	if $curloc = 'gschool_grounds' : gs 'mod_addedflavour_LocationTriggers' , 'PavSchool'
	if $curloc = 'pav_residential' : gs 'mod_addedflavour_LocationTriggers' , 'PavResidential'
	if $curloc = 'gdksport' : gs 'mod_addedflavour_LocationTriggers' , 'PavCommCentre'
	if $curloc = 'city_island' and menu_off = 0:
		act 'Walk to the Volleyball Stadium (0:10)' : minut += 10 & gt 'mod_addedflavour_city_vstadium' , 'start'
		act 'Walk to the University Fields (0:05)' : minut += 5 & gt 'mod_addedflavour_city_upitch' , 'start'
	end
	if $curloc = 'pav_train_hall' : gs 'mod_addedflavour_LocationTriggers' , 'PavTrainHall'
	if $curloc = 'lakecafe' : gs 'mod_addedflavour_LocationTriggers' , 'CityBarbeque'
	if $curloc = 'pav_station' : gs 'mod_addedflavour_LocationTriggers' , 'PavPoliceStation'
	if $curloc = 'city_industrial' : gs 'mod_addedflavour_LocationTriggers' , 'CityIndustrial'
	
	!! Character Talk Triggers !!
	if $curloc = 'mother' : gs 'mod_addedflavour_A29_Functions' , 'TalkEvents'
	if $curloc = 'sister_chat' : gs 'mod_addedflavour_A33_Functions' , 'TalkEvents'
	if $curloc = 'brother' : gs 'mod_addedflavour_A34_Functions' , 'TalkEvents'
	if $curloc = 'father' : gs 'mod_addedflavour_A28_Functions' , 'TalkEvents'
	
	if $curloc = 'Timofei' : gs 'mod_addedflavour_A77_Functions' , 'TalkEvents'
	
	!! Runs code for Mother scenes !!
	if Storyline = 1:
		if home_owned[2] = 0 and (momKnowsKolka = 1 or momKnowsVladimir = 1) and modVar_AF_EventProgress['A29-MotherConfidence'] > modVar_AF_EventGates['A29-MotherConfidence-4'] : modVar_AF_EventOpen['A29-PregRedemption'] = 1
		if modVar_AF_EventOpen['A29-PregRedemption'] = 1 and indorf = 1 and grandmaQW['block'] ! 1 : grandmaQW['block'] = 1 & modVar_AF_LocBlock['GrandparentsYard'] = 1
		if modVar_AF_LocBlock['GrandparentsYard'] = 1 and indorf = 0 : grandmaQW['block'] = 0 & modVar_AF_LocBlock['GrandparentsYard'] = 0
		if home_owned[2] = 1 and Storyline = 1 : modVar_AF_EventOpen['A29-PregRedemption'] = 0
		if modVar_AF_EventOpen['A29-PregRedemption'] = 1 and modVar_AF_EventLock['A29-VisitGrandparents'] ! daystart:
			modVar_AF_EventLock['A29-VisitGrandparents'] = daystart
			if rand(1,difficulty) = 1 and (week > 5):
				indorf = 1
			else
				indorf = 0
			end
		end
		if ($curloc = 'kuhrPar' or $curloc = 'korrPar' or $curloc = 'SitrPar') and indorf = 0 and momloc['athome'] = 1:
			if modVar_AF_EventProgress['A29-MotherConfidence'] > modVar_AF_EventGates['A29-MotherConfidence-4'] and modVar_AF_EventLock['A29-HomeFlash'] ! daystart and rand(1,(6 + difficulty)) = 1 : gt 'mod_addedflavour_A29_Events' , 'A29-HomeFlash'
		end
	end
	
	!! Fires events for Mother leaving City Apartment !!
	if Storyline = 1:
		if modVar_AF_EventOpen['A29-AptStayEv'] = 1 and hour >= 9:
			if $loc = 'kuhr' or $loc = 'korr' or $loc = 'vanr' or $loc = 'sitr' or $loc = 'balkon' or $loc = 'bedr':
				gs 'mod_addedflavour_A29_Functions' , 'A29-AptStayEv-Config' , 'Leave'
				gt 'mod_addedflavour_A29_Events' , 'A29-AptStayEv-Leave'
			end
		elseif modVar_AF_EventOpen['A29-AptStayEv'] = 1 and hour >= 11:
			gs 'mod_addedflavour_A29_Functions' , 'A29-AptStayEv-Config' , 'Leave'
		end
	end
	
	!! Runs code for Sister scenes !!
	if Storyline = 1:
		if ((npc_pregtalk['A33'] = 1 and $fath = 'Kolka') or (sisterLesb >= 6 and (brothersex >= 7 or brother['SexQW'] >= 7))) and modVar_AF_EventOpen['A33-BroSexTalk-1'] = 0 and npc_rel['A33'] >= 80 : modVar_AF_EventOpen['A33-BroSexTalk-1'] = 1
		if modVar_AF_EventLock['A33-SibSexEv'] ! daystart and modVar_AF_EventOpen['A33-SibSexEv'] >= 1 : modVar_AF_EventOpen['A33-SibSexEv'] = 0
		if daystart > modVar_AF_EventProgress['A33-SibThreesomeEv-SisInv'] : modVar_AF_EventProgress['A33-SibThreesomeEv-SisInv'] = 0
		if daystart > modVar_AF_EventProgress['A33-SibThreesomeEv-BroInv'] : modVar_AF_EventProgress['A33-SibThreesomeEv-BroInv'] = 0
	end
	
	!! Runs code for Stepfather scenes !!
	if Storyline = 1:
		if modVar_AF_DeliveryVanSetup ! daystart : gs 'mod_addedflavour_pav_depot' , 'setupvanlocs'
		if arrpos('$modArr_AF_DeliveryVanOptions',$loc) ! -1:
			gs 'mod_addedflavour_charsche' , 'chkschedule'
			gs 'mod_addedflavour_A28_Functions' , 'A28-WorkEv-X1'
			if modVar_AF_DeliveryJob['KnowValeri'] = 1 : gs 'mod_addedflavour_A704_Functions' , 'A704-WorkEv-X1'
		end
		if modVar_AF_DeliveryJob['State'] = 2:
			if modVar_AF_DeliveryJob['Issued'] ! daystart : gs 'mod_addedflavour_pav_depot' , 'generatejobs'
			if $menu_loc = 'liamelkafe' and $menu_arg = 'start' and arrpos('$modArr_AF_DeliveryJobTaken','liamelkafe') >= 0: $loc = 'liamelkafe' & $loc_arg = 'start'
			if arrpos('$modArr_AF_DeliveryJobTaken',$loc) >= 0 : gs 'mod_addedflavour_pav_depot' , 'deliverylocation'
		end
	end
	
	!! Runs code for Ilya scenes !!
	if Storyline = 1 and (kanikuli = 0 and SchoolAtestat = 0) and modVar_AF_BlockEvents['A130'] = 0:
		if hour = 8 and minut = 50 and (week = 1 or week = 3 or week = 5) and $loc = 'gschool_grounds' and $loc_arg = 'bulding' : gs 'mod_addedflavour_A130_Functions' , 'LessonEvent'
		if hour = 9 and (minut >= 35 and minut < 36) and $loc = 'gschool_lunch' and $loc_arg = 'break' : gs 'mod_addedflavour_A130_Functions' , 'HallEvent'
	end
	
	!! Runs code for SFLA scenes !!
	if modVar_AF_EventProgress['SFLA-AptLive'] = 3:
		if modVar_AF_SFLA_DayTracker['Day'] ! daystart : gs 'mod_addedflavour_SFLA_Functions' , 'SFLA-AptLive-EndDay'
		if modVar_AF_SFLA_KolkaVisit['InTransit'] = 1 and daystart >= modVar_AF_SFLA_KolkaVisit['BookingDate'] and week = 6 and hour = 10:
			'<b>You have a <a href="exec: gt ''mod_addedflavour_A34_Events'' , ''SFLA-AptGuest-KolkaCollect-X1'' ">Message</a> on your phone!</b>'
		elseif modVar_AF_SFLA_KolkaVisit['InTransit'] = 1 and daystart >= modVar_AF_SFLA_KolkaVisit['BookingDate'] and week = 6 and hour > 10:
			gt 'mod_addedflavour_A34_Events' , 'SFLA-AptGuest-KolkaCollect-X1' , 'late'
		end
		if daystart >= modVar_AF_SFLA_KolkaVisit['LeaveDate'] and modVar_AF_SFLA_AptState['SpareRoomOccupied'] = 2 and modVar_AF_SFLA_AptState['GuestID'] = 34:
			if hour >= 12:
				gs 'mod_addedflavour_SFLA_Functions' , 'guestvisit' , 'kolka' , 'leave'
			end
		end
		if modVar_AF_EventOpen['SFLA-ClubActive'] > 0:
			*nl
			'<b>You have a <a href="exec: gt ''mod_addedflavour_SFLA_Events'' , ''SFLA-ClubActive-Alert'' ">Message</a> on your phone!</b>'
		end
	elseif modVar_AF_EventProgress['SFLA-AptLive'] = 1 or modVar_AF_EventProgress['SFLA-AptLive'] = 2:
		if modVar_AF_EventProgress['SFLA-AptLive'] = 2 and modVar_AF_EventLock['SFLA-AptInvEv'] ! daystart and (hour >= 9 and hour <= 18):
			modVar_AF_EventLock['SFLA-AptInvEv'] = daystart
			modVar_AF_Rand = rand(modVar_AF_EventOpen['SFLA-AptInvEv-PhoneCall'],(modVar_AF_EventOpen['SFLA-AptInvEv-PhoneCall'] + 5))
			if daystart > modVar_AF_Rand:
				modVar_AF_EventOpen['SFLA-AptInvEv'] = 1
			end
		end
		if modVar_AF_EventOpen['SFLA-AptInvEv'] = 1 and menu_off = 0 and Karta >= 1000 and modVar_AF_EventProgress['SFLA-AptLive'] = 2:
			'<b>You have a <a href="exec: gt ''mod_addedflavour_SFLA_Events'' , ''SFLA-AptLive-MoveIn'' ">Message</a> on your phone!</b>'
		end
	end
	
	!! Runs code for Photography Events !!
	if modVar_AF_EventOpen['PhotographyEv'] = daystart and modVar_AF_EventProgress['PhotographyEv'] >= 1:
		$modVar_AF_TempStr = $curloc
		if arrpos('$modVar_AF_PhotoName',$modVar_AF_TempStr) ! -1:
			modVar_AF_Temp = arrpos('$modVar_AF_PhotoName',$modVar_AF_TempStr)
			if modVar_AF_PhotoTaken[modVar_AF_Temp] ! 1:
				if $curloc = 'psiklin' and $menu_arg = 'ps1' and (hour >= 8 and hour <= 19):
					act 'Take Photograph' : gt 'mod_addedflavour_Functions' , 'takephotograph' , $curloc
				elseif ($curloc = 'mother' or $curloc = 'sister_chat' or $curloc = 'lakecafe') and menu_off = 1:
					act 'Take Photograph' : gt 'mod_addedflavour_Functions' , 'takephotograph' , $curloc
				elseif ($curloc ! 'psiklin' or $curloc = 'mother' or $curloc = 'Sister') and menu_off = 0 and (hour >= 8 and hour <= 19):
					act 'Take Photograph' : gt 'mod_addedflavour_Functions' , 'takephotograph' , $curloc
				end
			end
		end
	end
	
	!! Runs code for Savings Goal Tracker Integration !!
	if $curloc = 'clothing' or $curloc = 'carF1' and $wloc ! 'wardrobe':
		if $curloc = 'carF1':
			gs 'mod_addedflavour_Functions' , 'setcardetails' , $loc_arg
		elseif $curloc = 'clothing':
			$modVar_AF_TempStr = $Result
			if len($modVar_AF_TempStr) <= 4 : $modVar_AF_TempStr = $loc + ' ' + $modVar_AF_TempStr
			modVar_AF_Temp = Price
		end
		if arrpos('$modArr_AF_SUTItemName',$modVar_AF_TempStr) = -1:
			act 'Add to Savings Goal Tracker' : gs 'mod_addedflavour_Functions' , 'addtosgt' , $modVar_AF_TempStr , modVar_AF_Temp & gt $loc, $loc_arg
		else
			act 'Remove from Savings Goal Tracker' : gs 'mod_addedflavour_Functions' , 'removefromsgt' , $modVar_AF_TempStr & gt $loc, $loc_arg
		end
	end
	
	!! Runs code for Football !!
	if $curloc = 'komp' and modVar_AF_EventProgress['Football'] >= 1:
		act 'View Womens Football Leagues' : gs 'mod_addedflavour_Football' , 'DisplayLeagues' , 'League 1'
	end
	
	!! Runs code for Hunter !!
	if modVar_AF_EventOpen['HunterActive'] = 1:
		if menu_off = 1 : modVar_AF_EventOpen['HunterEncounter'] = 0
		if modVar_AF_EventOpen['HunterEncounter'] = 1 and MSECSCOUNT >= (modVar_AF_EventGates['HunterEncounter'] + modVar_AF_HunterOffset):
			modVar_AF_EventOpen['HunterEncounter'] = 0
			gt 'mod_addedflavour_Hunter' , 'Hunter_Encounter'
		elseif modVar_AF_EventOpen['HunterEncounter'] = 1 and arrpos('$modArr_AF_HunterLocs',$curloc) ! -1:
			modVar_AF_EventGates['HunterEncounter'] = MSECSCOUNT
			modVar_AF_HunterOffset -= (2000 + (difficulty * 500))
			if sound = 0:
				CLOSE ALL
				PLAY 'mod/addedflavour/sound/Footsteps.mp3'
			else
				*nl
				'<b>You hear FOOTSTEPS coming from behind YOU!!!</b>'
			end
		else
			modVar_AF_EventOpen['HunterEncounter'] = 0
		end
		if arrpos('$modArr_AF_HunterLocs',$curloc) ! -1 and (modVar_AF_EventLock['HunterEncounter'] ! daystart and modVar_AF_EventLock['HunterEncounter'] ! (daystart + 1)):
			gs 'mod_addedflavour_Hunter' , 'Hunter_Chance'
			modVar_AF_Rand = rand(modVar_AF_HunterChance,100)
			if modVar_AF_Rand >= 100:
				modVar_AF_EventLock['HunterEncounter'] = daystart
				modVar_AF_EventOpen['HunterEncounter'] = 1
				modVar_AF_EventGates['HunterEncounter'] = MSECSCOUNT
				modVar_AF_HunterOffset = 10000
				if sound = 0:
					CLOSE ALL
					PLAY 'mod/addedflavour/sound/Footsteps.mp3'
				else
					*nl
					'<b>You hear FOOTSTEPS coming from behind YOU!!!</b>'
				end
			end
		end
	end
	
	!! Runs code for Pregnancy Features !!
	if modVar_AF_EventOpen['PregnancyBrace'] = daystart and modVar_AF_EventLock['PregnancyBrace'] ! hour:
		modVar_AF_EventLock['PregnancyBrace'] = hour
		if PregChem >= 5208:
			pcs_mood += 20
		elseif PregChem >= 4200:
			pcs_mood += 5
		end
	end
	if knowpreg = 1:
		if $locclass = 'livingr' : $modVar_AF_TempStr = 'There is a '
		if $locclass = 'kitr' and modVar_AF_EventLock['PregnancyPills'] ! daystart and modArr_AF_MaternityItemOwned[arrpos('$modArr_AF_MaternityItemName','Morning Sickness Pills')] > 0 and menu_off = 0:
			act 'Take Morning Sickness Pills' : gt 'mod_addedflavour_Functions' , 'PregPills'
		end
	end
	if $locclass = 'bedr' and modVar_AF_EventOpen['PregnancyBrace'] ! daystart and modArr_AF_MaternityItemOwned[arrpos('$modArr_AF_MaternityItemName','Pregnancy Brace')] = 1 and menu_off = 0:
		*nl
		if PregChem >= 3696:
			'You see your <a href="exec: gt ''mod_addedflavour_Functions'' , ''PregBrace'' ">Pregnancy Brace</a> on the floor'
		elseif knowpreg = 1:
			'You see your Pregnancy Brace on the floor, but you are not at the stage where you can use it'
		else
			'You see your Pregnancy Brace on the floor, but you are not pregnant'
		end
	end
	if modArr_AF_MaternityItemOwned[arrpos('$modArr_AF_MaternityItemName','Pregnancy Ball')] = 1 and menu_off = 0:
		if PregChem >= 4200:
			$modVar_AF_TempStr += '<a href="exec: gt ''mod_addedflavour_Functions'' , ''PregBall'' ">Pregnancy Ball</a>'
		else
			$modVar_AF_TempStr += 'Pregnancy Ball'
		end
	end
	if modArr_AF_MaternityItemOwned[arrpos('$modArr_AF_MaternityItemName','Pregnancy Pillow')] = 1 and menu_off = 0:
		if $modVar_AF_TempStr = 'There is a Pregnancy Ball' or $modVar_AF_TempStr = 'There is a <a href="exec: gt ''mod_addedflavour_Functions'' , ''PregBall'' ">Pregnancy Ball</a>' : $modVar_AF_TempStr += ' and '
		if PregChem >= 2688:
			$modVar_AF_TempStr += '<a href="exec: gt ''mod_addedflavour_Functions'' , ''PregPillow'' ">Pregnancy Pillow</a>'
		else
			$modVar_AF_TempStr += 'Pregnancy Pillow'
		end
	end
	if $locclass = 'livingr' and knowpreg = 1 and menu_off = 0:
		$modVar_AF_TempStr += ' here'
		if $modVar_AF_TempStr ! 'There is a  here':
			*nl
			'<<$modVar_AF_TempStr>>'
		end
	end
	
	!! Runs code for Mod Systems and Settings !!
	if $curloc = 'journal' : gs 'mod_addedflavour_journal' , 'start'
	if $curloc ! 'mod_setting' and $curloc ! 'mod_addedflavour_Functions' and $curloc ! 'mod_addedflavour_options' : $modVar_AF_CurLoc = $CurLoc
	if $modVar_AF_ModVersion ! 'Ver1.6.2' : $modVar_AF_ModVersion = 'Ver1.6.2'
	if $modVar_AF_SaveVersion = '' : $modVar_AF_SaveVersion = $modVar_AF_ModVersion
	if Enable_FaceTurn = 2 and menu_off = 0 : view 'mod/addedflavour/images/pc/<<$modVar_AF_ProfPicName>>'
	if Enable_FaceTurn = 3:
		gs 'mod_addedflavour_Functions' , 'pcs_reticence' , 'chkpossible' , 0
		if modVar_AF_Inhib['Result'] = 0 : view 'mod/addedflavour/images/pc/GoodStudent.jpg'
		if modVar_AF_Inhib['Result'] = 1 : view 'mod/addedflavour/images/pc/CuriousStudent.jpg'
		if modVar_AF_Inhib['Result'] = 2 : view 'mod/addedflavour/images/pc/SexualStudent.jpg'
		if modVar_AF_Inhib['Result'] = 3 : view 'mod/addedflavour/images/pc/BimboStudent.jpg'
	end
	if Enable_FaceTurn = 5:
		$modVar_AF_TempStr = FUNC('$body_image','body')
		view '<<$modVar_AF_TempStr>>'
	end
	if modVar_AF_InitialConfigRun ! 1 : gs 'mod_addedflavour_Functions' , 'InitialConfig'
	if $modVar_AF_NPCLastKnownLocation['DayTracker'] ! daystart : KILLVAR '$modVar_AF_NPCLastKnownLocation' & $modVar_AF_NPCLastKnownLocation['DayTracker'] = daystart

--- mod_addedflavour ---------------------------------