glife/locations/dinsexFX

# dinsexFX
!! penetration
!!horny - excitement
!!vagina - vagina elasticity
!!silavag - male skill:0-clumsy, 1-middle, 2-stud, 3-random
!!dick - his penis size
!!orgazm - what kind of orgasm

$vagstart = {
!condom check, to skip just use 2
	if prezik > 0:
		prezik -= 1
		protect = 1
		if preziktype = 2:
			sexcontra = 7
			'You give the guy a sabotaged condom and he puts it on in silence.'
		else
			sexcontra = 3
			'You give the guy a condom and he puts it on in silence.'
		end
	end
	dynamic $vagstart2
}

$vagstart2 = {
!need $boy, dick and silavag
	frost = 0

	horny += 10
	minut += 10
	if mesec > 0:
		!!Menstruation ruins the mood
		horny = 0
		manna -= 10
		willpower -= 10
		'Menstrual blood slowly flows from your vagina, somewhat ruining the mood.'
	end
}

$vagend = {
!!pose = 0:front, pose = 1:back, pose = 3:cum inside, silavag = sexskill
	if horny >= 80:
		if vagina = 0:
			horny = 0
			manna -= 15
			willpower -= 15
			vagina += 1
			'You bite your <<$liptalk>> in pain and tears flow down your face, <<$boy>> has torn your hymen with his <<dick>> centimeter dick. Your bloody pussy a reminder of your lost virginity.'
		elseif mesec > 0:
			horny -= 10
			'As enjoyable as the sex may be, you are too worried about your bleeding to fully relax and can not orgasm.'
		else
			!!No Menstruatsion
			prinat = vagina + (horny / 10)

			if dick >= prinat * 2:
				!!Painfully too big for PC
				orgazm = 0
			elseif dick > prinat:
				!!Big, but more bearable
				if silavag = 0:
					if horny >= 100:orgazm = 2
					if horny >= 90 and horny < 100:orgazm = 1
					if horny >= 80 and horny < 90:orgazm = 0
				elseif silavag = 1:
					if horny >= 90:orgazm = 2
					if horny >= 80 and horny < 90:orgazm = 1
				elseif silavag = 2:
					orgazm = 2
				end
			elseif dick <= prinat and dick >= vagina:
				!!Perfect size
				orgazm = 2
			elseif dick < vagina:
				!!On the small side
				if silavag = 0:
					if horny >= 100:orgazm = 2
					if horny < 100:orgazm = 3
				elseif silavag = 1:
					if horny >= 90:orgazm = 2
					if horny < 90:orgazm = 3
				elseif silavag = 2:
					orgazm = 2
				end
			end
		end

		if orgazm = 0:
			if vgape < 2:vgape = 2
			vgapetime = totminut
			horny -= 10
			manna -= 10
			willpower -= 10
			'You bite your lip in pain <<$boy>>s <<dick>> centimeter cock is too big and he has left you insides battered and bruised. You are moaning in pain and not pleasure. Your poor pussy.'
		elseif orgazm = 1:
			manna += 10
			willpower += 10
			'You are startled by how much your pussy has been stretching by <<$boy>>. It felt good when his <<dick>> centimeter dick was fucking your pussy. A pleasant warmth spread across your abdomen, but the strain of accomadating him denies you your release.'
		elseif orgazm = 2:
			horny = 0
			manna += 15
			willpower += 15
			orgasm += 1
			vaginalOrgasm += 1
			'Right from the pleasant feeling of your pussy stretching to fit his dick, it has felt so good having his <<dick>> centimeter dick fuck your pussy. The warmth that spread from your lower abdomen, has enveloped your entire body with hot, orgasmic waves. You scream with pleasure.'
		elseif orgazm = 3:
			horny += 5
			manna += 5
			willpower += 5
			'You felt from the momment his penis entered your pussy, that his <<dick>>cm dick is just too small for your pussy and his best efforts are not doing it for you. There is some please to be gained, but you never reach the heights of an orgasm.'
		end
	end

	if vagina < dick:vagina += 1

	sex += 1

	if protect < 2:
		!!Unprotected sex

		if rand(0, 1) = 0 or pose = 3:
			!!Inside
			gs 'cum_manage'
			'<<$boy>> groans and you feel a jet of sperm fill your pussy.'
			!std check
			dynamic $veneracheck
			if protect = 0:

				manna -= 15
				willpower -= 15

				if knowpreg = 0 and thinkpreg = 0:
					if tabletkishot ! 0: '"I''m glad I got my birth control shot." you think to yourself.'
					if tabletkishot = 0 and pillcon > 2000: '"Good thing I''m on the pill." you think to yourself.'
					if tabletkishot = 0 and pillcon <=2000:'"Damn! I could get pregnant!" you think in horror.'
				else
					'You chuckle to yourself, "Well at least I cannot get more pregnant."'
				end
			end
		else
			!!Out

			if pose = 0:
				spafinloc = 14
				gs 'cum_manage'
				'<<$boy>> groans and after pulling out his dick, he came on your stomach.'
			elseif pose = 1:
				spafinloc = 4
				gs 'cum_manage'
				'<<$boy>> groans and after pulling out his dick, he came on your ass.'
			end
		end
	else
		protect = 0
		'<<$boy>> groans and you realize that he came in the condom.'
		prezrand = rand(0, 100)

		if Sexcontra = 4:
			'Pulling out of you and looking at his dick, <<$boy>> said "Hmm, condom burst"'
			!std check
			dynamic $veneracheck
			Sexcontra = 0
		end
	end
	protect = 0
	sexcontra = 0

	pose = 0
}

$veneracheck = {
	if cheatHealth = 0:
		tipvenerarand = rand(1, 10)
		if tipvenerarand = 8:
			!!herpes

			if rand(1, 100) > 90:
				if GerpesOnce = 0:GerpesOnce = 1

				Venera += 1
				Gerpes += 1
			end
		elseif tipvenerarand = 7:
			!!syphilis

			if rand(1, 100) > 97:
				Venera += 1

				if SifacOnce = 0:SifacOnce = 1

				Sifilis += 1
			end
		elseif tipvenerarand >= 5 and tipvenerarand < 7:
			!!gonorrhea

			if rand(1, 100) > 90:
				Venera += 1

				if TriperOnce = 0:TriperOnce = 1

				Triper += 1
			end
		elseif tipvenerarand < 5:
			!!thrush

			if rand(1, 100) > 85:
				if KandidozOnce = 0:KandidozOnce = 1

				Kandidoz += 1
			end
		end
	end
}

--- dinsexFX ---------------------------------