glife/locations/SMStext_builder.qsrc

# SMStext_builder

!	How to use SMStext_builder:
!	
!	Start with:
!		gs 'SMStext_builder', 'start'
!	Then add your content through "send" and "receive":
!		gs 'SMStext_builder', 'send', [$text]
!		gs 'SMStext_builder', 'receive', [$text]
!		...
!		...
!	
!	If you want Sveta to reply to this (and thus the player potentially having a choice):
!		gs 'SMStext_builder', 'add_reply', [$text], [$file_name], [$file_args0], [$file_args1], ...
!		gs 'SMStext_builder', 'add_reply', [$text], [$file_name], [$file_args0], [$file_args1], ...
!	
!	Finally, if this is a new sms-chain, use:
!		gs 'SMStext_builder', 'add_sms', [$npc_code]
!	
!	If you are updating an ongoing sms-chain (usually in reponse to a choice made in the replies), use:
!		gs 'SMStext_builder', 'show_sms', ARGS[{n}]
!				where {n} is one more than the number of args you passed to the choice.
!				So if you are used:
!					gs 'SMStext_builder', 'add_reply', [$text], [$file_name], [$file_args0], [$file_args1].
!				Then you would pass ARGS[2] (since you used $ARGS[0] and $ARGS[1]):
!				gs 'SMStext_builder', 'add_sms', ARGS[2]
!	
!	Finally after the player has made a choice, you want to rebuild the SMS-history again (to get rid of the replies).
!	Starting fresh or having done your final update (even if you never updated it anyway)
!	End it with:
!		gs 'SMStext_builder', 'end'




if $ARGS[0] = 'start':
	$temp_SMStext = ''

elseif $ARGS[0] = 'end':
	killvar '$temp_SMStext'
	killvar '$temp_SMSreplies'
	killvar 'stb_i'
	killvar 'stb_maxi'
end

if $ARGS[0] = 'send':
	temp_text_width = max(10, 90 - 2 * len($ARGS[1]))
	$temp_SMStext += '<table width=80%><tr><td width=<<temp_text_width>>%></td><td collspan=2 bgcolor=pink style="padding-top:5pt; padding-bottom:5pt; padding-left:10pt; padding-right:3pt"><font color=black>'
	$temp_SMStext += $ARGS[1]
	$temp_SMStext += '</font></td></tr></table>'
	killvar 'temp_text_width'

elseif $ARGS[0] = 'send_img':
	$temp_SMStext += '<table width=80%><tr><td width=10%></td><td collspan=2 bgcolor=pink align=center style="white-space:pre-wrap">'
	if $ARGS[2] = '': $ARGS[2] = $ARGS[1]
	$temp_SMStext += '<br><img src="<<$ARGS[1]>>" alt="<<$ARGS[2]>>" style="horizontal-align:center; max-height:90%; max-width:90%"><br><br>'
	$temp_SMStext += '</td></tr></table>'


elseif $ARGS[0] = 'receive':
	temp_text_width = max(10, 90 - 2 * len($ARGS[1]))
	$temp_SMStext += '<table width=80%><tr><td collspan=2 bgcolor="#D4CEF9" style="padding-top:5pt; padding-bottom:5pt; padding-left:10pt; padding-right:3pt"><font color=black>'
	$temp_SMStext += $ARGS[1]
	$temp_SMStext += '</font></td><td width=<<temp_text_width>>%></td></tr></table>'
	killvar 'temp_text_width'

elseif $ARGS[0] = 'receive_img':
	$temp_SMStext += '<table width=80%><tr><td collspan=2 bgcolor="#D4CEF9" align=center style="white-space:pre-wrap">'
	if $ARGS[2] = '': $ARGS[2] = $ARGS[1]
	$temp_SMStext += '<br><img src="<<$ARGS[1]>>" alt="<<$ARGS[2]>>" style="horizontal-align:center; max-height:90%; max-width:90%"><br><br>'
	$temp_SMStext += '</td><td width=10%></td></tr></table>'
end


!	How to use 'add_reply':
!		gs 'SMStext_builder', 'add_reply', $reply_text, $file_loc, $file_arg1, $file_arg2, $file_args2, ...
!		gs 'SMStext_builder', 'add_reply', 'Hello', 'band_tour_anushka_SMS', 'week1', 'choice_a'
if $ARGS[0] = 'add_reply':
	$temp_reply_str = '<a href="exec: gs '

	stb_n_args = arrsize('$ARGS')
	stb_i = 2
	:SMS_build_reply_loop
	if stb_i <= stb_n_args:
		$temp_reply_str += '''<<$ARGS[stb_i]>>'', '
		stb_i += 1
		jump 'SMS_build_reply_loop'
	end

	$temp_reply_str += 'telefon[''SMSid'']">' + $ARGS[1] + '</a>'
	$temp_SMSreplies[] = $temp_reply_str

	killvar 'temp_reply_str'
	killvar 'stb_i'
	killvar 'stb_n_args'

elseif $ARGS[0] = 'set_replies':
	$temp_SMStext += '<table><tr><th> Reply</th></tr><tr><td>'

	stb_maxi = arrsize('temp_SMSreplies')
	stb_i = 0
	if stb_maxi >= 2:
		:SMS_reply_loop
			$temp_SMStext += $temp_SMSreplies[stb_i]
			$temp_SMStext += '</td></tr><tr><td>'
			stb_i += 1
		if stb_i < stb_maxi - 1: jump 'SMS_reply_loop'
	end
	$temp_SMStext += $temp_SMSreplies[stb_i]
	$temp_SMStext += '</td></tr></table>'

	killvar '$temp_SMSreplies'
	killvar 'stb_i'
	killvar 'stb_maxi'
end

if $ARGS[0] = 'add_sms':
	if arrsize('temp_SMSreplies') > 0: gs 'SMStext_builder', 'set_replies'
	gs 'telefon', 'add_sms', $ARGS[1], $temp_SMStext, $ARGS[2], $ARGS[3], $ARGS[4], $ARGS[5]

elseif $ARGS[0] = 'show_sms':
	if arrsize('temp_SMSreplies') > 0: gs 'SMStext_builder', 'set_replies'
	$SMSMessage[ARGS[1]] = $temp_SMStext
	gs 'telefon', 'show_sms', ARGS[1], $ARGS[2], $ARGS[3], $ARGS[4], $ARGS[5]
end

! $ARGS[1] = displayed text
! $ARGS[2] = control string = 'c|sw|u|n|b|sh|ft|fa|fp'
!		c: clothed | sw: swim | u: underwear
!		n: nude | b: bath | sh: shower
!		ft: flash tits | fa: flash ass | fp: flash pussy
! $ARGS[3] -> onward = the return location.
! gs 'SMStext_builder', 'send_selfie', 'Send a sexy selfie', 'cbf', 
if $ARGS[0] = 'send_selfie':
	$temp_reply_str = '<a href="exec: gs ''SMS_selfies'', ''selfie_menu'', ''<<lcase($ARGS[2])>>'', telefon[''SMSid''], '

	stb_n_args = arrsize('$ARGS')
	stb_i = 3
	:SMS_build_send_selfie_loop
	if stb_i < stb_n_args:
		$temp_reply_str +=  '''<<$ARGS[stb_i]>>'', '
		stb_i += 1
		jump 'SMS_build_send_selfie_loop'
	end
	$temp_reply_str = mid($temp_reply_str, 1, len($temp_reply_str)-2)

	$temp_reply_str += '"><<$ARGS[1]>></a>'
	$temp_SMSreplies[] = $temp_reply_str

	killvar 'temp_reply_str'
	killvar 'stb_i'
	killvar 'stb_n_args'
end



--- SMStext_builder ---------------------------------