glife/locations/gor_mirror

# gor_mirror
if $ARGS[0] = 'start':
	cla
	clr

	if player_avatar = 1:
		'<center><img src="avatar.jpg"></center>'
	else
		'<center><img src="<<FUNC(''$face_image'')>>"></center>'
		'<<$hair>> <<$mop>> <<$skin>> <<$vnesh>>'
	end

	if kosmetica > 0:'Cosmetics <<kosmetica>>'
	if kosmetica = 0:'You have no makeup.'

	if hapri = 0:
		act 'coiffured':
			cla
			minut += 3
			hapri = 1

			act 'View results':gt 'gor_mirror', 'start'
		end
	end

	if mop = 1 and kosmetica > 0:
		act 'Apply makeup':
			cla
			*clr
			'<center><img src="images/etogame/mop.jpg"></center>'

			act 'Light make-up':
				cla
				minut += 3
				kosmetica -= 1
				mop = 2
				'You legonechko summed eyes and lips a little tint.'

				act 'View results':gt 'gor_mirror', 'start'
			end

			if kosmetica >= 2:
				act 'normal makeup':
					cla
					minut += 5
					kosmetica -= 2
					mop = 3
					'You lipstick, summed up his eyes and eyelids.'

					act 'View results':gt 'gor_mirror', 'start'
				end
			end

			if kosmetica >= 3:
				act 'calling makeup':
					cla
					minut += 10
					kosmetica -= 3
					vidageday -= 1
					mop = 4
					'You heavily nakrasili eyes, eyelids and mascara, lip contour nakrasili pencil and lipstick.'

					act 'View results':gt 'gor_mirror', 'start'
				end
			end
		end
	end

	if lipbalm > 0 and lipbalmstat <= 0:
		act 'Smear lip balm moisturizing':
			cla
			minut += 10
			lipbalm -= 1
			lipbalmstat += 8
			lipkoef += rand(5, 15)

			if lipkoef > 50:
				lipkoef = 0
				lip += 1
			end

			'You smeared lip moisturizing balm.'

			act 'View results':gt 'gor_mirror', 'start'
		end
	end

	act 'Move away from the mirror':
		cla
		gt 'dom_gor'
	end
end

--- gor_mirror ---------------------------------