WLife/locations/mod_wlife_phone.qsrc

# mod_wlife_phone

if $ARGS[0] = 'start':
	*clr & cla
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'

	act 'Put your phone away': gt $loc, $loc_arg

	if wl_wine = 1 and wine = 0: 'Claim the bottle of <a href="exec: wl_wine = 0 & wine = 1 & gt ''mod_wlife_phone'', ''start''">wine</a> Henri gave you as a present.'

	if wl_georgiy['payment_method'] = 1:
		'<br>You have to pay <<wl_georgiy[''lump_sum'']>> <b>₽</b>'+iif(wl_debt['amount'] = 0, '.', ' while you already owe the Belys <<wl_debt[''amount'']>> <b>₽</b>.')+' If you want to work at the gas station, you''ll have to take a bus from the industrial train station in St. Petersburg.'
	elseif week < 7:
		'<br>You have to work <<wl_whore[''shifts_week'']>> shifts for Mr. Bely and have worked <<wl_whore[''shifts_done'']>> this week.'+iif(wl_prison['status'] > 0 and wl_prison['shift'] = 0, ' You have to work one of those shifts at the prison', ' ')+iif(wl_whore['shifts_message'] = 0, 'If you want to work at the gas station'+iif(wl_prison['status'] > 0, ' or at the prison,', ',')+' you have to send Volya a message before 16:00.', iif(hour < 17, '<br>Volya will pick you up outside your parents apartment building between 16:00 and 17:00.', ''))
	elseif week = 7 and wl_georgiy['timer_day'] ! daystart:
		'<br>You have to report to Georgiy at the warehouse today. He is at the warehouse after 20:00. You '+iif(wl_whore['shifts_done'] < wl_whore['shifts_week'], 'haven''t', 'have')+' fulfilled this weeks obligation.'
	elseif week = 7 and wl_georgiy['timer_day'] = daystart:
		'<br>You have reported to Georgiy. Next week you have to work <<wl_whore[''shifts_week'']>> shifts.'
	end

	!!Earnings Check
	if wl_georgiy['payment_method'] = 0:
		if wl_whore['shifts_done'] > 0:
			wl_whore['earnings_check'] = wl_whore['earnings_week'] / wl_whore['shifts_done']

			wl_whore['earnings_check_unmod'] = wl_whore['earnings_check']

			if wl_whore['shifts_minimum'] = 3 and wl_whore['shifts_done'] > wl_whore['shifts_week']: wl_whore['earnings_check'] += 750 * (wl_whore['shifts_done'] - wl_whore['shifts_week'])

			if wl_whore['earnings_check'] < 1500:
				$wl_whore['performance'] = 'a very weak'
			elseif wl_whore['earnings_check'] < 2250:
				$wl_whore['performance'] = 'a weak'
			elseif wl_whore['earnings_check'] < 3250:
				$wl_whore['performance'] = 'a slightly below average'
			elseif wl_whore['earnings_check'] < 4750:
				$wl_whore['performance'] = 'an average'
			elseif wl_whore['earnings_check'] < 6500:
				$wl_whore['performance'] = 'an slightly above average'
			elseif wl_whore['earnings_check'] < 9000:
				$wl_whore['performance'] = 'a strong'
			else
				$wl_whore['performance'] = 'a very strong'
			end

			'<br>This week you have earned <<wl_whore[''earnings_check_unmod'']>> <b>₽</b> per shift. This is <<$wl_whore[''performance'']>> performance.'
		end

		if wl_debt['amount'] > 0:
			'<br>Currently you only get <<wl_whore[''share_player''] - 20>>% of your earnings. Volya keeps 20% to pay down your debts.'
		else
			'<br>Currently you get <<wl_whore[''share_player'']>>% of your earnings.'
		end

		'<br>Volya will pick you up and drop you off in <<$wl_loc[2]>>. (<a href="exec: gt ''mod_wlife_phone'', ''loc_change''">Change it</a>)'

		if wl_whore['shifts_message'] = 0 and wl_whore['shifts_message_timer'] ! daystart and hour < 16 and week ! 7 and wl_georgiy['timer_week'] ! week:
			if wl_whore['shifts_done'] >= wl_whore['shifts_week']:
				if wl_stats['acceptance'] < 10:
					'<br>You haven''t accepted your life as a whore and are very hesitant to work an additional shift.'
					gs 'willpower', 'prostitution', 'self', 'hard'
					will_cost = will_cost * 2
				elseif wl_stats['acceptance'] < 20:
					'<br>You haven''t accepted your life as a whore and are hesitant to work an additional shift.'
					gs 'willpower', 'prostitution', 'self', 'hard'
				elseif wl_stats['acceptance'] < 40:
					'<br>You haven''t accepted your life as a whore, but you are slowly getting used to it. It''s still difficult to motivate you to work an additional shift.'
					gs 'willpower', 'prostitution', 'self'
				else
					gs 'willpower', 'prostitution', 'self', 'easy'
				end
				if wl_cheat['will_cost'] = 1: will_cost = 0
				if will_cost <= pcs_willpwr:
					act 'Text Volya that you will work today (<<will_cost>> Willpower)':
						minut += 1
						wl_whore['shifts_message'] = 1
						wl_whore['shifts_message_timer'] = daystart
						gs 'willpower', 'pay', 'self'
						gt 'mod_wlife_phone', 'start'
					end
				else
					act 'Text Volya that you will work today (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
				end
			elseif wl_whore['shifts_done'] < wl_whore['shifts_week']:
				act 'Text Volya that you will work today':
					minut += 1
					wl_whore['shifts_message'] = 1
					wl_whore['shifts_message_timer'] = daystart
					gt 'mod_wlife_phone', 'start'
				end
			end
		elseif wl_whore['shifts_message'] = 1 and wl_whore['shifts_message_timer'] = daystart and hour < 17:
			act 'Text Volya that you can''t make it':
				minut += 1
				wl_whore['shifts_message'] = 0
				gt 'mod_wlife_phone', 'start'
			end
		elseif $loc = 'mod_wlife_highway':
			act 'Text Volya to pick you up': wl_temp = 1 & gt 'mod_wlife_volya', 'shift_premature_end'
		end
	end

	if wl_iosif['timer'] = 1: '<br>You have to visit Iosif at the warehouse at 23:00.'

	if wl_georgiy['timer_week'] < week and wl_demand['party'] = 1:
		'<br>You have to go to the party at Vadim Bely''s house next saturday.'
	elseif wl_georgiy['timer_week'] = week and wl_demand['party'] = 1:
		'<br><font color="red">You can''t work today. You have to go to Volya''s apartment today (19:00) to get ready for the party at Vadim Bely''s house</font>.'
	end

	if wl_status['main'] > 4 and PCloStyle = 4 and ShoHeels > 3 and (wl_whore['pirsA'] = 0 or (wl_whore['pirsA'] > 0 and pirsA < 10000)):
		'<br>You are ready to work. Outfit'+iif(wl_whore['pirsA'] > 0, ', heels and tongue piercing', ' and heels')+' are an appropriate choice to work as a street whore.'
	elseif wl_status['main'] > 4:
		iif(PCloStyle = 4, '<br>Your outfit is an appropriate choice for a prostitute.', '<br>You need to change your outfit to work as a prostitute.')+iif(pirsA < 10000, '', iif(wl_whore['pirsA'] > 0, ' You''ll have to wear your tongue piercing to be able to work.', ''))
		iif(ShoHeels > 3, 'Your shoes are a good choice', 'You should think about your choice of shoes')+' if you want to go to work today.'
	end

	if $wl_names['street'] ! '': act 'Check your personal information': gt 'mod_wlife_phone', 'character'

	if wl_status['main'] > 4: act 'Check your information about the Bely''s operation': gt 'mod_wlife_phone', 'investigation'

	if wl_pictures > 0:
		act 'Look at '+iif(wl_pictures['count'] > 1, 'your degrading pictures', 'the degrading picture')+'':
			*clr & cla
			if wl_pictures['start'] = 1:
				*nl & '<center><b>The fateful day</b></center>'
				'<center><img src="mod/wlife/images/sex/story/start/start.jpg"></center>'
			end

			if wl_pictures['iosif_1'] = 1:
				*nl & '<center><b>Iosif marking his territory'+iif(wl_pictures['iosif_2'] = 1 or wl_pictures['iosif_3'] = 2, ' (Part 1)', '')+'</b></center>'
				'<center><img src="mod/wlife/images/sex/iosif/warehouse/creampie.jpg"></center>'
			end

			if wl_pictures['iosif_2'] = 1:
				*nl & '<center><b>Iosif marking his territory (Part 2)</b></center>'
				'<center><img src="mod/wlife/images/sex/iosif/warehouse/piss_whore.jpg"></center>'
			end

			if wl_pictures['iosif_3'] = 2:
				*nl & '<center><b>Iosif marking his territory (Part '+iif(wl_pictures['iosif_2'] = 1, '3', '2')+')</b></center>'
				'<center><img src="mod/wlife/images/prostitution/party/iosif/iosif_facial.jpg"></center><br>'
			end

			act 'Go back': gt 'mod_wlife_phone', 'start'
		end
	end

	if wl_okoro['status'] = 3:
		act 'Reply to Henri Okoro': gt 'mod_wlife_phone', 'okoro_reply'
	elseif wl_okoro['status'] > 3 and wl_okoro['status'] < 9 and wl_okoro['timer'] ! daystart and week = 7:
		act 'Call Henri Okoro':
			if ($loc ! 'bedr' and $loc ! 'bedr2x' and $loc ! 'bedrPar' and $loc ! 'pav_shared_apt' and $loc ! 'mod_BroMod_bedrPar' and $loc ! 'mod_wlife_hotelroom') or ((locat['Anya_inroom'] = 1 or locat['Anya'] = 4 or locat['Anya'] = 15) and ($loc = 'bedrPar' or $loc = 'mod_BroMod_bedrPar')):
				*clr & cla
				'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
				'Henri said to call him on a Sunday and you should probably be in your bedroom'+iif(locat['Anya_inroom'] = 1 or locat['Anya'] = 4 or locat['Anya'] = 15 and $loc = 'bedrPar', ', when your sister isn''t here.', '.')

				act 'Go back': gt 'mod_wlife_phone', 'start'
			else
				gt 'mod_wlife_okoro', 'call'
			end
		end
	end

	if wl_okoro['gang'] = 1:
		act 'Text Henri Okoro about meeting his guys':
			*clr & cla
			'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
			'You think about it for a moment before typing your response to his offer. You write him that you...'

			act '... won''t meet his guys': wl_okoro['gang'] = -1 & gt 'mod_wlife_phone', 'start'
			act '... will meet his guys':
				cla & *nl
				wl_okoro['gang'] = 2
				'<b>Developer Note: This is the end of the current Okoro content.</b>'

				act 'Continue': gt 'mod_wlife_phone', 'start'
			end
		end
	end

	if wl_alexei['status'] = 1 and wl_alexei['party'] = 0:
		act 'Call Alexei to hang out with him': gt 'mod_wlife_alexei', 'call'
	elseif rex['pussy'] = 1 and wl_alexei['status'] = 6 and wl_thought['best_alexei'] = 2:
		act 'Call Alexei again': gt 'mod_wlife_alexei', 'call_2'
	end

	if wl_homeless['video_count'] > 0:
		act 'Visit youporn.com to see your video':
			*clr & cla
			'<center><img <<$set_imgh>> src="mod/wlife/images/prostitution/homeless/set_1/youporn.jpg"></center>'
			if wl_homeless['video_timer'] ! daystart:
				wl_temp = daystart - wl_homeless['video_timer']
				wl_homeless['video_count'] += rand(500,1500) * wl_temp
				wl_homeless['video_timer'] = daystart
				killvar 'wl_temp'
			end
			gs 'arousal', 'porn', 2
			gs 'stat'
			'You look at the number of views. It '+iif(wl_homeless['video_count'] = 70000, 'still is', 'has gone up to')+' <<wl_homeless[''video_count'']>>.'

			act 'Close your browser': gs 'arousal', 'end' & gt 'mod_wlife_phone', 'start'

			act 'Click play':
				*clr & cla
				'<center><video autoplay loop src="mod/wlife/images/prostitution/homeless/set_1/pussy_1.mp4"></video></center>'
				wl_homeless['video_count'] += 1
				gs 'arousal', 'porn', 6
				gs 'arousal', 'end'
				gs 'stat'
				'You watch yourself getting fucked.'

				act 'Close your browser': gs 'arousal', 'end' & gt 'mod_wlife_phone', 'start'
			end
		end
	end

	act 'Cheatmenu/FAQ': gt 'mod_wlife_cheatmenu', 'start'
end

if $ARGS[0] = 'loc_change':
	*clr & cla
	minut += 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Text him the new address where he should pick you up and drop you off after work.'

	act 'Don''t change the address': gt 'mod_wlife_phone', 'start'

	act 'Pavlovsk':
		$wl_loc[0] = 'pav_complex'
		$wl_loc[1] = 'start'
		$wl_loc[2] = 'Pavlovsk'
		gt 'mod_wlife_phone', 'start'
	end

	act 'Pavlovsk''s Hotel':
		$wl_loc[0] = 'pav_market'
		$wl_loc[1] = ''
		$wl_loc[2] = 'Pavlovsk''s Hotel'
		gt 'mod_wlife_phone', 'start'
	end

	act 'St. Petersburg':
		$wl_loc[0] = 'city_residential'
		$wl_loc[1] = ''
		$wl_loc[2] = 'St. Petersburg'
		gt 'mod_wlife_phone', 'start'
	end

	act 'Pushkin/Old Town':
		$wl_loc[0] = 'liam'
		$wl_loc[1] = ''
		$wl_loc[2] = 'Pushkin/Old Town'
		gt 'mod_wlife_phone', 'start'
	end

	act 'Gadukino':
		$wl_loc[0] = 'gadukino'
		$wl_loc[1] = ''
		$wl_loc[2] = 'Gadukino'
		gt 'mod_wlife_phone', 'start'
	end
end

if $ARGS[0] = 'character':
	*clr & cla
	'<center><img src="<<func(''$face_image'')>>"></center>'

	'<b>Names:</b>'
	if $wl_names['street'] ! '': 'The name you tell your clients is: <<$wl_names[''street'']>> <a href="exec: gt ''mod_wlife_phone'', ''change_name_street''">(Change it)</a>'
	if $wl_names['okoro'] ! '': 'You gave the Okoro brothers your '+iif($wl_names['okoro'] = $pcs_firstname, 'real', 'fake')+' name.'
	if $wl_names['first'] ! '': 'The first name in your fake passport is: <<$wl_names[''first'']>> <a href="exec: gt ''mod_wlife_phone'', ''change_firstname_passport''">(Change it)</a>'
	if $wl_names['last'] ! '': 'The last name in your fake passport is: <<$wl_names[''last'']>> <a href="exec: gt ''mod_wlife_phone'', ''change_lastname_passport''">(Change it)</a>'

	*nl

	if (wl_bestiality['cuni_count'] + wl_bestiality['bj_count']) > 0:
		'<b>Bestiality statistics:</b>'
		'- Cunnilingus: <<wl_bestiality[''cuni_count'']>>x'
		'- Blowjob: <<wl_bestiality[''bj_count'']>>x'
		'- Vaginal: <<wl_bestiality[''pussy_count'']>>x'
		*nl
	end

	'<b>Fetishes</b>'
	'Do you like the following fetishes?'
	if $wl_fetish['BDSM'] ! '': '- Masochism: '+iif($wl_fetish['BDSM'] = 'yes', '<b>Yes</b>', '<a href="exec: $wl_fetish[''BDSM''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Yes</a>')+'|'+iif($wl_fetish['BDSM'] = 'no', '<b>No</b>', '<a href="exec: $wl_fetish[''BDSM''] = ''no'' & gt ''mod_wlife_phone'', ''character''">No</a>')
	if $wl_fetish['humiliation'] ! '': '- Being humiliated: '+iif($wl_fetish['humiliation'] = 'yes', '<b>Yes</b>', '<a href="exec: $wl_fetish[''humiliation''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Yes</a>')+'|'+iif($wl_fetish['humiliation'] = 'no', '<b>No</b>', '<a href="exec: $wl_fetish[''humiliation''] = ''no'' & gt ''mod_wlife_phone'', ''character''">No</a>')
	if $wl_fetish['pissing'] ! '' and wl_thought['pissing'] = 1: '- Pissing: '+iif($wl_fetish['pissing'] = 'yes', '<b>Yes</b>', '<a href="exec: $wl_fetish[''pissing''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Yes</a>')+'|'+iif($wl_fetish['pissing'] = 'no', '<b>No</b>', '<a href="exec: $wl_fetish[''pissing''] = ''no'' & gt ''mod_wlife_phone'', ''character''">No</a>')+'|'+iif($wl_fetish['pissing'] = 'blocked', '<b>Blocked</b>', '<a href="exec: $wl_fetish[''pissing''] = ''blocked'' & gt ''mod_wlife_phone'', ''character''">Blocked</a>')
	if $wl_fetish['pissed_on'] ! '': '- Getting pissed on: '+iif($wl_fetish['pissed_on'] = 'yes', '<b>Yes</b>', '<a href="exec: $wl_fetish[''pissed_on''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Yes</a>')+'|'+iif($wl_fetish['pissed_on'] = 'no', '<b>No</b>', '<a href="exec: $wl_fetish[''pissed_on''] = ''no'' & gt ''mod_wlife_phone'', ''character''">No</a>')+'|'+iif($wl_fetish['pissed_on'] = 'blocked', '<b>Blocked</b>', '<a href="exec: $wl_fetish[''pissed_on''] = ''blocked'' & gt ''mod_wlife_phone'', ''character''">Blocked</a>')
	if $wl_fetish['piss_drinking'] ! '': '- Drinking piss: '+iif($wl_fetish['piss_drinking'] = 'yes', '<b>Yes</b>', '<a href="exec: $wl_fetish[''piss_drinking''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Yes</a>')+'|'+iif($wl_fetish['piss_drinking'] = 'no', '<b>No</b>', '<a href="exec: $wl_fetish[''piss_drinking''] = ''no'' & gt ''mod_wlife_phone'', ''character''">No</a>')+'|'+iif($wl_fetish['piss_drinking'] = 'blocked', '<b>Blocked</b>', '<a href="exec: $wl_fetish[''piss_drinking''] = ''blocked'' & gt ''mod_wlife_phone'', ''character''">Blocked</a>')
	if $wl_fetish['piss_pussy'] ! '': '- Have someone piss inside your pussy: '+iif($wl_fetish['piss_pussy'] = 'yes', '<b>Yes</b>', '<a href="exec: $wl_fetish[''piss_pussy''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Yes</a>')+'|'+iif($wl_fetish['piss_pussy'] = 'no', '<b>No</b>', '<a href="exec: $wl_fetish[''piss_pussy''] = ''no'' & gt ''mod_wlife_phone'', ''character''">No</a>')+'|'+iif($wl_fetish['piss_pussy'] = 'blocked', '<b>Blocked</b>', '<a href="exec: $wl_fetish[''piss_pussy''] = ''blocked'' & gt ''mod_wlife_phone'', ''character''">Blocked</a>')
	if $wl_fetish['rimjob'] ! '' and $wl_fetish['rimjob'] ! 'undecided': '- Giving rimjobs: '+iif($wl_fetish['rimjob'] = 'yes', '<b>Yes</b>', '<a href="exec: $wl_fetish[''rimjob''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Yes</a>')+'|'+iif($wl_fetish['rimjob'] = 'no', '<b>No</b>', '<a href="exec: $wl_fetish[''rimjob''] = ''no'' & gt ''mod_wlife_phone'', ''character''">No</a>')+'|'+iif($wl_fetish['rimjob'] = 'blocked', '<b>Blocked</b>', '<a href="exec: $wl_fetish[''rimjob''] = ''blocked'' & gt ''mod_wlife_phone'', ''character''">Blocked</a>')
	if $wl_fetish['atm'] ! '': '- Ass to mouth: '+iif($wl_fetish['atm'] = 'yes', '<b>Yes</b>', '<a href="exec: $wl_fetish[''atm''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Yes</a>')+'|'+iif($wl_fetish['atm'] = 'no', '<b>No</b>', '<a href="exec: $wl_fetish[''atm''] = ''no'' & gt ''mod_wlife_phone'', ''character''">No</a>')+'|'+iif($wl_fetish['atm'] = 'blocked', '<b>Blocked</b>', '<a href="exec: $wl_fetish[''atm''] = ''blocked'' & gt ''mod_wlife_phone'', ''character''">Blocked</a>')
	if $wl_fetish['bestiality'] ! '': '- Bestiality: '+iif($wl_fetish['bestiality'] = 'active', '<b>Active</b>', '<a href="exec: $wl_fetish[''active''] = ''yes'' & gt ''mod_wlife_phone'', ''character''">Active</a>')+'|'+iif($wl_fetish['bestiality'] = 'blocked', '<b>Blocked</b>', '<a href="exec: $wl_fetish[''bestiality''] = ''blocked'' & gt ''mod_wlife_phone'', ''character''">Blocked</a>')

	if $wl_brand['type'] ! '' or wl_whore['pirsA'] > 0:
		*nl
		'<b>Tattoos and Piercings:</b>'
		if $wl_brand['type'] ! '': 'You have been branded as a whore with a <a href="exec: gt ''mod_wlife_phone'', ''tattoo'', ''brand''"><<$wl_brand[''type'']>> tattoo</a>.'
		if $wl_brand['text_pubic'] ! '': 'Iosif forced you to get a <a href="exec: gt ''mod_wlife_phone'', ''tattoo'', ''iosif''">pubic tattoo</a>.'
		if wl_whore['pirsA'] > 0: 'The Bely''s forced you to get a <a href="exec: gt ''mod_wlife_phone'', ''tongue_piercing''">tongue piercing</a>.'
		if wl_whore['pirsF'] > 0: 'Irina forced you to get a <a href="exec: gt ''mod_wlife_phone'', ''nipple_piercing''">nipple piercing</a>.'
		*nl
	end

	*nl

	act 'Go back': gt 'mod_wlife_phone', 'start'
end

if $ARGS[0] = 'investigation':
	*clr & cla
	minut += 1
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'

	if wl_status > 4:
		'<b>Properties:</b>'
		'- They own a warehouse in Pavlovsk''s industrial area'
		if wl_status['hotel'] > 0: '- The hotel near the train station is owned by the Belys'
		if wl_irina['status'] > 0: '- Irina Bely owns a huge estate outside of St. Petersburg'
		if wl_investigation['okoro_2'] > 0: '- They own a house in the suburbs of St. Petersburg. The Okoro Brothers rent it regularly.'
		*nl
	end

	if wl_medical['status'] = 2:
		'<b>Doctor Mikhailov:</b>'
		'- As far as you know all whores have to check-in with Doctor Mikhailov at the clinic in Pavlovsk'
		'- Doctor Mikhailov works for the Belys and maybe has files on all girls working for the Belys'
		*nl
	end

	if wl_investigation['shura'] > 0:
		'<b>Shura Azarov:</b>'
		'- He''s the one in charge or one of the higher ups of a drug dealing operation'
		if wl_drugs['status'] = 2: '- Sacha, an ex-classmate of yours, is selling weed in the park for Shura'
		if wl_shura['talk_hard_drugs'] = 1 or wl_sacha['cocaine_talk'] > 0: '- The Belys sell hard drugs like heroin and cocaine'
		if wl_shura['ignore_counter'] > 6: '- The Belys store at least some of the drugs at the warehouse'
		*nl
	end

	if (wl_investigation['okoro'] + wl_investigation['okoro_2']) > 0:
		'<b>Okoro Brothers:</b>'
		if wl_investigation['okoro'] > 0: '- The Okoro brothers shipped 1,000 kilos of an unknown substance (drugs???) through the St. Petersburg port'
		if wl_okoro['gang'] ! 0: '- They have expanded their operations in Russia and they now have some members of their organization staying here permanently.'
		if (wl_investigation['okoro_2'] > 1 and wl_investigation['okoro'] = 1) or wl_investigation['okoro_2'] = 4:
			'- Léon and Henri Okoro bought a warehouse somewhere in St. Petersburg. You suspect that it''s somewhere in the industrial area'
		end
		*nl
	end

	if wl_investigation['maxim'] > 0:
		'<b>Maxim:</b>'
		if wl_investigation['maxim'] = 1:
			'- You could see excel-sheets on Maxim''s laptop. Maybe he works as some kind of numbers guy for the Bely''s'
		elseif wl_investigation['maxim'] > 1:
			'- The Belys have legitimate businesses they use to launder their illegal incomes'
			'- Maxim is an accountant and manages the financial side of the Bely''s legitimate businesses'
			if wl_investigation['maxim'] = 3:
				'- You know the password for Maxim''s laptop. It''s Arthur his dog''s name.'
			elseif wl_investigation['maxim'] = 4:
				'- You have copied Maxim''s files onto my usb-drive. You need to '+iif(komp = 0, 'buy a laptop to check the files.', 'check the files on your laptop')
			elseif wl_investigation['maxim'] = 5:
				'- You have all financial information about the legal and illegal parts of the Bely''s business'
			end
		end
		*nl
	end

	if arrsize('wl_crime') > 0 or wl_bad['whip'] > 0:
		'<b>Violent Crimes:</b>'
		if wl_bad['whip'] > 0: '- Georgiy''s and Vadim''s sister Irina Bely tortures girls for them'
		if wl_crime['katharina_murder'] > 0: '- You '+iif(wl_crime['katharina_murder'] = 2, 'killed', 'assaulted')+' a homeless woman'+iif(wl_iosif['katharina'] > 0, ' and Iosif knows about it', '')
		if wl_crime['detective_murder'] > 0: '- You '+iif(wl_crime['detective_murder'] = 1, 'shot', 'strangled')+' the cop that raped you'
		if wl_crime['detective_murder'] = -1: '- You saw Georgiy shoot the cop that raped you'
		*nl
	end

	act 'Go back': gt 'mod_wlife_phone', 'start'
	if wl_investigation['points'] > 0:
		act 'Send the information to the police':
			*clr & cla
			'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
			'Developer Note: For now the information you have collected is enough to get the Belys arrested, since the other investigations aren''t finished yet. Sending the information will block all content, like the cheat. Right now there is also no ''end scene'' or something similar. You can also revert your decision later if you want to. This will not be possible, when I have added more investigations and a proper end.'

			act 'Wait for now': gt 'mod_wlife_phone', 'investigation'
			act 'Send the information':
				wl_status['stored'] = wl_status['main']
				wl_status['main'] = -1
				gt $loc, $loc_arg
			end
		end
	end
end

if $ARGS[0] = 'change_name_street':
	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	$wl_names['street'] = ''
	$wl_names['street'] = input("What name do you want to tell your clients? (Leave blank for <<$pcs_nickname>>)")
	if $wl_names['street'] = '': $wl_names['street'] = $pcs_nickname
	act 'Continue': gt 'mod_wlife_phone', 'character'
end

if $ARGS[0] = 'change_firstname_passport':
	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	$wl_names['first'] = ''
	$wl_names['first'] = input("What is your first name in your fake passport? (Leave blank for Anastasia)")
	if $wl_names['first'] = '': $wl_names['first'] = 'Anastasia'
	if $wl_names['okoro'] ! '' and $wl_names['okoro'] ! $pcs_firstname: $wl_names['okoro'] = $wl_names['first']
	act 'Continue': gt 'mod_wlife_phone', 'character'
end

if $ARGS[0] = 'change_lastname_passport':
	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	$wl_names['last'] = ''
	$wl_names['last'] = input("What is your last name in your fake passport? (Leave blank for Semenova)")
	if $wl_names['last'] = '': $wl_names['last'] = 'Semenova'
	act 'Continue': gt 'mod_wlife_phone', 'character'
end

if $ARGS[0] = 'passport_pay':
	*clr & cla
	minut += 1
	menu_off = 1
	wl_debt['amount'] += 18000
	wl_debt['amount'] += wl_brand['price']
	wl_passport_pay = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. Volya send you a message.'
	*nl
	'<i>Hi <<$pcs_nickname>>, I totally forgot to tell you the good news, when I gave you the passport. It normally costs 30,000 <b>₽</b>, but Georgiy agreed that you don''t have to pay the full amount. I managed to beat down the price to 18,000 <b>₽</b>.</i>'
	*nl
	'18,000 <b>₽</b>? And you also have to pay for getting branded? You read the message again, but the amount didn''t change. You sigh and shake your head. Yeah, that''s really great, you think sarcastically and put your phone away.'

	act 'Continue': gt $loc, $loc_arg
end

if $ARGS[0] = 'tattoo':
	*clr & cla
	if $ARGS[1] = 'brand':
		'<center><img src="<<$wl_brand[''image'']>>"></center>'
		'The tattoo on your <<$wl_brand[''type'']>> is your whore brand.'
	elseif $ARGS[1] = 'iosif':
		'<center><img src="<<$wl_brand[''image_pubic'']>>"></center>'
		'Iosif forced you to get the word ''<<$wl_brand[''text_pubic'']>>'' inked on your pubic area.'
	end

	act 'Continue': gt 'mod_wlife_phone', 'start'
end

if $ARGS[0] = 'tongue_piercing':
	*clr & cla
	'<center><img  height = 334 src="images/pc/body/piercings/a<<wl_whore[''pirsA'']>>.jpg"></center>'
	'The Bely''s forced you to buy this piercing.'

	act 'Continue': gt 'mod_wlife_phone', 'start'
end

if $ARGS[0] = 'nipple_piercing':
	*clr & cla
	'<center><img  height = 480 src="images/pc/body/piercings/a<<wl_whore[''pirsF'']>>.jpg"></center>'
	'Irina forced you to get this piercing.'

	act 'Continue': gt 'mod_wlife_phone', 'start'
end

if $ARGS[0] = 'start_aftermath_picture':
	*clr & cla
	menu_off = 1
	minut += 1
	wl_status['main'] = 3
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. You have received a message from an unknown number.'
	gs 'stat'

	act 'Open it':
		*clr & cla
		minut += 1
		'<center><img <<$set_imgh>> src="mod/wlife/images/sex/story/start/start.jpg"></center>'
		'It''s a picture of you as one of the guys shoots his load directly into your mouth.'
		'Shortly after the picture a second message appears: <i>A little memento of your special day</i>.'
		'You click on the message and ...'
		gs 'stat'

		act 'Delete the picture (Warning: Blocks one scene)':
			cla & *nl
			wl_pictures['start'] = 0
			'You angrily delete the picture. Why would you ever want to remember that day?'

			act 'Put your phone away': gt $loc, $loc_arg
		end

		act 'Save the picture':
			cla & *nl
			inhib_exp += 2
			wl_pictures['start'] = 1
			wl_pictures['count'] += 1
			'You save the picture. Maybe you save it as evidence, maybe because you really want to, but whatever your reasons are, you keep it on your phone.'

			act 'Put your phone away': gt $loc, $loc_arg
		end
	end
end

if $ARGS[0] = 'start_aftermath_volya':
	*clr & cla
	menu_off = 1
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. You are getting a call from an unknown number.'

	act 'Answer it': gt 'mod_wlife_volya', 'introduction_start'
end

if $ARGS[0] = 'volya_missed':
	*clr & cla
	menu_off = 1
	wl_whore['shifts_message'] = 0
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. Volya send you a message.'
	*nl
	if wl_shift_missed = 0:
		wl_shift_missed = 1
		'<i>Hi <<$pcs_nickname>>. If you aren''t going to make it, send me a message next time.</i>'
	else
		wl_stats['loyalty'] -= rand(0,1)
		'<i>Come on <<$pcs_nickname>>, next time tell me, when you aren''t going to make it. Don''t stand me up like this.</i>'
	end

	act 'Put your phone away': gt $loc, $loc_arg
end

if $ARGS[0] = 'iosif_work_first':
	*clr & cla
	minut += 1
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. You are getting a call from an unknown number.'

	act 'Answer it': gt 'mod_wlife_iosif', 'first_call'
end

if $ARGS[0] = 'iosif_work_regular':
	*clr & cla
	minut += 1
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. You are getting a call from Iosif.'

	gs 'willpower', 'prostitution', 'resist', 'easy'
	if will_cost <= pcs_willpwr:
		act 'Don''t answer it (<<will_cost>> Willpower)':
			wl_stats['loyalty'] -= rand(0,1)
			wl_iosif['call_avoid'] += 1
			wl_iosif['timer_whore'] = daystart + rand(0,3)
			gs 'willpower', 'pay', 'resist'
			gt $loc, $loc_arg
		end
	else
		act 'Don''t answer it (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end

	act 'Answer it': wl_iosif['call_avoid'] = 0 & gt 'mod_wlife_iosif', 'regular_call'
end

if $ARGS[0] = 'iosif_party_pic':
	*clr & cla
	minut += 1
	menu_off = 1
	wl_pictures['count'] += 1
	wl_pictures['iosif_3'] = 2
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. Iosif has send you a picture.'

	act 'Open it':
		*clr & cla
		minut += 2
		gs 'stat'
		'<center><img src="mod/wlife/images/prostitution/party/iosif/iosif_facial.jpg"></center><br>'
		'A small message accompanies the picture: <i>Slut look what I found. Isn''t it a great picture? I sifted through all the footage I could get my hands on. I hope you like it.</i>'

		act 'Continue': gt $loc, $loc_arg
	end
end

if $ARGS[0] = 'iosif_missed':
	*clr & cla
	menu_off = 1
	wl_iosif['call_missed'] += 1
	wl_stats['loyalty'] -= rand(2,6) * wl_iosif['call_missed']
	wl_iosif['timer_whore'] = daystart + rand(2,4)
	wl_iosif['timer'] = 0
	minut += 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. Iosif send you a message.'
	*nl
	if wl_iosif['call_missed'] > 1 and wl_bad['status_punishment'] = 0:
		wl_bad['status_punishment'] = 1
		wl_bad['iosif'] = 1
		wl_iosif['call_missed'] = 0
		'<i>This was the last time that you ignored me. I called Georgiy and told him what a bitch you were. Good luck on Sunday.</i>'
	elseif rand(0,1) = 0:
		'<i>Who do you think you are? You fucking cunt. Next time, when I tell you to get your ass to the warehouse, you''ll get your fucking ass to the warehouse!</i>'
	else
		'<i>I told you to come to the warehouse you stupid bitch. Move your ass next time or you''ll fucking regret it.</i>'
	end

	act 'Put your phone away': gt $loc, $loc_arg
end

if $ARGS[0] = 'iosif_avoid':
	*clr & cla
	menu_off = 1
	wl_iosif['call_missed'] += 1
	wl_stats['loyalty'] -= rand(2,6) * wl_iosif['call_missed']
	wl_iosif['timer_whore'] = daystart + rand(2,4)
	wl_iosif['call_avoid'] = 0
	minut += 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. Iosif send you a message.'
	*nl
	if wl_iosif['call_missed'] > 1 and wl_bad['status_punishment'] = 0:
		wl_bad['status_punishment'] = 1
		wl_bad['iosif'] = 1
		wl_iosif['call_missed'] = 0
		'<i>This was the last time that you ignored me. I called Georgiy and told him what a bitch you were. Good luck on Sunday.</i>'
	elseif rand(0,1) = 0:
		'<i>Fucking lazy bitch, answer your fucking phone, when I call you.</i>'
	else
		'<i>Pick up, when I fucking call you!</i>'
	end

	act 'Put your phone away': gt $loc, $loc_arg
end

if $ARGS[0] = 'volya_party_warning':
	*clr & cla
	minut += 1
	menu_off = 1
	wl_party_warning_day = daystart
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. Volya send you a message.'
	*nl
	'<i>Hi <<$pcs_nickname>>, remember to be at my apartment at 19:00 to go to Vadim''s party. This is important!</i>'

	act 'Put your phone away': gt $loc, $loc_arg
end

if $ARGS[0] = 'okoro':
	*clr & cla
	minut += 1
	menu_off = 1
	wl_okoro['status'] = 3
	wl_okoro['timer'] = daystart
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. An unknown number send you a message.'
	*nl
	'<i>Hello <<$wl_names[''okor'']>>. I hope you don''t mind, but I asked Vadim for your number. If you ever want to chat, send me a message. I typically have some free time on Sundays.
	- Henri Okoro</i>'

	act 'Put your phone away': gt $loc, $loc_arg
	act 'Reply': gt 'mod_wlife_phone', 'okoro_reply'
end

if $ARGS[0] = 'okoro_reply':
	*clr & cla
	menu_off = 1
	minut += rand(3,7)
	wl_okoro['status'] = 4
	wl_okoro['timer'] = daystart
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'You type a quick message to Henri that you would like to chat with him someday. It only takes a few minutes for Henri to reply: <i>There is a video chat app I always wanted to give a try if you''re up for it. Talking would be fine, but I really want to see you.</i>'

	act 'Install the app':
		cla & *nl
		minut += 1
		gs 'stat'
		'You quickly download the app and install it. You can now call Henri on a Sunday.'

		act 'Put your phone away': gt $loc, $loc_arg
	end
end

if $ARGS[0] = 'leon_reminder':
	*clr & cla
	minut += 1
	menu_off = 1
	wl_okoro['timer'] = daystart
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. Henri Okoro send you a message.'
	*nl
	'<i>Hello <<$wl_names[''okoro'']>>. Léon is looking forward to tonight and he wanted me to tell you, that he''s in room 309 and should be back in his room after ten.</i>'
	*nl
	'You wonder for a second why Henri and not Léon is texting you, but then you remember that his brother doesn''t speak Russian, not even English. Why would Henri send his brother to Georgiy instead of going himself, when he doesn''t speak either of those languages? Maybe Georgiy speaks French? But you somehow doubt it. And then you realize that you also won''t be able to talk to him. Not that you expect a lot of talking, but still it could make it more complicated.'

	act 'Put your phone away': gt $loc, $loc_arg
end

if $ARGS[0] = 'homeless_aftermath':
	*clr & cla
	minut += 1
	menu_off = 1
	wl_homeless['video_count'] = 70000
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/player/phone_holding.jpg"></center>'
	'Your phone vibrates in your '+iif(bag = 1, 'purse', 'pocket')+'. The unknown person, who send you the picture of getting blowbanged in the warehouse, send you another message.'
	*nl
	'<i>Nice work <<$pcs_nickname>>, you really fucked him good. See for yourself, I''m not the only one saying that: <a href="exec: minut += 2 & gt ''mod_wlife_phone'', ''homeless_aftermath_link''">https://www.youporn.com/watch/15288211/young-russian-whore-makes-a-bum-s-day</a>'
	'See you next Sunday, Georgiy</i>'

	act 'Click on the link': gt 'mod_wlife_phone', 'homeless_aftermath_link'
end

if $ARGS[0] = 'homeless_aftermath_link':
	*clr & cla
	'<center><img <<$set_imgh>> src="mod/wlife/images/prostitution/homeless/set_1/youporn.jpg"></center>'
	wl_homeless['video_timer'] = daystart
	gs 'arousal', 'porn', 2
	gs 'stat'
	'With trembling hands you click on the link praying that it isn''t what it obviously is.'
	'Oh... my... god... they really made a video. It''s short, only two minutes, but it isn''t a problem for you to recognize yourself even if your face isn''t visible. There is no doubt about it.'
	*nl
	'Why would they do that? Isn''t it enough for you to get pounded by a hobo? Why do they need to publicly humiliate you? But while you''re pondering those questions the only possible answer is already forming in your mind. It''s not about humiliating you, it''s blackmail material. You bet your life on it, that this isn''t all there is. They probably took a longer video where your face is visible in some part of it.'

	act 'Watch it again': wl_temp = 1 & gt 'mod_wlife_phone', 'homeless_aftermath_watch'
	act 'Read the comments': wl_temp = 1 & gt 'mod_wlife_phone', 'homeless_aftermath_comments'
end

if $ARGS[0] = 'homeless_aftermath_watch':
	*clr & cla
	'<center><video autoplay loop src="mod/wlife/images/prostitution/homeless/set_1/pussy_1.mp4"></video></center>'
	gs 'arousal', 'porn', 6
	gs 'stat'
	'Seeing it again comes with a bunch of different emotions. It''s humiliating, frustrating, enraging and so much more. Your mind can''t decide what to focus on and so you watch it again and again and again...'
	*nl
	'Three things stand out from the confusing mix of emotions: disgust, arousal and pride.'
	'You are disgusted by it, when you remember the smell, how his filthy hands felt on your body and his dick inside you. But a hint of arousal also flares up inside you, when you remember how degrading the whole experience was and a little bit of pride manifests itself, when you think about how you gave him a happy memory to hold on to in what must be a miserable existence.'
	*nl
	'In the end one of the three dominates your reaction to the video...'

	act 'Disgust':
		cla & *nl
		wl_homeless['bad'] -= 1
		wl_homeless['good'] -= 1
		'That whole experience was one of the worst days of your life and you hope to never have to repeat it.'

		gs 'mod_wlife_phone', 'homeless_aftermath_actions', 'watch'
	end

	act 'Pride':
		cla & *nl
		wl_homeless['good'] += 1
		pcs_mood = 100
		gs 'stat'
		'You really did it and stepped up. In the end you conquered your own fear and revulsion. Yeah, it was disgusting, but you''re proud of yourself to be able to get through it and that in the process you actually did something nice for somebody.'

		gs 'mod_wlife_phone', 'homeless_aftermath_actions', 'watch'
	end

	act 'Arousal':
		cla & *nl
		wl_homeless['bad'] += 1
		if pcs_horny < 60: pcs_horny = 60
		gs 'stat'
		'At some point you have to deal with those weird flashes of arousal that spark inside you whenever you''re being degraded. You should be ashamed of yourself, the conscious part of your brain tells you, but your perverted subconscious relishes those memories like getting fucked by a homeless men'+iif($wl_fetish['pissed_on'] = 'yes', ' or being pissed on by Iosif.', '.')

		gs 'mod_wlife_phone', 'homeless_aftermath_actions', 'watch'
	end
end

if $ARGS[0] = 'homeless_aftermath_comments':
	*clr & cla
	minut += 3
	wl_adrian['timer'] = daystart + rand(2,5)
	gs 'stat'
	'<center><img <<$set_imgh>> src="mod/wlife/images/prostitution/homeless/set_1/youporn.jpg"></center>'
	'It already has over 70,000 views... "70,000?" you whisper and shake your head in disbelieve. You scroll down to take a look at the comments'
	*nl
	'<i>1. That girl knows her place.</i>'
	iif($wl_homeless['condom'] = 'yes' or $wl_homeless['condom'] = 'broke', '<i>2. Such a vile whore doesn''t deserve a condom, she should have let him fuck her raw.</i>', '<i>2. She isn''t even using a condom. Such a piece of trash. Probably is riddled with diseases.</i>')
	'<i>3. Doing her good deed for the day...</i>'
	'<i>4. Where is the rest??? I want to see more of her!!</i>'
	'<i>5. Only thinking about it makes me cum... again.</i>'
	iif($wl_homeless['condom'] = 'yes' or $wl_homeless['condom'] = 'broke', '<i>6. I hope the condom broke that bitch doesn''t deserve it any better.</i>', '<i>6. I hope he came inside her. That bitch deserves a bum-baby.</i>')
	'<i>7. Shut up you haters. That bitch is hot. Girls who fuck everything that moves are the best.</i>'
	'<i>8. Probably the best day of his life.'
	'<i>9. I bet she''s hot as fuck, just look at her legs... somebody knows who she is????</i>'
	'<i>10. Damn I wish there was more...</i>'
	'<i>11. He''s the happiest bum in the whole world.</i>'
	*nl
	'After reading the first comments, you liked...'

	act 'None of them':
		cla & *nl
		wl_stats['acceptance'] -= 1
		wl_homeless['bad'] -= 1
		wl_homeless['good'] -= 1
		'Why would you like any of them? Those men all are fucked up perverts and can go to hell.'

		gs 'mod_wlife_phone', 'homeless_aftermath_actions', 'comments'
	end

	act '4, 5, 7, 9 and 10':
		cla & *nl
		wl_stats['acceptance'] += 2
		'You know that you shouldn''t care what random men on the internet think about you, but you feel validated by their comments about wanting to see more and masturbating to you.'

		gs 'mod_wlife_phone', 'homeless_aftermath_actions', 'comments'
	end

	act '3, 8 and 11':
		cla & *nl
		wl_homeless['good'] += 1
		'It''s not a very healthy reaction, your brain tells you, but that can''t stop your heart from beating a bit faster, when you read those comments. Helping the needy is something everybody should do, it isn''t something bad.'

		gs 'mod_wlife_phone', 'homeless_aftermath_actions', 'comments'
	end

	act '1, 2, 6 and 8':
		cla & *nl
		wl_homeless['bad'] += 1
		if pcs_horny < 60: pcs_horny = 60
		gs 'stat'
		'You feel ashamed, but can''t lie to yourself, when your eyes keep going back to the degrading comments, that you''re nothing more than trash. They trigger something inside you that lay dormant until you have been exposed to more and more degrading situation like getting fucked by strangers in their cars'+iif(wl_vadim['rough'] = 2, ' or begging Vadim to fuck you in the attic.', '')

		gs 'mod_wlife_phone', 'homeless_aftermath_actions', 'comments'
	end
end

if $ARGS[0] = 'homeless_aftermath_actions':
	if $ARGS[1] = 'watch':
		if wl_temp < 2:
			act 'Read the comments': wl_temp = 2 & gt 'mod_wlife_phone', 'homeless_aftermath_comments'
		else
			act 'Put your phone away':
				killvar 'wl_temp'
				gs 'arousal', 'end'
				gt $loc, $loc_arg
			end
		end
	else
		if wl_temp < 2:
			act 'Watch it again': wl_temp = 2 & gt 'mod_wlife_phone', 'homeless_aftermath_watch'
		else
			act 'Put your phone away':
				killvar 'wl_temp'
				gs 'arousal', 'end'
				gt $loc, $loc_arg
			end
		end
	end
end

--- mod_wlife_phone ---------------------------------