Bratva/locations/bratva_pornstudio.qsrc

# bratva_pornstudio
! sites of post-judgment
! work office

$location_type = 'public_indoors'
$loc = $curloc
gs 'bratva_events','bratva_check'
if $args[0] = '' or $args[0] = 'main':
	*clr & cla
	CLOSE ALL
	$loc_arg = 'start'
	$loc = 'pornstudio'
	$menu_loc = 'pornstudio'
	$menu_arg = 'start'
	menu_off = 0
	gs 'themes', 'indoors'
	gs 'stat'
	if studio['init'] = 0: gs 'bratva_pornstudio_init'
	'<center><b><font color="maroon">Office</font></b></center>'
	'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/pornstudio/office.jpg"></center>'
	'Studio Office. From here you direct casting and filming.
		Monthly you pay 10000r. for rent + 500r. for each renovation of premises.
		You give 25% of the profit for the "roof", another 20% - taxes.
		10% of the remaining amount is credited to your card, the rest - to the studio balance.'
	if hour >= 15 and hour <= 16: 'Sitting on the couch are some<a href="exec: gt ''mod_bratva_start''"> Bratva members</a>.'
	gs 'bratva_pornstudio','navigation'
	!Conditions start the event with masturbation
	if pcs_horny >= 40 and hour >= 9 and hour <= 14: act' Caress yourself looking porn': gt 'bratva_studioQW','ofisevent1'
	!Terms and conditions start with Stamos
	if week <= 5 and studio['ofisevent9_day'] ! daystart and rand(1,4) = 1: gt 'bratva_studioQW','ofisevent9'
	! 25% chance of tripping
	if bratva['location'] = 3:
		!Conditions of the start of the event with Inna and Gennady
		if studio['inna'] = 1 and studio['ofisevent2_day'] ! daystart and rand(1,4) = 1: gt 'bratva_studioQW','ofisevent2'
		!The condition of the start of the event with Inna''s threesome
		if studio['ofisevent2'] >= 5 and studio['ofisevent3_day'] ! daystart and rand(1,4) = 1: gt 'bratva_studioQW','ofisevent3'
		!Conditions for starting the event with Gennady
		if week > 5 and studio['ofisevent10_day'] ! daystart: gt 'bratva_studioQW','ofisevent10'
		!The condition of the start of the event with Stas and Gennady
		if studio['ofisevent11_day'] ! daystart and rand(1,4) = 1: gt 'bratva_studioQW','ofisevent11'
		!The condition for starting a mini event in the office with a make-up artist
		if studio['ofisevent2'] = 0 and rand(1,3) = 1: gt 'bratva_studioQW','mini4'
		!The condition for starting a mini-event in office 4 and above
		if studio['room,2'] >= 4 and rand(1,3) = 1: gt 'bratva_studioQW','mini5'
	end
	if hour < 9 or hour > 18: exit
	act 'List of actresses': gt 'bratva_pornstudio_actress','actress_list'
	act 'Filmography studios': gt 'bratva_pornstudio_films','films'
	act 'Studio information': gt 'bratva_pornstudio','studio'
	!---
	if studio['film_day'] ! daystart: act 'To make a movie': gs 'bratva_pornstudio_films','select_film',-1,-1
	act 'How it works':
		*clr & cla
		act 'Close': gt 'bratva_pornstudio'
			'Monthly you pay 10000r. for rent + 500r. for each renovation of premises.
			You give 25% of the profit for the "roof", another 20% - taxes.
			10% of the remaining amount is credited to your card, the rest - to the studio balance.
			Only one movie can be made per day. The quality and, therefore, the rating of the film depends on the development of the infrastructure, but during the repair the shooting is impossible.
			At the moment you can have a maximum of 5 actresses. Each of them has its own set of available genres for filming. For hiring you have to pay an actress bonus of 10,000 rubles.
			To restore the actress need 2 days or more, depending on the genre of the previous film and the development of the recreation area.
			In the lesboscenes, the second actress will always be your heroine - if she is not available, you will not be able to make a film.
			Profit depends on the number of views, advertising can help increase them, but not all advertising is good - choose the right time and amount. After 10 days, the possibility of advertising the film is cut off.
			Daily the number of views will fall and over time the film will cease to make a profit.'
	end
end
! гримерка
if $args[0] = 'dressing_room':
	*clr & cla
	$loc_arg = $args[0]
	gs 'bratva_pornstudio','navigation',$args[0]
	'<center><b><font color="maroon">Office</font></b></center>'
	'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/pornstudio/grim.jpg"></center>'
	'Make-up room, where entertainers of the cheerful genre are preparing for the shooting. Here you can dress up and apply make-up.'
	! Conditions of the start of the event with Inna in the bathroom
	if bratva['location'] = 3 and studio['ofisevent3'] >= 5 and rand(1,4) = 1 and studio['ofisevent4_day'] ! daystart: gt 'bratva_studioQW','ofisevent4'
	! The condition of the start of the event in the bathroom
	if bratva['location'] = 3 and studio['ofisevent6'] = daystart: gt 'bratva_studioQW','ofisevent8'
	! The condition for starting mini-events in the dressing room
	if hour >= 10 and hour < 18 and rand(1,4) = 1: gt 'bratva_studioQW','mini2'
	! The condition for starting mini-events in the dressing room 3 and above
	if hour >= 10 and hour < 18 and studio['room,1'] >= 3 and rand(1,4) = 1: gt 'bratva_studioQW','mini3'
end
! set
if $args[0] = 'shooting_space':
	*clr & cla
	$loc_arg = $args[0]
	gs 'bratva_pornstudio','navigation',$args[0]
	'<center><b><font color="maroon">Office</font></b></center>'
	'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/pornstudio/studia.jpg"></center>'
	'Spacious studio with bright lighting and comfortable wide sofas and beds, on which most of the scenes are shot. It made a good repair, I can not believe that before it was the usual warehouse.'
	!Conditions for starting a mini event in a studio
	if hour >= 10 and hour <= 20 and rand(1,4) = 1: gt 'bratva_studioQW','mini1'
end
! navigation
if $args[0] = 'navigation':
	act '<b>Leave<b>': minut += rand(10,15) & gt 'city_industrial'
	if studio['upgrade'] > 0:
		*clr
		'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/pornstudio/closed.jpg"></center>'
		'The studio is closed for renovation! Opening through <<studio[''upgrade'']>> day.'
		exit
	end
	if $args[1] ! '' and $args[1] ! 'main': act '<font color=maroon>Office</font>': gt 'bratva_pornstudio','main'
	if $args[1] ! 'dressing_room': act '<font color=maroon>Dressing Room</font>': gt 'bratva_pornstudio','dressing_room'
	if $args[1] ! 'shooting_space': act '<font color=maroon>Set</font>': gt 'bratva_pornstudio','shooting_space'
end
! description of studio premises
if $args[0] = 'studio':
	*clr & cla
	act 'Close': gt 'bratva_pornstudio'
	$_studio_str = '<div class="film-info">Profit for the current month: <b><<studio[''money_month'']>></b>р.'
	$_studio_str += 'Last month profit: <b><<studio[''money_last_month'']>></b>р.'
	$_studio_str += 'Studio balance: <b><<studio[''money'']>></b>р.</div>'
	$_studio_str
	!--
	$_studio_str = '<tr><th>Title</th><th>Status</th><th>...</th>'
	$_studio_name[0] = 'Set'
	$_studio_name[1] = 'Make-up room'
	$_studio_name[2] = 'Office'
	$_studio_name[3] = 'Rest zone'
	i = 0
	:loop_studio
	if i < 4:
		$_studio_str += '<tr><td>'+$_studio_name[i]+'</td><td><img src="mod/Bratva/locations/city/north/pornstudio/rating/'+(studio['room,<<i>>']*2)+'.png"></td><td>'+func('bratva_pornstudio','mk_upgrade_str','<<i>>')+'</td></tr>'
		i += 1
		jump 'loop_studio'
	end
	'<center><table width=700 class="film-table">'+$_studio_str+'</table></center>'
	killvar '$_studio_name'
	killvar '$_studio_str'
end
! link building for studio improvement
! $args[1] - room id
if $args[0] = 'mk_upgrade_str':
	_studio_id = val($args[1])
	_studio_price[0] = 40000
	_studio_price[1] = 20000
	_studio_price[2] = 30000
	_studio_price[3] = 50000
	_studio_upgrade_price = (studio['room,<<_studio_id>>'] + 1)*_studio_price[_studio_id]
	if studio['room,<<_studio_id>>'] < 5:
		$result = iif(studio['money'] >= _studio_upgrade_price,'<a href="exec:gt''bratva_pornstudio'',''studio_upgrade'',<<_studio_id>>,<<_studio_upgrade_price>>">Upgrade (<<_studio_upgrade_price>>р.)</a>','Upgrade (<<_studio_upgrade_price>>р.)')
	else
		$result = ''
	end
	killvar '_studio_id'
	killvar '_studio_price'
	killvar '_studio_upgrade_price'
end
! studio repair
if $args[0] = 'studio_upgrade':
	*clr & cla
	act '<b>Leave<b>':
		minut += rand(10,15)
		gt 'city_industrial'
	end
	studio['upgrade_room'] = args[1]
	studio['upgrade'] = 3 + studio['room,<<args[1]>>']
	_studio_upgrade_price = args[2]
	studio['money'] -= _studio_upgrade_price
	'<center><img <<$set_imgh>> src="mod/Bratva/locations/city/north/pornstudio/closed.jpg"></center>'
	'Studio closes on <<studio[''upgrade'']>> days for repairs which will cost <<_studio_upgrade_price>>р.'
	killvar '_studio_upgrade_price'
end
! daily recalculations
if $args[0] = 'update_info':
	! studio renovation
	if studio['upgrade'] > 0:
		studio['upgrade'] -= 1
		if studio['upgrade'] = 0:
			studio['room,<<studio[''upgrade_room'']>>'] += 1
			studio['upgrade_room'] = -1
		end
	end
	! movie ratings
	gs 'bratva_pornstudio_films','update_films_info'
	! actress ratings
	gs 'bratva_pornstudio_actress','update_actress_info'
	! studio ratings
	studio['work_rating'] = studio['room,0'] * 6 + studio['room,1'] * 6 + studio['room,2'] * 3 + studio['room,3'] * 5
	studio['rating'] = (func('bratva_pornstudio_films','avg_rating') + func('bratva_pornstudio_actress','avg_rating'))/2
end
--- bratva_pornstudio ---------------------------------