# KatjaHomeTalk
gs 'KatjaHomeDin'
gs 'stat'
'<center><b><font color="maroon"><<$npcName[14]>> <<$npcSurName[14]>></font></b></center>'
'<center><img src="images/qwest/alter/npc/14.jpg"></center>'

if sweat > 0:
	'Katja wrinkled her nose "Sveta, you`re all sweaty, go to the shower?"'

	act 'Go to the shower':
		cls
		minut += 15
		gs 'stat'

		if KatjaHorny >= 50:
			'Katja held you in the shower. She blushed and said "I, Come join Pomo."'

			act 'one wash':
				cls
				dynamic $showerdin
				minut += 15
				set horny += 1
				set hapri = 1
				set mop = 1
				set sweat = -3

				if frost > 0:frost = 0

				gs 'stat'
				'<center><img src="images/dush.jpg"></center>'
				'You kicked out of the shower and Katja closed the door. You got into the shower and began to lather your body washcloth. After washed off the soap and washed her hair with shampoo. Rinse off the shampoo you become completely clean.'

				act 'Get out of the shower':gt $curloc
			end

			act 'Bathe together':
				cls
				dynamic $showerdin
				minut += 15
				set horny += 1
				set hapri = 1
				set mop = 1
				set sweat = -3

				if frost > 0:frost = 0

				horny += 10
				KatjaHorny += 10
				KatjaLust += 1
				gs 'stat'
				'<center><img src="images/qwest/alter/katja/shower.jpg"></center>'
				'You undressed and climbed together with Katja in the shower.'

				if lobok <= 0:
					'Katja eyes slid over your body a little lingering on your breasts and pussy. Katja took a shower together and you became watered.'

					act 'further':
						cls
						gs 'stat'
						'<center><img src="images/qwest/alter/katja/shower2.jpg"></center>'
						'Katja gently shampooed you gel and rinse with warm shower jets.'

						if KatjaLust >= 10 and KatjaHorny >= 90:
							'Katja washed with soap your pussy and breasts gentle stroking his little palms. Her cheeks were flushed and her eyes glistened.'
							dynamic $katja_shower_kiss_home
						else
							'Katja finally finished and you wash herself pomylas.'

							act 'Get out of the shower':gt $curloc
						end
					end
				end

				if lobok > 0:
					'Katja eyes slid over your body a little lingering on her breasts and pubic hair. Katja smiled "Svetulya, you got such vegetation, it is no longer fashionable, I`ll let sbreyu hair."'

					act 'Shave the hair between her legs ':
						cls
						minut += 5
						lobok = -3
						KatjaHorny += 10
						KatjaLust += 1
						gs 'stat'
						'<center><img src="images/qwest/alter/katja/lobok.jpg"></center>'
						'Katja sat in the bathroom and you lathered your crotch passing lathered his stomach and chest. She took a razor and began to gently shave your hairs between her legs.'

						if KatjaLust >= 10 and KatjaHorny >= 90:
							'Katja washed with soap your pussy and breasts gentle stroking his little palms. Her cheeks were flushed and her eyes glistened.'
							dynamic $katja_shower_kiss_home
						else
							'Katja finally shaved all your hair between her legs and began to wash off with soap you.'

							act 'Get out of the shower':gt $curloc
						end
					end
				end
			end
		end

		if KatjaHorny < 50:
			dynamic $showerdin
			minut += 15
			set horny += 1
			set hapri = 1
			set mop = 1
			set sweat = -3

			if frost > 0:frost = 0

			gs 'stat'
			'<center><img src="images/pics/dush.jpg"></center>'
			'Katja showed you where the toiletries and came out of the shower. You got into the shower and began to lather your body washcloth. After washed off the soap and washed her hair with shampoo. Rinse off the shampoo you become completely clean.'

			act 'Get out of the shower':gt $curloc
		end
	end
else
	!!not sweaty
	if hour < 20:
		act 'Chat with Katja':
			cls
			KatjaHorny += 1
			!KatjaLust += 1
			!if npcSex[14] = 1:
			minut += 15
			gs 'stat'
			'<center><b><font color="maroon"><<$npcName[14]>> <<$npcSurName[14]>></font></b></center>'
			'<center><img src="images/qwest/alter/npc/14.jpg"></center>'

			if katjaPreg = 0 or knowKatjaPreg >= 1:
				if KatjaHorny < 50:'Katka talks about the lessons, cosmetics, the latest fashion trends in clothing and other very important things.'

				if KatjaHorny >= 50:
					dynamic $d_katjaSextalk
					exit
				end
			end

			if katjaPreg > 0 and knowKatjaPreg = 0:
				if knowKatjaPreg = 0:
					'Katja biting her lip without looking you in the eye, Finally typed determination and says "Sveta, i am pregnant."'

					act 'from?':
						cls
						minut += 5
						knowKatjaPreg = 1
						gs 'stat'
						'You asked dumbfounded "from." Katja wrinkled her nose, "Santa Claus! Yes by Voinov, I was with him at the Christmas party school slept. And flew. Jesus, what to do now that?"'

						act 'I have no idea':gt $curloc
					end
				else
					''
				end
			end

			act 'further':gt $curloc
		end

		if KatjaLust > 10:
			katkisrand = rand(0, 5)

			if katkisrand = 0:
				cls
				gs 'stat'
				'<center><b><font color="maroon"><<$npcName[14]>> <<$npcSurName[14]>></font></b></center>'
				'<center><img src="images/qwest/alter/npc/14.jpg"></center>'
				dynamic $d_katjahornykiss
			end
		end
	end

	if hour >= 20:
		'Katja says, he wants to go to the disco.'

		if money >= 25:act 'Go to the disco':money -= 25 & minut += 15 & gt 'gdkin'
	end
end

act 'Say goodbye and go home':gt 'gorodok'

--- KatjaHomeTalk ---------------------------------
