Bratva/locations/bratva_home.qsrc

# bratva_home
$loc = $curloc

if $ARGS[0] = 'bcorridor':
	$loc = 'bratva_home'
	$loc_arg = 'bcorridor'
	$locM_arg = 'bcorridor'
	$location_type = 'private'
	$menu_loc = 'bratva_home'
	$menu_arg = 'bcorridor'
	menu_off = 0
	killvar '$locclass'
	*clr & cla
	frost = 0
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'bratva_events','bratva_check'
	gs 'bratva_home', 'Bratva_tip_tip'
	'<center><b><font color="maroon">Entrance hall</font></b></center>'
	'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/bratva/home/korr.jpg"></center>'
	'Large wall hanging <a href="exec:GT ''mirror'',''start''">mirror</a>'
	act 'To the room': gt 'bratva_home','room'
	act 'To the kitchen': gt 'bratva_home','kitchen'
	act 'Go to bathroom': gt 'bratva_home','bathroom'
	!! Conditions for starting an event when the thief''s first event fails
	if bratva['thieffail'] = 1 : gt 'bratva_thief','eventthief2'
	!---
	if bratva['location'] = 1 and bratva['stage'] < 20:
		! Sveta finds documents of one of the bandits
		if bratva['documents'] = 0: gt 'bratva_home_events','eventmini1'
		! escape sveta slave
		if bratva['escape_day'] ! daystart and bratva['stage'] >= 6 and bratva['stage'] <= 8: gt 'bratva_home_events','event13'
	end
	! Self care from the apartment
	if bratva['stage'] >= 20: act '<b>Leave</b>': gt 'city_industrial'
end

if $args[0] = '' or $args[0] = 'room':
	$menu_loc = 'bratva_home'
	$menu_arg = 'room'
	menu_off = 0
	$loc = 'bratva_home'
	$loc_arg = 'room'
	minut += 1
	*clr & cla
	gs 'stat'
	gs 'bratva_events','bratva_check'
	gs 'bratva_home', 'Bratva_tip'
	'<center><b><font color="maroon">Room</font></b></center>'
	'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/bratva/home/bedr.jpg"></center>'
	'In the room there is a <a href="exec: gt ''bed'',''start''">bed</a>, a sofa and a <a href="exec: gt ''bratva_home'',''Bratva_telly''">television</a> opposite that. On the shelf near the TV there is a few <a href="exec: gt ''bratva_home'',''Bratva_journal''">pornographic magazines</a> and a <a href="exec: gt ''bratva_home'',''Bratva_book_marquise''">book.</a>'
!!* might use rest in stead of wait
	act 'Wait':gs 'obj_din', 'wait'
	if bratva['location'] = 0: 'Sit on the couch <a href="exec: gt ''mod_bratva_start''">bandits</a>'
	if bratva['location'] ! 0:
		if bratva['counter'] < 2 and bratva['stage'] <= 10:
			if (hour = 8 or hour = 9) and bratva['stage'] = 1: gt 'bratva_home_events','event1'
			if (hour = 14 or hour = 15) and bratva['stage'] = 2: gt 'bratva_home_events','event2'
			if (hour >= 17 and hour <= 19) and bratva['stage'] = 3: gt 'bratva_home_events','event3'
			if hour = 21 or hour = 22:
				if bratva['stage'] = 4: gt 'bratva_home_events','event4'
				if bratva['stage'] = 5: gt 'bratva_home_events','event5'
				if bratva['stage'] = 10: gt 'bratva_home_events','event10'
			end
		end
	end
	! choice of profession
	if bratva['stage'] = 20 and bratva['day'] ! daystart and bratva['location'] = 0 and ((bratva['sniper'] = 0 and bratva['thieffail'] = 0 and bratva['madam'] = 0) or (bratva['thieffail'] = 2 and pcs_agil >= 65)):
		gt 'bratva_home_events','event14'
	end
	
	!The condition of the start of a recurring event
	if hour >= 21 and hour < 23 and bratva['happyend'] > 10 and rand(1,5) = 1 and bratva['bratva_event13'] ! daystart: gt 'bratva_events','bratva_event13'
	!----------------------
	!The condition of the start of the second event with Samantha
	if ((hour >= 8 and hour < 10) or hour = 14 or (hour >= 17 and hour < 20) or (hour >= 21 and hour < 23)) and bratva['madam'] = 3: gt 'bratva_madam','eventmadam4'
	!The condition of the start of the third event with Samantha
	if ((hour >= 10 and hour < 14) or (hour >= 15 and hour < 17)) and bratva['madam'] = 4: act'Have fun with Samantha': gt 'bratva_madam','eventmadam5'
	!Conditions for the start of the event Svetka punishment
	if ((hour >= 8 and hour < 10) or hour = 14 or (hour >= 17 and hour < 20) or (hour >= 21 and hour < 23)) and bratva['madam'] = 5: gt 'bratva_madam','eventmadam6'
	!Conditions for starting a recurring event with Samantha
	if ((hour >= 8 and hour < 10) or hour = 14 or (hour >= 17 and hour < 20) or (hour >= 21 and hour < 23)) and bratva['madam'] = 6 and bratva['eventmadam7'] ! daystart: gt 'bratva_madam','eventmadam7'
	!----------------------
	act 'To hallway': gt 'bratva_home','bcorridor'
end

if $ARGS[0] = 'kitchen':
	$menu_loc = 'bratva_home'
	$menu_arg = 'kitchen'
	$loc = 'bratva_home'
	$loc_arg = 'kitchen'
	$locclass = 'kitr'
	menu_off = 0
	minut += 2
	*clr & cla
	gs 'stat'
	gs 'kit_din'
	gs 'bratva_events','bratva_check'
	gs 'bratva_home', 'Bratva_tip'
	'<center><b><font color="maroon">Kitchen</font></b></center>'
	'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/bratva/home/kuhr.jpg"></center>'
	*nl
	'It''s a modest kitchen, but has all that is required.'
	!!* So when first brought here there is food and such
	if bkitchen_first ! 1:
		bkitchen_first = 1
		cltarelka = 6
		fairy = 21
		eda = 21
	end
	! dishes
	if cltarelka > 0:
		'Above the sink are <b><<cltarelka>></b> the clean plates'
	else
		'<b><font color = red>You have no clean dishes left.</font></b>'
	end
	if dirttarelka > 0:'The sink has <b><<dirttarelka>></b> dirty dishes. <a href="exec: dynamic $dirtarm">that need to be washed</a>.'
	if fairy > 0:
		'Above the sink is some detergent to wash the dishes with. There is enough for <b><<fairy>></b> uses.'
	else
		'<b><font color = red>You do not have enough detergent, you should buy some from the supermarket.</font></b>'
	end

	! food
	if eda > 0:
		if cltarelka = 0 or edahot > 0:$edagot = ''
		if cltarelka > 0 and edahot = 0:
			$edagot = '<a href="exec:dynamic $edagotd">Cook a meal  for yourself (0:30)</a>'
		end
		'In the refrigerator there''s enough (your own) food for <b><<eda>></b> servings. <<$edagot>>'
	end
	if edahot > 0:'<a href="exec: dynamic $edahotd ">On the table is ready meal (0:30).</a>'
	if edaD = 0 and eda = 0:'<b><font color="red">You have nothing to eat, the refrigerator is empty!</font></b>'


	dynamic $edasnack
	dynamic $driwater
	dynamic $dritea
	dynamic $edaD
	dynamic $pranik
	dynamic $fatdel
	dynamic $lekarstvo
	dynamic $vitamin
	
	if bratva['location'] = 1:
		'Sitting at the table <a href="exec: gt ''mod_bratva_start''">Cossacks-robbers</a>'
		if bratva['counter'] < 2 and bratva['stage'] = 9:
			gt 'bratva_home_events','event9'
		end
		! the end of the stay in the apartment is either discarded or a conversation about joining
		if bratva['stage'] = 11:
			if bratva['fail'] > 3:
				bratva['stage'] = 255
				gt 'bratva_home_events','event11'
			else
				bratva['stage'] = 20
				bratva['day'] = daystart
				bratva['agent_zeropussy'] = 1
				gt 'bratva_home_events','event12'
			end
		end
	end
	act 'Return to hallway':gt 'bratva_home','bcorridor'
end

if $args[0] = 'bathroom':
	*clr & cla
	$menu_loc = 'bratva_home'
	$menu_arg = 'bathroom'
	menu_off = 0
	minut += 1
	$location_type = 'bathroom'
	$loc = 'bratva_home'
	$loc_arg = 'bathroom'
	$locM_arg = 'bathroom'
	$locM = 'bratva_home'
	gs 'bratva_events','bratva_check'
	gs 'bratva_home', 'Bratva_tip'
	'<center><h3>Bathroom</h3></center>'
	'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/bratva/home/bath.jpg"></center>'
	*nl
	'Modest bathroom, containing all that young people need for their daily life, such as:'
	'A Shower, toilet, <a href="exec:gt ''mirror'',''start''">mirror</a>, where you can ' +iif(pcs_hairbsh = 0,'<a href="exec:gt ''mirror'',''brush''">brush</a>','brush') + ' your hair, a sink and even a bath tub.'
	*nl
	if bbath_first ! 1:
		bbath_first = 1
		shampoo += 14
		stanok += 1
	end
	gs 'din_van', 'private'
	gs 'stat'
	if bratva['counter'] < 2 and bratva['location'] = 1:
		if bratva['stage'] = 6: gt 'bratva_home_events','event6'
		if bratva['stage'] = 7: gt 'bratva_home_events','event7'
		if bratva['stage'] = 8: gt 'bratva_home_events','event8'
!!*		if bratva['stage'] >= 6 and bratva['stage'] <= 8: gt 'bratva_home_events','event<<bratva['stage']>>'
	end
	act 'Leave':gt 'bratva_home','bcorridor'
end
!
!
!------- Мелкие занятия ------
if $args[0] = 'Bratva_telly':
'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/bratva/mini/04.jpg"></center>'
	'In the TV there is only an informational news, sports channels and porn.'
	act 'Watch sport channel':
		*clr
		minut += 30
		pcs_mood += 10
		gs 'stat'
		'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/bratva/mini/04.jpg"></center>'
		'There is an American football broadcast on TV. ** You are watching this match for about half an hour.'
		gs 'bratva_home', 'Bratva_tip'
	end
	act 'Switch to porn':
		*clr
		minut += 30
		pcs_horny += 15
		pcs_mood += 5
		gs 'stat'
		'<center><video autoplay loop src="mod/Bratva/locations/city/north/bratva/mini/'+rand(5,6)+'.mp4"></video></center>'
		'You watch with excitement, as on the screen a group of men having fun with a girl.'
		gs 'bratva_home', 'Bratva_tip'
	end
	act 'Turn off': gt $loc,$loc_arg
End
!---
if $args[0] = 'Bratva_journal':
	act 'Browse magazines':
		*clr
		minut += 30
		pcs_horny += 25
		gs 'stat'
		'You are looking at pictures with the most severe pornography. The pictures are mostly rough anal sex..'
		gs 'bratva_home', 'Bratva_tip'
	end
	act 'Quit looking': gt $loc,$loc_arg
End
!---
if $args[0] = 'Bratva_book_marquise':
'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/bratva/mini/03.jpg"></center>'
	act 'Read a book':
		*clr
		minut += 60
		pcs_horny += 30
		pcs_dom -= 2
		gs 'stat'
		'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/bratva/mini/03.jpg"></center>'
		'You, without stopping, read the work of the Marquis de Sade for an hour with burning ears. And very excited.'
		gs 'bratva_home', 'Bratva_tip'
	end
	act 'Put': gt $loc,$loc_arg
End
!--- The end of the small classes ---
!--- Tip about someone coming home ---
if $args[0] = 'Bratva_tip':
	if Bratva_single_day2 ! daystart and bratva['counter'] = 1:
		Bratva_single_day2 = daystart
		killvar 'Bratva_single_day'
	elseif Bratva_single_day ! daystart and bratva['counter'] ! 2 and ((hour >= 8 and hour <= 9 and bratva['stage'] = 1) or ((hour = 14 or hour = 15) and bratva['stage'] = 2) or ((hour = 17 or hour = 19) and bratva['stage'] = 3) or ((hour = 21 or hour = 22) and (bratva['stage'] = 4 or bratva['stage'] = 5 or bratva['stage'] = 10)) or (hour = 20 and ((bratva['stage'] >= 6 and bratva['stage'] <= 9) or bratva['stage'] = 11))):
!!*		gs 'zz_funcs','message','', '<center><green>You hear the front door slam the apartment, it seems someone came.</green></center>'
		'<center><green>You hear the front door slam the apartment, it seems someone came.</green></center>'
		Bratva_single_day = daystart
	end
End
!------------------------------------------
--- bratva_home ---------------------------------