AddedFlavour/locations/mod_addedflavour_SFLA_Sitr.qsrc

# mod_addedflavour_SFLA_Sitr
	if $ARGS[0] = 'start' or $ARGS[0] = '':
		*clr & cla
		CLOSE ALL
		$locM = 'mod_addedflavour_SFLA_Sitr'
		$locM_arg = 'start'
		$loc = 'mod_addedflavour_SFLA_Sitr'
		$loc_arg = 'start'
		$menu_loc = 'mod_addedflavour_SFLA_Sitr'
		$menu_arg = 'start'
		menu_off = 0
		$location_type = 'private'
		$locclass = 'livingr'
		gs 'themes', 'indoors'
		gs 'mod_addedflavour_charsche' , 'chkschedule'
		gs 'stat'
		if modVar_AF_SFLA_AptContributions['PCS'] < 0:
			$modVar_AF_PlayerWarning['SFLA-InDebt'] = 1
		else
			$modVar_AF_PlayerWarning['SFLA-InDebt'] = 0
		end
		if modVar_AF_SFLA_AptContributions['PCS'] < -5000 and (hour >= 9 and hour < 23):
			gt 'mod_addedflavour_SFLA_Events' , 'SFLA-AptLive-KickOut'
		end
		if sound = 0 : gs 'mod_addedflavour_SFLA_Functions' , 'soundgen'
		if modVar_AF_LocBlock['SFLA_Bedr1'] = 1:
			gs 'mod_addedflavour_SFLA_Functions' , 'whoelse' , 'mod_addedflavour_SFLA_Bedr1' , 'Sex'
			if arrsize('modArr_AF_SFLA_SharedActPeopleArray') = 0 : modVar_AF_LocBlock['SFLA_Bedr1'] = 0
		elseif modVar_AF_LocBlock['SFLA_Bedr2'] = 1:
			gs 'mod_addedflavour_SFLA_Functions' , 'whoelse' , 'mod_addedflavour_SFLA_Bedr2' , 'Sex'
			if arrsize('modArr_AF_SFLA_SharedActPeopleArray') = 0 : modVar_AF_LocBlock['SFLA_Bedr2'] = 0
		elseif modVar_AF_LocBlock['SFLA_Bedr3'] = 1:
			gs 'mod_addedflavour_SFLA_Functions' , 'whoelse' , 'mod_addedflavour_SFLA_Bedr3' , 'Sex'
			if arrsize('modArr_AF_SFLA_SharedActPeopleArray') = 0 : modVar_AF_LocBlock['SFLA_Bedr3'] = 0
		end
		if modVar_AF_SFLA_AptRProg['Sitr'] >= modVar_AF_SFLA_AptRProg['Lv2Req']:
			$modVar_AF_TempStr = 'Lv2'
		else
			$modVar_AF_TempStr = 'Lv1'
		end
		'<center><b><font color="maroon">Living Room</font></b></center>'
		'<center><img style="<<$modVar_AF_ImageRestrictions>>" src="mod/addedflavour/images/locations/city/citycenter/SharedFLApartment/Sitr<<$modVar_AF_TempStr>>.jpg"></center>'
		gs 'mod_addedflavour_SFLA_Functions' , 'SFLA-UpgradeRoom-Check' , 'Sitr'
		if modVar_AF_SFLA_AptRProg['Sitr'] >= modVar_AF_SFLA_AptRProg['Lv2Req']:
			'You are standing in a very nice looking Living Room with plenty of space and seating, all set in an environment of peace and comfort.'
		else
			'You are standing in an open Lounge.  It is acting as the hub for the whole apartment as well as the first room you see as you come through the door.'
		end
		gs 'mod_addedflavour_SFLA_Functions' , 'SFLA-PeoplePresent-Display' , 'mod_addedflavour_SFLA_Sitr'
		*nl
		'<b>Bulletin Board:</b>'
		'A Sheet of Paper detailing Apartment <a href="exec: gt ''mod_addedflavour_SFLA_Functions'' , ''SFLA-AptBoard-Contributions'' ">Finances</a>'
		*nl
		if $modVar_AF_PlayerWarning['SFLA-RentPaid'] = 1:
			'<font color="Red">Your Rent of <<modVar_AF_SFLA_AptState[''Rent'']>>₽ has been taken out of your contributions for this week</font>'
			*nl
		end
		if $modVar_AF_PlayerWarning['SFLA-InDebt'] = 1:
			modVar_AF_Temp = (modVar_AF_SFLA_AptContributions['PCS'] - modVar_AF_SFLA_AptContributions['PCS']) - modVar_AF_SFLA_AptContributions['PCS']
			'<font color="Red">You are behind in your payments by <<modVar_AF_Temp>>₽</font>'
			*nl
		end
		if modVar_AF_SFLA_KolkaVisit['LeaveDate'] = daystart:
			'<font color="Red">Kolka is leaving the Apartment to go back home today</font>'
			*nl
		elseif modVar_AF_SFLA_KolkaVisit['LeaveDate'] - 1 = daystart:
			'<font color="Red">Kolka is leaving the Apartment to go back home tomorrow</font>'
			*nl
		end
		'<b>Furniture:</b>'
		'A Sofa to Relax on or <a href="exec: gt ''mod_addedflavour_SFLA_Events'' , ''watchtv'' ">Watch TV</a>'
		act 'Watch TV (0:30)' : gt 'mod_addedflavour_SFLA_Events' , 'watchtv'
		if modVar_AF_SFLA_AptRProg['Sitr'] >= modVar_AF_SFLA_AptRProg['Lv2Req']:
			*nl
			'<b>Activities</b>'
			'A <a href="exec: gt ''mod_addedflavour_SFLA_Events'' , ''videogames'' ">Video Game Console</a> hooked up to the TV'
			act 'Play Video Games(0:30)' : gt 'mod_addedflavour_SFLA_Events' , 'videogames'
		end
		act 'Relax (0:30)' : gt 'mod_addedflavour_SFLA_Events' , 'relax' , 30
		if komp = 1:
			act 'Fetch Laptop (0:15)' : gt 'mod_addedflavour_SFLA_Events' , 'computertime' , 'PCS'
		end
		act '<b>Go To Kitchen</b>' : minut += 1 & gt 'mod_addedflavour_SFLA_Kit' , 'start'
		if modVar_AF_LocBlock['SFLA_Bedr1'] = 0:
			act '<b>Go To Kazumi''s Room</b>' : minut += 1 & gt 'mod_addedflavour_SFLA_Bedr1' , 'start'
		end
		if modVar_AF_LocBlock['SFLA_Bedr2'] = 0:
			act '<b>Go To Elizabeth''s Room</b>' : minut += 1 & gt 'mod_addedflavour_SFLA_Bedr2' , 'start'
		end
		if modVar_AF_LocBlock['SFLA_Bedr3'] = 0:
			act '<b>Go To Janina''s Room</b>' : minut += 1 & gt 'mod_addedflavour_SFLA_Bedr3' , 'start'
		end
		act '<b>Go To <<$pcs_firstname>>''s Room</b>' : minut += 1 & gt 'mod_addedflavour_SFLA_Bedr4' , 'start'
		act '<b>Go To Spare Room</b>' : minut += 1 & gt 'mod_addedflavour_SFLA_SpRm' , 'start'
		act '<b>Go To Balcony</b>' : minut += 1 & gt 'mod_addedflavour_SFLA_Bal' , 'start'
		if $clothingworntype ! 'nude':
			act '<b>Leave Apartment</b>' : minut += 5 & gt 'city_center'
		else
			*nl
			'<b>You cannot leave the Apartment with no clothes on!!!</b>'
		end
	end

--- mod_addedflavour_SFLA_Sitr ---------------------------------