glife/locations/pav_park.qsrc

# pav_park
!2021/05/12
CLOSE ALL

if $ARGS[0] = 'start':
	*clr & cla
	$loc = 'pav_park'
	$region = 'pav_park'
	$loc_arg = 'start'
	$location_type = 'public_outdoors'
	$menu_loc = 'pav_park'
	$menu_arg = 'start'
	$locclass = 'city_park'
	menu_off = 0
	gs 'stat'
	gs 'vicky_meynold_schedule'

	if sound = 0:
		if month >=11 and month <= 12 or month >=1 and month <=3:
			if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/zima.mp3',30
			if hour >= 0 and hour <= 7: PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
		else
			if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street_leto.mp3',30
			if hour >= 0 and hour <= 7:PLAY 'sound/street_night.mp3',30
		end
	end

	if month=3 or month=4 or month=5:
		if daystage = 2 or daystage = 3:
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.spring.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. Spring has come, melting the worst of the snow. The trees are sprouting new leaves.'
			'There are puddles on the ground everywhere, all remains from the melted snow. A lot of people in the park are having fun with them, trying to jump over them and mocking those that fail. They''re not particularly deep though, and plenty of others just walk through without giving them a second thought.'
			'The park is not particularly crowded, this time of year. Many people think it''s still too cold to spend much time outdoors.'
			*nl
		else
			prcptn_exp += rand(1,2)
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.spring.night.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. Spring has come, melting the worst of the snow. The trees are sprouting new leaves.'
			'There is no particular reason to visit the park during the night, and as a result it''s largely deserted. In the distance you see one person running through the park, probably using it as a shortcut to go home faster.'
			*nl
		end
	end
	if month=6 or month=7 or month=8:
		if daystage = 2 or daystage = 3:
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/park/skver.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. At this time of year, it''s one of the primary places in town that locals and tourists enjoy spending their spare time in.'
			'It''s always busy: people are resting, walking, playing and dating to their heart''s desires, enjoying the nice surroundings.'
			*nl
		else
			prcptn_exp += rand(1,2)
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.summer.night.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. At this time of year, it''s one of the places where locals and tourists enjoy going in their spare time.'
			'However, there is no particular reason to visit the park during the night, and as a result it''s largely deserted. In the distance you see one person running through the park, probably using it as a shortcut to go home faster.'
			*nl
		end
	end
	if month=9 or month=10 or month=11:
		if daystage = 2 or daystage = 3:
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.autumn.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. Autumn has come, and some of the trees are already shedding their leaves. The leaves that are still on the trees have changed colour, and are a beautiful mix of red and brown.'
			'Everywhere in the park, people are enjoying nature. Some are taking photos of the fallen leaves, kids are playing everywhere, and couples are walking hand-in-hand, simply enjoying each other''s company.'
			*nl
		else
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.autumn.night.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. Autumn has come, and some of the trees are already shedding their leaves.'
			'It gets quite cold at night, and you try to stay active to keep yourself warm. The lone soul you see running across the park is probably trying to get home faster, to warm up with some nice cocoa.'
			*nl
		end
	end
	if month=1 or month=2 or month=12:
		if daystage = 2 or daystage = 3:
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.winter.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. It''s winter, and the park is quite busy with locals and tourists alike.'
			'There''s snow everywhere, and kids from the whole town have gathered here to make snowmen and enjoy snowball fights. Some of the adults are joining them, happy to play like kids again for just a moment.'
			*nl
		else
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/skver.winter.night.jpg"></center>'
			*nl
			'The main square of Pavlovsk Park. It''s winter, and the nights in Pavlovsk are very cold.'
			'As you expected, the park is mostly deserted at this time of day. You occasionally see a wild animal, scrounging for food.'
			*nl
		end
	end

	act 'Walk to the Residential area (0:05)':minut += 5 & gt 'pav_residential'
	act 'Walk to the Commercial area (0:05)':minut += 5 & gt 'pav_commercial'
	act 'Walk to Pushkin (0:10)':minut += 10 & gt 'liam'

	if hour > 8 and hour < 19:'There''s a small <a href="exec:minut += 5 & gt ''gskino''">movie theater</a> in the park. It only has a single screen.'
	'The newly opened cafe <a href="exec:gt''cafe_parco'',''start''">"Del Parco"</a>, with eye-catching facade, lots of tables and a summer terrace. Two paths lead out of the park. One brings you to the <a href="exec:minut += 5 & gt ''pav_commercial''">commercial</a> the other to the <a href="exec:minut += 5 & gt ''pav_residential''">residential</a> area.'
	if ((month = 8 and day > 20) or (month = 9 and day < 16)) and week > 5 and hour > 8 and hour < 20 and AlbinaQW['ParkRally'] = 0:
		'<br>You overhear someone speaking in front of a crowd. The crowd is quite rowdy, with lots of yelling and clapping throughout the <a href="exec: minut += 2 & gt ''pav_park'', ''alb_father_meeting_1''">meeting</a>.'
	elseif ((month = 9 and day > 20) or (month = 10 and day < 16)) and week > 5 and hour > 8 and hour < 20 and AlbinaQW['ParkRally'] = 1 and AlbinaQW['StarletsShutDown'] = 0:
		'Once again a large crowd has gathered in the town center. You can hear Albina''s father holding a public <a href="exec: minut += 2 & gt ''pav_park'', ''alb_father_meeting_2''">meeting</a>.'
	elseif ((month = 10 and day > 20) or (month = 11 and day < 16)) and week > 5 and hour > 8 and hour < 20 and AlbinaQW['ParkRally'] = 2 and AlbinaQW['StarletsShutDown'] = 0 and AlbinaQW['StarletsJoined'] = 0:
		'By this time you''re well aware that it''s Albina''s father that is holding a <a href="exec: minut += 2 & gt ''pav_park'', ''alb_father_meeting_3''">meeting</a>, this time though they have erected a big stage.'
	end

	*nl
	if $clothingworntype = 'nude': pcs_mood -= 15 & 'You notice passers-by in the park pointing at you as you walk, and overhear one older lady telling her friend: "Look at her... it''s that <<$pcs_lastname>> girl. Youth these days, they have no shame at all!"'

	if GvstreBoy = 1:'You see <a href="exec:numnpc = SkverBoy & gt ''Gnpc''"><<$nameBoyfrend[SkverBoy]>></a> walking across the main square of Pavlovsk Park. He doesn''t look like he''s going anywhere in particular, and seems to just be enjoying his walk.'
	!!if kotovLoveQW > 0 and hour >= 18 and hour < 20 and week < 6 or week >= 6 and kotovLoveQW > 0 and hour >= 9 and hour < 20:'You see <a href="exec:minut += 3 & gt ''kotovEv''">Vitek Kotov</a> sitting on a bench in the park, drinking beer by himself. Judging from the empty bottles near the bench, he''s already had a few.'
	if StoryLine = 1 and SchoolAtestat = 0:
		if (sunWeather = 1 and temper > 0) and (hour >= 18 and hour < 20 and week < 6) or (week >= 6 and hour >= 9 and hour < 20):
			'You see your classmates <a href="exec:minut += 3 & gt ''gopskver''">Vitek, Dan and Vasily</a> sitting on a park bench, drinking beer.'
		end
	end

	if week <= 5 and hour >= 16 and hour < 20 and strelaQW = -2 and fedorKozlovQW <= -10 and FedorOutcast = 0:
		'You can see the <a href="exec:gt ''FedorMisc'', ''Outcast Intro''">train tracks</a> from here.'
	elseif week <= 5 and hour >= 16 and hour < 20 and strelaQW = -2 and fedorKozlovQW <= -10 and FedorOutcast = 1:
		'You can see the train tracks where <a href="exec:gt ''FedorMisc'', ''Outcast''">Fedor</a> spends his time.'
	end

	if rexPark = 1 and rexParkDay = daystart and hour >= 16 and hour < 18:
		'You see Rex walking in the park.'
		act 'Go and see Rex':gt 'rex_events', 'skver'
	end

	if week >= 6 and hour >= 8 and hour <= 9 and StoryLine = 1 and socialchg['tVanya_day'] ! daystart: '<a href="exec:gt ''gschool_socialchg1'',''tVanya''">Vanya</a> is out on a light jog and is slowly approaching you.'

	if month > 8 and month < 6 and week < 6 and hour >= 16 and hour <= 20 and storyline = 1 and christinaQW['dompath'] = 0 and christinaQW['subpath'] = 0 and socialchg['tChris_Lina_jog'] ! daystart:
		if rand(1,4) = 1:'You spot <a href="exec:gt ''Zvereva_events'',''Chris_Lina_park''">Christina</a> and Lina jogging around the park.'
	end

	act 'Go for a walk (0:15)':
		menu_off = 1
		if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1', 1

		if StoryLine = 1 and SchoolAtestat = 0 and mey_vika['mey_vika_qw'] > 0 and mey_vika['mey_vika_qw'] < 27 and mey_vika['qw_day'] ! daystart and locat['Vicky'] = 11:
			gs 'mey_vika_events', 'park_meet'
			gs 'stat'
		else
			*clr & cla
			minut += 15
			place = 1
			Frend_num = 0
			if MagikDostup ! 1 and rand (1, 4) <= pcs_magik and (hour <=6 or hour >=19): gt 'MagEncounterFairy'
			gt 'placer'
		end
	end

	!! If you already know about the treeCircle here in PavPark, go ahead and show it.
	if tpKnown['PavlovskPark'] = 1:	gs 'treeCircEntry', 'PavlovskPark'

	gs 'park_walkevents', 'run'

	if hour >= 8 and hour < 22:
		act 'Distribute flyers to earn money (50 <b>₽</b>) (1:00)':
			*clr & cla
			menu_off = 1
			minut += 60
			money += 50
			pcs_mood -= 5
			gs 'stat'
			'<center><h2>Pavlovsk Park</h2></center>'
			'<center><img <<$set_imgh>> src="images/locations/shared/park/job_flyer.jpg"></center>'
			*nl
			'You spend an hour handing out advertising flyers to park visitors. You received 60 <b>₽</b> for your efforts.'

			act 'Continue':gt 'pav_park', 'start'
		end
	end


	if hour >= 8 and hour <= 22 and sunWeather = 1 and temper >= 15 and ml_guitar['carried'] = 1 and ml_performance['performed_minutes'] < ml_performance['max_perform_minutes'] and ml_performance['max_perform_minutes'] >= 15:
		*nl
		'With the weather being pleasant and sunny, the parks is full of people enjoying the weather. You could play some music, practice performing songs and maybe make some money too.'
		ml_buskingtime =  min((ml_performance['max_perform_minutes']-ml_performance['performed_minutes']), 60)

		if pcs_inhib < 30:
			if pcs_inhib < 10:
				$diff = 'hard'
			elseif pcs_inhib < 20:
				$diff = 'medium'
			else
				$diff = 'easy'
			end

			gs 'willpower', 'skill', 'self', $diff
			will_cost = (will_cost * 3) - (pcs_perform)
			if will_cost <= pcs_willpwr:
				act 'Start busking (<<ml_buskingtime>> minutes) (<<will_cost>> Willpower)':
					inhib_exp += rand(1,3)
					gs 'willpower', 'pay', 'self'
					gs 'stat'
					gs 'music_buskingevents', 'busking', 'pav'
					if rand(0,100) > 75 and (pcs_instrmusic + pcs_vokal + pcs_perform) >= 120 and hotcat >= 5:
						gt 'music_gigstarts', 'delparco_start', 'pav_park'
					end
				end
			else
				act 'Start busking (<<ml_buskingtime>> minutes) (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end
		else
			act 'Start busking (<<ml_buskingtime>> minutes)':
				gs 'music_buskingevents', 'busking', 'pav'
				if rand(0,100) > 75 and (pcs_instrmusic + pcs_vokal + pcs_perform) >= 120 and hotcat >= 5:
					gt 'music_gigstarts', 'delparco_start', 'pav_park'
				end
			end
		end
	end

	if month >= 6 and month <=8 and TourGuide = 0 and (work = 0 or cheatWork = 1):
		if hour >= 8 and hour <= 18:
			act 'Apply for the Tour Guide job (0:30)':gt 'tour_guide', 'tourstart'
		end
	elseif month >= 6 and month <=8 and TourGuide = 1:
		if hour >= 8 and hour <= 12:
			act 'Work as Tour Guide (6:00)':gt 'tour_guide', 'tourstart'
		end
	elseif month >= 9 and month <= 5 and TourGuide = 1:
		TourGuide = 0
		work = 0
	elseif month >= 9 and month <= 5 and TourGuide = 3:
		TourGuide = 0
	end

	if mey_vika['mey_vika_qw'] > 0 and mey_vika['mey_vika_qw'] < 27 and mey_vika['qw_day'] ! daystart:
		if locat['Vicky'] ! 11:
			'<br>Vicky and Vanya never are in the park at this time.'
		else
			act 'Look for Vicky and Vanya (0:05)':
				cla
				minut += 5
				gs 'mey_vika_events', 'park_meet'
				gs 'stat'
			end
		end
	end

	if pcs_inhib >= 35 or exhibitionist_lvl > 0:
		act 'Flash your tits (0:05)':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			menu_off = 1
			gs 'flash', 'tits', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'pav_park', 'start'
		end
	end

	if exhibitionist_lvl > 0:
		act 'Flash your butt (0:05)':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			menu_off = 1
			gs 'flash', 'butt', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'pav_park', 'start'
		end
	end

	gs 'kseniyaQW', 'events'

	if exhibitionist_lvl > 1:
		act 'Flash your pussy (0:05)':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			menu_off = 1
			gs 'flash', 'pussy', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'pav_park', 'start'
		end
	end

	act 'Sit down on the bench': gt'placer_sex','sitting_park_bench'

	if joint > 0 and jointhigh = 0: act 'Smoke a joint': gs 'drugs', 'joint' & gt $loc, $loc_arg

	if (hour >= 20 or hour < 6) and pcs_sleep <= 40:
		if home_owned[2] = 0 and workPTU <= 2 and HotelRoom < 1:
			!nowhere to live in town
			'It''s quite dark now, and you have no where to stay nearby. Maybe you should try to sleep on a bench?'
			if StoryLine = 1: 'Or try your luck and go to Uncle Shulgin''s Apartment?'
		elseif home_owned[2] = 1 and (hour >= 22 or hour < 6):
			'It''s quite dark outside, and you feel tired. Maybe you should head home.'
		else
			'It''s quite dark now, and you feel tired. Maybe you should try sleeping on a bench?'
		end
		act 'Sleep on a bench': gt'placer_sex','sleeping_park_bench'
	end

	gs 'camera', 'check_location'
end

if $ARGS[0] = 'alb_father_meeting_1':
	cla & *clr
	AlbinaQW['ParkRally'] = 1
	minut += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/park/event/meeting/meeting1.jpg"></center>'
	'"First of all, we need to take care of the corruption originating from the police force!" A speech is ringing out to a cheering crowd.'
	'You take a closer look and see that it is Albina''s father. He''s really going hard on the authorities while the crowd is getting more and more rowdy.'
	'"Calm down everyone! Don''t take out your anger now! Instead, go and show them at the ballots how upset you truly are!" Albina''s father finishes to cheers from the crowd.'

	act 'Go on with your day': gt 'pav_park', 'start'
end

if $ARGS[0] = 'alb_father_meeting_2':
	cla & *clr
	AlbinaQW['ParkRally'] = 2
	minut += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/park/event/meeting/meeting2.jpg"></center>'
	'"Don''t believe the ridiculous accusations thrown against me! They''re just trying to smear me!" He''s slamming the podium as he passionately speaks.'
	'The crowd is keeping calm, except for his most die hard supporters, who are yelling profanities against the current administration.'
	'Albina''s father continues on. "I''m just a regular guy, just like the rest of you! My opponents are jealous of my self-made fortune! Why would I be corrupt if I''m already well-off?! No one can pay me off!" He slams the podium again.'

	act 'Go on with your day': gt 'pav_park', 'start'
end

if $ARGS[0] = 'alb_father_meeting_3':
	cla & *clr
	AlbinaQW['ParkRally'] = 3
	minut += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/park/event/meeting/meeting3.jpg"></center>'
	'You walk over to see what the commotion is about and you see Albina''s father speaking to the crowd as usual. This time however, he seems very nervous and stutters a lot while speaking to the crowd. He continues on for a couple more minutes and by the end of the speech, he''s profoundly sweating.'
	'He clears his throat a few times. "And now for some entertainment from my daughter and her dance group. If you look to the right, there are some refreshments available." He awkwardly steps away from the podium.'
	'The music starts and the girls reluctantly step out. They''re all wearing skintight, skimpy leotards that leave nothing to the imagination. The men whistle and holler while the women look on in disgust, whispering amongst themselves that they can''t believe that young girls would wear such revealing outfits.'
	'You stay and watch the performance. The girls are clearly uncomfortable with the situation and you see Albina glare at her father a few times. The girls finish their performance and quickly run from the stage as Albina''s father desperately tries to appease his dimishing crowd as everyone leaves, yourself included.'

	act 'Leave': gt 'pav_park', 'start'
end

--- pav_park ---------------------------------