glife/locations/Komp.qsrc

# komp
!2021/04/26
if $ARGS[0] = 'start':
	*clr & cla
	killvar '$account_used'
	!! This is stupid, if Sveta uses the library computer or Artem's computer, her electricity bill won't go up
	!!elektro += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
	'Your computer boots up, and soon you''re looking at your operating system''s main screen.'

	act 'Shut your computer down': 
		killvar '$subs'
		killvar 'access'
		gt 'komp', 'fin'
	end
	act 'Play Solitaire (0:20)': gt 'komp', 'pasians'
	
	if AlbinaQW['flashdrive'] = 1:
		if $loc = 'dachain' or $loc = 'sitr' or $loc = 'bedr' or $loc = 'bedr2x' or ($loc = 'uni_dorm' and $loc_arg = 'dorm_room') or ($loc = 'city_mansion_residence_2' and $loc_arg = 'yoffice') or ($loc = 'pav_shared_apt' and $loc_arg = 'pcsRoom') or ($loc = 'mey_home' and $loc_arg = '3') or ($loc = 'city_house_res_misc' and $loc_arg = 'livroom') or $loc = 'nichBedroomServant' or (locat['Anya_inroom'] = 0 and $loc = 'bedrPar'):
			act 'Check Albina''s flash drive': gt 'albina_house_events', 'flash_drive'
		end
	end

	if GameCD > 0: act 'Play Disopl': gt 'KGDstart'
	if mc_inventory['tech_game_ds'] > 0: act 'Play Sunset Dead': gt 'KGZstart'
	if GameCD3 > 0: act 'Play Albido': gt 'FSstart'

	!!act 'SunReview of the Dead': gt 'KGZstart'

	!! If the access uses one of the home connections (i.e. Sveta is at home, or in a location that she owns)
	!! and the 'internet_enabled' value is 1, the Sveta is paying utlities.
	!! Now electricity can go up - but by 5???
	elektro += 5

	!! Only because subscription[$subs] is easier to type than subscription[$access[''subscription'']]
	$subs = $access['subscription']

	!! Any location that calls 'komp', 'start' has to set up $access.
	!! $access includes the subscription/conection used, and limitations like 'noporn' and 'nocamshow'
	!! arrived here from mobile net.
	!! Sveta can access the internet if > 0
	if subscription[$subs] > 0:
		if access['metered'] = 0: 
			act 'Browse the internet': gt 'komp', 'browse'
		else
			act 'Browse the internet - You have <<subscription[$subs]>> minutes of access left': gt 'komp', 'browse'
		end
	else
		'You don''t have internet access here, and you don''t even have mobile internet.'
	end
end

if $ARGS[0] = 'browse':
	*clr & cla
	gs 'stat'
	menu_off = 0
	
	act 'Close the browser': gt 'komp','start'
	
	!! TODO: Update
	!! check if the original account still valid?
	!! if account_used > 0
	!! There are 3 ways this can happen during the use of the inernet:
	!!  1. Sveta is using a minute based internet and ran out of minutes.
	!!  2. Sveta is using a subscription, she didn''t have enough money to pay the monthly fee, grace period expired and 
	!!		the interned service has been cut off
	!!  3. Sveta is using a free internet and something went really, really wrong that set subscription[''free''] to 0.
	if subscription[$subs] < 1:
		'<center><b>Browser</b></center>'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/eror.jpg"></center>'
		'You have no internet access, '+iif(access['metered'], ' you have to buy more minutes.', ' maybe you forgot to pay the internet bill?')
		
		if  camwhore = 1 and access['nocamshow'] = 0 and mc_inventory['tech_webcam'] = 1: 
			'Since MyFreeCams will cover the cost, you can still log on to do a cam show.'
			act 'Go to MyFreeCams.org': gt 'komp_camgirl', 'start'
		end
	else
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
		if access['general-text'] = 1: '<center><h4 style="color: red;"><b><<$access[''general-text'']>></b></h4></center>'
		'You go to your favourite start page, while you try to decide on what you want to see right now.'		
		'A blinking banner for a <a href="exec: gt ''komp'',''agent''">Kirsanova Real Estate Agency</a> keeps popping up in the corner.'
		if $access['noporn'] = 1:
			"<b><<$access['noporn']>></b>"
		end
		if camwhore = 1 and access['nocamshow'] = 1 and mc_inventory['tech_webcam'] = 1: 
			"<b><<$access['nocamshow']>></b>"
		end
		if func('homes_properties', 'is_property_of_status', 'owned', 'city_apartment') and husband = 0: act 'Rent your apartment out': gt 'komp', 'sale'

		if access['noporn'] = 0: act 'Watch porn': gt 'komp', 'porno'

		act 'Browse a dating website (1:00)': gt 'komp', 'znak'

		if hour < 20 and hour > 7:
			if $clothingworntype = 'nude':
				'You need to be dressed before searching for jobs.'
			else
				act 'Look for a job online': gt 'komp', 'rabota'
			end
		end

		act 'Search for cable TV services (1:00)': gt 'komp', 'kabtv'
		act 'Play an online game': gt 'KGstart'
		act 'Check social media on Assbook': gt 'komp_assbook', 'main'
		if shantfoto > 0: act 'Find the girl you took photos of in the park': gt 'komp_assbook', 'blackmail'

		if fuckornot = 3: act 'Visit ''Fuckable or not'' site': $view_location = 'komp' & gt 'komp_HF_or_not', 'fuckornot'
		if hotornot >= 2: act 'Visit ''Hot or not'' site': $view_location = 'komp' & gt 'komp_HF_or_not', 'hotornot'

		if fuckornot_uni = 1: act 'Visit ''Fuckable or not'' University site': $view_location = 'komp' & gt 'komp_HF_or_not', 'fuckornot_uni'
		if hotornot_uni = 1: act 'Visit ''Hot or not'' University site': $view_location = 'komp' & gt 'komp_HF_or_not', 'hotornot_uni'
		!!if bankAccount > 0: act 'Visit your bank, maybe to purchase more online time': gt 'komp', 'bank'
		if gor_dorm = 7: act 'Read letter from Eugene': gt 'etoexhib', 'pos91'
		if camwhore = 1 and access['nocamshow'] = 0 and mc_inventory['tech_webcam'] = 1: act 'Go to MyFreeCams.org': gt 'komp_camgirl', 'start'
		if (mid($start_type,1,2) = 'sg' and SchoolAtestat = 0) or func('uniutil', 'student', 'enrolled'): act 'Spend time studying': gt 'komp', 'study'
		if sucpcinfo = 0 and succubxp > 0: act 'Research the strange feelings you''ve been having': gt 'succubus', 'kompresearch'
	end
end

if $ARGS[0] = 'sale':
	*clr & cla
	!! TODO: Update time and internet
	
	!! IMPORTANT: What happens if an activity takes more time than the minutes Sveta has? We just say "You tried, but could not finish"?
	if access['metered'] and subscription[$subs] < 15:
		'You check the website, but realize that <<subscription[$subs]>> minutes won''t be enough to fill out all the forms.'
	else
		minut += 30
		elektro += 3
		gs 'internet_mobile', 'use_internet', $subs, 30

		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
		'You go to a popular website where people can post advertisements for free. You could post an advertisement here.'
		if obkvsdam >= 1 and func('homes_properties', 'property_status', 'city_apartment') = 2: 'You placed an advertisement to rent out your apartment. You should probably check every once in a while to see if anyone responded.'

		if obkvsdam = 0 and func('homes_properties', 'property_status', 'city_apartment') = 2:
			act 'Rent out your city residential apartment':obkvsdam = 1 & gt 'komp', 'sale'
		elseif obkvsdam > 0:
			act 'Check if you got any replies':
				cla
				if obkvsdam = 1:
					'No one has responded to your offer to rent out your apartment just yet.'
				elseif obkvsdam > 1: 
					predsum = 14000 + (obkvsdam*1000)
					'Someone wants to stay in your apartment for a month! They''re offering you <<predsumm>> <b>₽</b> in cash.'

					act 'Accept the offer':
						gs 'homes_properties', 'tenants_move_in', 'city_apartment', iif(month + 1 > 12, 1, month + 1), MIN(day, monthsEnd[tenant_endmonth])
						karta += predsumm
						gt 'komp', 'start'
					end
					killvar 'predsum'
				end

				act 'Leave this website': gt 'komp', 'browse'
			end
		end
	end
	act 'Leave this website': gt 'komp', 'browse'
end

if $ARGS[0] = 'porno':
	*clr & cla
	gs 'stat'

	if subscription[$subs] < 1:
		'<center><b>Browser</b></center>'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/eror.jpg"></center>'
		'You have no internet access, '+iif(access['metered'], ' you have to buy more minutes.', ' maybe you forgot to pay the internet bill?')

		act '<B>Close the browser</B>': gt 'komp','start'
	elseif access['noporn'] = 1:
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
		'<<$access[''noporn'']>>'

		act 'Leave this website': gt 'komp', 'browse'
	else
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
		'You go to a porn site and browse for a few minutes, trying to find a hot video.'

		act 'Watch porn':
			*clr & cla
			elektro += 3
			pcs_mood += rand(10, 20)
			minut += 30
			gs 'internet_mobile', 'use_internet', $subs, 30
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/porno.jpg"></center>'
			'You find a video you think you''d enjoy and spend some time watching it. Wow, that girl is so lucky...'

			gs 'arousal', 'porn', 30
			minut -= 30
			gs 'stat'

			act 'The video ends...': gt 'komp', 'porno'
		end

		if pcs_horny >= 50: act 'Masturbate': gt 'komp', 'masturbate'

		act 'Leave this website': gt 'komp', 'browse'
	end
end

if $ARGS[0] = 'masturbate':
	*clr & cla
	
	!! needs this because can arrive here from this code block and time can be gone
	if subscription[$subs] < 1:
		'You have no internet access, '+iif(access['metered'], ' you have to buy more minutes.', ' maybe you forgot to pay the internet bill?')
	else
		gs 'sweat', 'add', 10

		if divanmastr = 0:
			divanmastr = 1
			if pcs_inhib < 30:inhib_exp += rand(1,3)
		end

		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/kompmas.jpg"></center>'
		'You get comfortable in front of your computer and with one hand begin to fondle your breasts, while you click on a link to something really dirty.'
		'You let go of the mouse and start rubbing your pussy, imagining you''re the woman in the video. The fantasy and your touching are getting you all hot and bothered.'

		gs 'arousal', 'clit_finger', 30, 'masturbate'
		minut -= 30
		gs 'stat'

		if pcs_horny >= 100:
			$orgasm_or = 'yes'
			$orgasm_txt = 'Suddenly your muscles tighten and you cum powerfully, while you stifle your moans so your neighbors won''t find out. Afterward, you have goosebumps all over your skin. That was just what you needed!'
			gs 'arousal', 'clit_finger', -1, 'masturbate'
			gs 'stat'
		end

		act 'Stop masturbating':divanmastr = 0 & gt 'komp', 'porno'

		gs 'arousal', 'end'
		gs 'stat'

		if pcs_horny >= 50: act 'Masturbate some more': gt 'komp', 'masturbate'
	end
end

if $ARGS[0] = 'pasians':
	*clr & cla
	minut += 20
	elektro += 3
	pcs_mood += rand(10, 20)

	gs 'stat'
	'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
	'You entertain yourself for about twenty minutes, playing a game of solitaire on the computer.'

	act 'Play for another 20 minutes': gt 'komp', 'pasians'
	act 'Return to desktop': gt 'komp', 'start'
end

if $ARGS[0] = 'znak':
	*clr & cla
	minut += 30
	pcs_mood += 5
	elektro += 3
	gs 'internet_mobile', 'use_internet', $subs, 30
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
	'You enter a dating site, and immediately see all sorts of profiles of both men and women.'
	'The guys on this site are rather cute! If you''re single, you could try contacting one. Who knows, maybe you''ll meet the man of your dreams through here!'

	if gor_dorm = 8:
		act 'Pick someone suitable for Eugenia':
			cla
			gor_dorm = 9

			'You click through dozens of profiles, before choosing a guy who you think would be a good match for Eugenia. You send him a message, asking if he wants to meet up somewhere.'
			'Now the waiting game begins! Let''s hope you picked a nice guy for her...'

			act 'Leave this website': gt 'komp', 'browse'
		end
	!! Eligible homes: 1, 2, 3, 4, 5, 7 , 10, 11, 15
	elseif $home['type'] ! 'permanent_residence':
		pcs_mood += rand(5, 10)
		'You spend time looking at the various profiles, but it won''t let you register unless you have your own home and it is set as your current home.'
		'Still, some of the pictures were quite raunchy and the more desperate profiles were really funny.'
	else
		if pcs_lover < 3:
			act 'Look for a kind man':
				cla
				gs 'boy'
				gs 'boyfrend', 'start'
				haraklover[lover_number] = 0
				'You find a guy named <<$loverdesc[lover_number]>> and send him your number after checking out his profile. You hope he will call you!'

				act 'Leave this website': gt 'komp', 'browse'
			end

			act 'Look for a normal guy':
				cla
				gs 'boy'
				gs 'boyfrend', 'start'
				haraklover[lover_number] = 1
				'You find a guy named <<$loverdesc[lover_number]>> and send him your number after checking out his profile. You hope he will call you!'

				act 'Leave this website': gt 'komp', 'browse'
			end

			act 'Look for a strong man':
				cla
				gs 'boy'
				gs 'boyfrend', 'start'
				haraklover[lover_number] = 2
				'You find a guy named <<$loverdesc[lover_number]>> and send him your number after checking out his profile. You hope he will call you!'

				act 'Leave this website': gt 'komp', 'browse'
			end
		end
	end
	act 'Leave this website': gt 'komp', 'browse'
end

if $ARGS[0] = 'kabtv':
	*clr & cla
	minut += 5
	elektro += 3
	gs 'internet_mobile', 'use_internet', $subs, 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
	'You check out the website of the local cable TV provider. A subscription for cable TV costs 300 <b>₽</b> per month, payable on the 25th.'
	''

	if kabel = 1:
		'You currently have a cable subscription for your TV.'

		act 'Cancel your cable subscription (300 <b>₽</b>)':
			cla
			kabel = 0
			karta -= 300
			msg 'Your subscription has been canceled and you can no longer watch the extra channels. The cable firm charges a one-time fee of 300 <b>₽</b> for disconnecting you.'
			gt 'komp', 'browse'
		end
	elseif kabel = 0 and mc_inventory['tech_tv'] >= 1 and mc_inventory['plasma_tv'] = 0:
		'You currently do not have a cable subscription for your TV.'

		act 'Get cable services for your TV':
			cla
			msg 'Unfortunately your TV is too old and crap for cable. You''ll have to get a modern TV first.'
			gt 'komp', 'browse'
		end
	elseif kabel = 0 and mc_inventory['plasma_tv'] >= 1:
		'You currently do not have a cable subscription for your TV.'

		act 'Get cable services for your TV (300 <b>₽</b> per month)':
			cla
			kabel = 1
			minut += 10
			gs 'internet_mobile', 'use_internet', $subs, 10
			gs 'stat'

			msg 'Soon after you fill out the form, you get a confirmation message that your sign-up was successful. You should have the extra channels on your TV now.'
			gt 'komp', 'browse'
		end
	else
		'You don''t even have a TV!'
		act 'Leave this website': gt 'komp', 'browse'
	end
	act 'Leave this website': gt 'komp', 'browse'
end

if $ARGS[0] = 'foto':
	*clr & cla
	gs 'stat'

	if subscription[$subs] < 1:
		'<center><b>Browser</b></center>'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/eror.jpg"></center>'
		'You have no internet access, '+iif(access['metered'], ' you have to buy more minutes.', ' maybe you forgot to pay the internet bill?')
		act '<B>Close the browser</B>': gt 'komp','start'
	else
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'
		'You''re currently on Russia''s biggest social network site, "Assbook". Almost everyone has an account here, probably including the girl you took that photo of the other day!'
		'"Maybe if I can find her, I can blackmail her", you think to yourself. "This photo is very raunchy, after all... I bet she would hate to see it published if she''s important!"'
		'You can''t help but rub your pussy every now and then while you look at it. You''ll probably keep a copy of this for yourself, either way!'

		if shantfoto > 0:
			act 'Try to find out who she is (1:00)':
				cla
				minut += 60
				elektro += 6
				gs 'internet_mobile', 'use_internet', $subs, 60
				fotsearchrand = rand(0,10)

				if fotsearchrand <= 7:
					'Despite your best efforts, you don''t manage to find the girl this time.'

					act 'Go back to the "Assbook" main page': gt 'komp', 'foto'
				end

				if fotsearchrand > 7:
					shantfoto -= 1
					'Despite your best efforts, you don''t manage to... wait, that''s her! You found her!'
					gerofotorand = rand(0,100)

					if gerofotorand > 30:
						'Your dreams of making a fortune are quickly shattered when you check out her profile. Cheap clothes, few friends, lives in a poor district of the city... this girl is not worth blackmailing.'

						act 'Go back to the "Assbook" main page': gt 'komp', 'foto'
					end

					if gerofotorand >= 5 and gerofotorand <= 30:
						shantsr += 1
						'When you click through her profile, you estimate she''s an unknown middle-class girl. Still, she has a lot of friends and the outfits she''s wearing in her photos look stylish... she has money to spend.'
						'"Why not make her spend some of it on me?" you laugh to yourself, and begin to write a private message.'
						'You send her a copy of the photo with the private message and tell her to transfer a very modest amount of 5,000 <b>₽</b> to your bank account. If she doesn''t want that photo to be sent to her entire friends list (which you secured before sending the message), the money needs to be on your bank account within 48 hours.'

						act 'Go back to the "Assbook" main page': gt 'komp', 'foto'
					end

					if gerofotorand < 5:
						shantbog += 1
						'You can barely believe it when you read her profile, this girl is a celebrity! It would be a major scandal if this photo got published!'
						'You send her a copy of the photo with a private message, telling her to transfer 30,000 <b>₽</b> to your bank account. If she doesn''t want that photo to be sent to the press, the money needs to be on your bank account within 48 hours.'

						act 'Go back to the "Assbook" main page': gt 'komp', 'foto'
					end
				end
			end
		end

		act 'Leave this website': gt 'komp', 'browse'
	end
end

if $ARGS[0] = 'rabota':
	*clr & cla
	if subscription[$subs] < 1:
		'<center><b>Browser</b></center>'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/eror.jpg"></center>'
		'You have no internet access, '+iif(access['metered'], ' you have to buy more minutes.', ' maybe you forgot to pay the internet bill?')

		act '<B>Close the browser</B>': gt 'komp','start'
	else
		minut += 30
		elektro += 3
		gs 'internet_mobile', 'use_internet', $subs, 30
		komprabota = rand(0, 10)
		if $loc = 'vasilyhome':komprabota = rand(5, 15)
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/komp.jpg"></center>'

		if komprabota = 0 and gorodokkomp = 0:
			'You find a job vacancy, on a legit-looking website. It reads: "Wanted! <b>URGENTLY!</b> Female underwear model, for a photoshoot. Pay: 2000 <b>₽</b> cash."'
			'The description explains that they need someone today. If you decide to take this job, you will have to shut down your computer and go there right away.'

			if pcs_apprnc < 120:
				'You consider it for a moment but decide against it. You''re probably not pretty enough to be an underwear model.'
			elseif pcs_apprnc >= 120:
				act 'Accept the job and go there': gt 'qjob', 'var1'
			end

			if hour < 20 and hour > 7: act 'Search for more jobs': gt 'komp', 'rabota'

			act 'Leave this website': gt 'komp', 'browse'
		elseif komprabota = 1 and gorodokkomp = 0:
			'You find a job vacancy, on a legit-looking website. It reads: "Wanted! <b>URGENTLY!</b> Female underwear model, for a photoshoot. Pay: 2000 <b>₽</b> cash."'
			'The description explains that they need someone today. If you decide to take this job, you will have to shut down your computer and go there right away.'

			if pcs_apprnc < 120:
				'You consider it for a moment, but decide against it. You''re probably not pretty enough to be an underwear model.'
			elseif pcs_apprnc >= 120:
				act 'Accept the job and go there': gt 'qjob', 'var2'
			end

			if hour < 20 and hour > 7: act 'Search for more jobs': gt 'komp', 'rabota'

			act 'Leave this website': gt 'komp', 'browse'
		elseif komprabota > 1 and komprabota < 5 and gorodokkomp = 0:
			'You find a job vacancy, on a legit-looking website. It reads: "Wanted! <b>URGENTLY!</b> Good-looking female model, posing for artwork. Must be able to stand still in one pose for a long time. Pay: 1000 <b>₽</b> cash."'
			'The description explains that they need someone today. If you decide to take this job, you will have to shut down your computer and go there right away.'

			if pcs_apprnc < 60:
				'You consider it for a moment but decide against it. You''re probably not pretty enough to be a model.'
			elseif pcs_apprnc >= 60:
				act 'Accept the job and go there': gt 'qjob', 'var3'
			end

			if hour < 20 and hour > 7: act 'Search for more jobs': gt 'komp', 'rabota'

			act 'Leave this website': gt 'komp', 'browse'
		elseif komprabota > 4 and komprabota < 8 and camwhore = 0:
			'You find a job vacancy, on a legit-looking website. It reads: "Wanted! Webcam models. Flexible working hours. Click for more info."'
			act 'Gather more information':
				*clr & cla
				minut += 5
				elektro += 1
				gs 'internet_mobile', 'use_internet', $subs, 5
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/camwhore1.jpg"></center>'
				'You click the button and get taken to the full job description.'
				'<i>For this job, you will have to expose your body in front of customers, fulfilling their wishes. Payment is completely based on a tip system: customers on the website can buy tokens, which they can use to tip girls they enjoy watching.'
				'The website will cover all costs during your shows. But how much money you make is up to you: the better you are at attracting viewers, and the more you are willing to do to please them, the more likely they will be to tip you.'
				'After a quick verification, you usually get paid immediately after a session ends. The tokens you earn will be converted to rubles, and paid to your bank account right away.'
				'The website hides your stream for viewers from your region, so the chance of being recognized by someone you know in real life is very low.'
				'If you''re interested in becoming a webcam girl, please fill in this questionnaire below.</i>'
				
				if bankAccount = 0:
					'You need a valid bank account to be able to register for this job.'
				else
					if pcs_inhib >= 40 or exhibitionist_lvl > 1 or (pcs_inhib >= 35 and exhibitionist_lvl > 0):
						act 'Fill in the questionnaire':
							*clr & cla
							camwhore = 1
							mfcclients = 0
							camclients = 0
							mfccum = 0
							minut += 20
							gs 'stat'
							'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/camwhore2.jpg"></center>'
							if $pcs_webcamname = '':
								'You consider which name you''d like to register under.'
									$pcs_webcamname = input("Which name would you like to use? (Leave blank for <<$pcs_nickname>>)")
								if $pcs_webcamname = '':$pcs_webcamname = '<<$pcs_nickname>>'
							end
							'You fill out the questionnaire and register yourself as a webcam model. Ten minutes later, you have already been approved and you can now earn money as a webcam girl.'
							'Of course, you will need a functioning webcam to do this! If you don''t have one yet, they are fairly cheap to buy at most local supermarket chains.'
							act 'Leave this website': gt 'komp','browse'
						end
						act 'Leave this website': gt 'komp','browse'
					else
						*nl
						'You don''t feel comfortable showing off your body in this way.'
					end
				end

				if hour < 20 and hour > 7: act 'Search for more jobs': gt 'komp','rabota'
				act 'Leave this website': gt 'komp','browse'
			end
		else
			'Unfortunately, you do not find any jobs you would consider doing.'

			if hour < 20 and hour > 7: act 'Search for more jobs': gt 'komp','rabota'
			act 'Leave this website': gt 'komp','browse'
		end
	end
end

if $ARGS[0] = 'study':
	*clr & cla
	minut += 30
	elektro += 3
	gs 'internet_mobile', 'use_internet', $subs, 30
	gs 'exp_gain', 'intel', 1 + (mentats_dose - rand(0,mentats_dose))
	gs 'exp_gain', 'compskl', 1
	'<center><b>The Institute for Education Measurement</b></center>'
	'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/study.jpg"></center>'
	'You spend an hour on the IEM website, reading news articles and educational blogs. You already feel a bit smarter.'

	act 'Leave this website': gt'komp','browse'
end

if $ARGS[0] = 'agent' :
	*clr & cla
	minut += 30
	elektro += 3
	gs 'internet_mobile', 'use_internet', $subs, 30
	gs 'stat'
	gs 'housing', 'rent'
	gs 'housing', 'sale'
	'<center><b>Kirsanova Real Estate Agency</b></center>'
	'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/agent.jpg"></center>'
	*nl
	'You''re currently at the website of the largest real estate agency in the area, Kirsanova Real Estate Agency.'
	'<br>The website shows they have apartments available for rent or purchase in various areas, both in and out of the city. Renting or purchasing requires you to visit the agency in the city center to fill out an application and collect the keys. Rent on all properties is deducted every month on the 25th.'
	*nl
	'<b>Property listing</b>:'
	if func('homes_properties', 'is_property_of_status', 'rented', 'city_apartment') :
		if func('homes_properties', 'get_rent_days', 'city_apartment') > 0: 
			'You have <B><<func(''homes_properties'', ''get_rent_days'', ''city_apartment'')>> days</B> remaining on the rental of your St. Petersburg apartment.'
			*nl
		end
		if karta + bankDebtLimit >= func('homes_properties', 'get_rent_amount', 'city_apartment'):
			act 'Pay rent on St. Petersburg':
				cla
				gs 'homes_properties', 'pay_rent', 'city_apartment', 'card'
				'After a very simple procedure, you can now call an apartment in the city residential district home for another month. You have <B><<func(''homes_properties'', ''get_rent_days'', ''city_apartment'')>> days</B> remaining on the rental of your apartment.'
				act 'Leave this website': gt 'komp','browse'
			end
		end
	elseif func('homes_properties', 'has_access', 'city_apartment') = 0:
		'There is an apartment in St. Petersburg residential area available, for rent or purchase.'
		'Rent is: <<func(''homes_properties'', ''get_rent_amount'', ''city_apartment'')>><b>₽</b> per month. Current sale price is listed at: <<func(''homes_properties'', ''get_property_sales_price'', ''city_apartment'')>> <b>₽</b>.'
		*nl
	end

	if func('homes_properties', 'has_access', 'village_cottage') = 0:
		'There is a holiday cottage with an adjacent allotment in the communal village for sale.'
		'Current sale price is listed at: <<func(''homes_properties'', ''get_property_sales_price'', ''village_cottage'')>> <b>₽</b>.'
		*nl
	end
	
	if func('homes_properties', 'is_property_of_status', 'rented', 'old_town_apartment'):
		if func('homes_properties', 'get_rent_days', 'old_town_apartment') >= 0: 
			'You have <B><<func(''homes_properties'', ''get_rent_days'', ''old_town_apartment'')>> days</B> remaining on the rental of your Pushkin apartment.'
			*nl
		end
		
		if karta + bankDebtLimit >= func('homes_properties', 'get_rent_amount', 'old_town_apartment'):
			act 'Pay rent on Pushkin':
				cla
				gs 'homes_properties', 'pay_rent', 'old_town_apartment', 'card'
				'After a very simple procedure, you can now call an apartment in Pushkin home for another month. You have <B><<func(''homes_properties'', ''get_rent_days'', ''old_town_apartment'')>> days</B> remaining on the rental of your apartment.'
				act 'Leave this website': gt 'komp','browse'
			end
		end
	elseif func('homes_properties', 'has_access', 'old_town_apartment') = 0:
		'There is an apartment in Pushkin area (Old Town) available to rent.'
		'Rent is: <<func(''homes_properties'', ''get_rent_amount'', ''old_town_apartment'')>><b>₽</b> per month.'
		*nl
	end

	if func('homes_properties', 'has_access', 'matryona_mansion') = 0:
		'There is a plot in the suburbs available for purchase, with planning permission for a mansion.'
		'Current sale price is listed at: <<func(''homes_properties'', ''get_property_sales_price'', ''matryona_mansion'')>> <b>₽</b>.'
		*nl
	end

	act 'Leave this website': gt 'komp','browse'
end

if $ARGS[0] = 'bank':
	'<center><img <<$set_imgh>> src="images/pc/items/accessories/computer/online_bank.jpg"></center>'
	if karta + bankDebtLimit >= 10:
		*pl

		'You can buy prepaid internet access online through your bank account. 1 hour of internet only costs 10 <b>₽</b>! *'

		*pl

		if karta >= 0:
			'You have <<karta>> <b>₽</b> in your account.'
			'You have an overdraft limit of <font color="blue"><<bankDebtLimit>></font>!'
		else
			'You are overdrawn by <font color="red"><<-1 * karta>> <b>₽</b></font>.'
			'You have a remaining credit limit of <font color="blue"><<bankDebtLimit + karta>></font>!'
		end

		*pl

		!! TODO: This needs to be updated
		act 'Buy internet time':
			cla
			intinp = input ("How many hours of internet access do you wish to purchase? (1hr = 10 <b>₽</b>)")

			if intinp <= 0 or intinp * 10 > karta + bankDebtLimit:
				'Invalid amount.'
			else
				karta -= intinp * 10
				internet += intinp
				'You pay for <<intinp>> hours of prepaid internet access. You have a total of <<internet>> hours of internet access remaining.'
				'<<intinp * 10>> <b>₽</b> was removed from your account to pay for it.'
			end
			act 'Continue': gt 'komp', 'bank'
		end
	end
	act 'Close your browser': gt 'komp', 'browse'
end

if $ARGS[0] = 'fin': gt $loc, $loc_arg


--- komp ---------------------------------