# cikl
!!moving the porn schedule ahead a day, flaffing for missed shootings, if it even matters
if (film > 0 or pornstack = 1) and pfilmNO = 0 and pfilmSTOP = 0:
	if pfilmday[0] > 0:gs 'pornschedule', 'pornmiss'
	gs 'pornschedule', 'schedule'
end

day += 1
week += 1
hour -= 24
gs 'daystart'
dynamic $hypnoDaychange

!!Party refresh if you didn''t see sis
if sisboyparty_day + 1 > daystart and sisboyparty = -1: sisboyparty = 1

!!phone reset for bf
ringA = 0
ringB = 0
ringC = 0

if BuyHous = 2 and ArendHouseSL <= 0:ArendHouseSL = 0 & BuyHous = 0 & housr = 0
if BuyHous = 2 and ArendHouseSL > 0:ArendHouseSL -= 1

vidageday -= 1
if workDolgDay > 0:workDolgDay -= 1
if QWdogreiqTimer > 0:QWdogreiqTimer -= 1
if husband > 0:husbanday += 1
if husband > 10 and husbanday > 0:husband -= 15
if fingal > 0:fingal -= 1

if husbandMark = 1 and husband <= 10:
	husbizvradd = 0
	husbharmin = 0
	husbandMark = 0
	husband = 0
	divorced += 1

	if KFOnLineReaga > 0:KFOnLineReaga -= 1

	'<b><font color="red">Your husband has filed for a divorce.</font></b>'
end

if year_start ! year and katjaPreg = 0 and month >= 2:katjaPreg = 1

!Clothing stock and price randomizers
Clothingstock = rand (0,23)
i = 1
:loopprice
Clothingstock[i] = rand (0,500)
i += 1
if i <= 147:jump 'loopprice'

if coatH[defaultcoat] <= 0: defaultcoat = 0

!!SECTION: Bimbo (daily status update checks)
!!A Succubus cannot be a Bimbo
if succubusflag = 1 and bimbo > 0: bimbo -= succublvl * 2

!!Once bimbolevel is set to 1, must use the withdrawal in stat to return to 0
if bimbo > 0 or bimbolevel > 0:
    if bimbo < 10:
        bimbo -= 1
    elseif bimbo < 20:
    	bimbolevel = 1
    elseif bimbo < 30:
    	bimbolevel = 2
    else
        bimbolevel = 3
    end
end

if bimbo >= 40: bimbo = 40

!!Bimbo levels. They use custom variables so they wont permanently change character stats
if bimbolevel = 0: supnatvnesh = 0 & bimbostupidity = 0
if bimbolevel = 1: supnatvnesh = 2 & bimbostupidity = (intel / 6)
if bimbolevel = 2: supnatvnesh = 4 & bimbostupidity = (intel / 4)
if bimbolevel = 3: supnatvnesh = 8 & bimbostupidity = (intel / 3)

if bimbocl = 1 and succubusflag = 0:
	bimbocl = 0
	bimbo += 2
else
	bimbocl = 0
end

!Succubus Level & hunger calcs 
if succubusflag = 1:
	cheatHealth = 1
		dynamic $cheatmenu['std_cure']

!!	A Succubus cannot be a Bimbo
	if bimbolevel > 0 and bimbo <= 0: bimbowithdrawal = 40

!!	Hunger handling
	if sucxpsnapshot >= succubxp: succhungry += 1
	sucxpsnapshot = succubxp
	if succubxp < 0: succubxp = 0
	if succubxp < 60:
		succublvl = 1
		$sucself1 = 'that feeling'
		sucstorecap = 0
		if bimbolevel <= 0: supnatvnesh = 1
	elseif succubxp < 150:
		succublvl = 2
		$sucself1 = 'the power'
		sucstorecap = 0
		if bimbolevel <= 0: supnatvnesh = 3
	elseif succubxp < 270:
		succublvl = 3
		$sucself1 = 'your other self'
		sucstorecap = 100
		if bimbolevel <= 0: supnatvnesh = 6
	else
		succublvl = 4
		$sucself1 = 'your true self'
		sucstorecap = 200
		if bimbolevel <= 0: supnatvnesh = 10
	end
	if sucskill >= 2 and succublvl >= 2: sucstorecap += 100
	if sucskill >= 3 and succublvl >= 2: sucstorecap += (sucstorecap * 2) / 10
	if mutagenP < (succublvl - 1): mutagenP = (succublvl - 1)
	if mutagenS < (succublvl - 1): mutagenS = (succublvl - 1)
	if mutagenA < (succublvl - 1): mutagenA = (succublvl - 1)
	if mutagenR < (succublvl - 1): mutagenR = (succublvl - 1)
	if mutagenV < (succublvl - 1): mutagenV = (succublvl - 1)
	if mutagenW < (succublvl - 1): mutagenW = (succublvl - 1)
	if mutagenI < (succublvl - 1): mutagenI = (succublvl - 1)
	if (sucexcess >= 100 and (sucskill < 2 or succhungry > -2)) or (sucexcess >= 100 + sucstorecap and sucskill >= 2):
		if stren < 250: stren += 1 & sucexcess -= 12
		if speed < 250: speed += 1 & sucexcess -= 12
		if agil < 250: agil += 1 & sucexcess -= 12
		if react < 250: react += 1 & sucexcess -= 12
		if vital < 250: vital += 1 & sucexcess -= 12
		if will < 250: will += 1 & sucexcess -= 12
		if intel < 250: intel += 1 & sucexcess -= 12
		if succhungry > (0 - 2 - succublvl): succhungry -= 1 & sucexcess -= 10
		if skinvan < 100: skinvan += 1 & sucexcess -= 2
!!		This is to drive the Succubus vidage into the max appearance range
		if vidageday < 720 and vidage >= 28: vidageday += 2 & sucexcess -= 2
		if vidageday > 0 and vidage <= 20: vidageday -= 2 & sucexcess -= 2
		if vidageday >= 720 and vidage > 28:
			vidageday -= 360
			vidage -= 1
		end
		if sucexcess > sucstorecap: sucexcess = sucstorecap
	elseif sucexcess < 0 and succhungry < 0:
		succhungry += 1
		if (0 - sucexcess) < (10 * succublvl):
			sucexcess = 0
		else
			sucexcess += (10 * succublvl)
		end
	end
	if sucexcess < 0: sucpowzeroed += 1
	if sucexcess >= 0 and sucpowzeroed > 0: sucpowzeroed -= 1
	
!!	This is so a Succubus always moves toward a default vaginal and anal size when she has the accomadation ability
	if sucskill >= 4:
		if vagina - 2 >= 13:
			vagina -= 2
		elseif vagina + 2 <= 13:
			vagina += 2
		end
		if anus - 2 >= 8:
			anus -= 2
		elseif anus + 2 <= 8:
			anus += 2
		end
	end
end

!!Bimbo second half, after Succubus so changes there can be reflected here if still bimbo and Succubus
!!Checks how often sex has occured in the last 24 hours and for drops in bimbo score, for calculating withdrawal
if bimbolevel >= 1:
	bimbo += ((stat['vaginal'] + stat['bj'] + stat['anal']) - snapshotX) - 3
	if bimbo <= snapshotY:
		bimbowithdrawal = 0
	else
		bimbowithdrawal += 1
	end
end

if bimbo < 0: bimbo = 0
snapshotX = (stat['vaginal'] + stat['bj'] + stat['anal'])
snapshotY = bimbo

!!***************

if curly > 0:curly -= 1

! WD: Added daily reduction of braids for Maruda Hair Mod
if hbraids > 0:hbraids -= 1


sweat += 2

if tan > 0:tan -= 1

if prezikmsg = 2: prezikmsg = 3

if tabletkishot <= 0: pillcon -= 1000
if pillcon < 0:	pillcon = 0

if tabletkicheck = 2:
	if tabletkishot ! 0:
		cycle = 1
		mesec = 0
		if rand(0,1000) = 1000:
			EggRH = rand(20,80)
		else
			EggRH = 0
		end
		FocH = EggRH
	end
	if tabletkishot <= 0:
		pillcon -= 29000
		if tabletkishot < 0: tabletkishot = 0
	end
	if shotdays = -8:
		tabletkicheck = 0
		shotdue = 0
		'Your birth control shot is no longer protecting you.'
	elseif shotdays <= 0:
		if shotdays = 0: 
			shotdue = 7
		else
			shotdue -= 1
		end
		'The chemicals regulating your fertility cycle are wearing off, you need to get your shot in <<shotdue>> days.'
	elseif shotdays > 1 and shotdays < 5:
		'You are due for a birth control shot soon if you do not get one, you might get pregnant.'
	elseif shotdays = 1:
		'Your birth control shot is due for renewal tomorrow.'
	end

	if tabletkishot > 0:tabletkishot -= 1
end

tabletkipd += tabletkipi
tabletkipi = 0
tabletkipt = 0
if tabletkicheck = 1:
	if tabletki <= 0:
		tabletkicheck = 0
		'You are out of birth control pills.'
		tabletkipi = -5
	elseif tabletki < 5:
		'You are running out of birth control pills, you only have a few left.'
	end
end

if tabletkicheck = 1 and tabletkichday < daystart:
	tabletkichday = daystart
	tabletkimm = (100*(willpower / willpowermax)) + (100*(manna / mannamax))
	if son < 10:
		tabletkimm -= (100- (son * 10))
	end
	if willpower < willpowermax / 4:
		tabletkimm = tabletkimm / 4
	elseif manna < mannamax / 10:
		tabletkimm = tabletkimm / 2
	end
	tabletkiap = tabletkimm
	tabletkiap += (intel*4)+(will*2)+(age*3)
	tabletkiap -= ((kid*30)+(abort*2)-(tabletkipd*((60-age)/10)))
	temprand = rand(0,(200+(tabletkimm-((100-will)*3))))
	if temprand = 0:
		tabletkioddp = 1
	end
	tabletkiap += temprand
	if tabletkiap < 300:
		if tabletkipd > -10:
			if willpower < willpowermax / 4:
				'You stare at your bottle of birth control pills, you know you should take one but you can''t quite work up enough effort to care.'
			elseif manna < mannamax / 10:
				'You stare at your bottle of birth control pills, but you don''t open it.'
			elseif son < 10:
				'You fumble with the cap on your birth control pills, trying to get it open. You finally give up too tired to manage it.'
			else
				'You just realized you forgot to take your birth control pill today.'
			end
		end
		tabletkipt = 2
		tabletkipi = -4
	else
		if tabletkiap < 350:
			temprand = rand(0,5)
		else
			temprand = rand(0,1000)
		end
		if temprand = 0:
			temprand = rand(0,1)
			if temprand = 0:
				tabletki -= 1
				skinvan += 1
				tabletkipt = -2
				tabletkipi = 1
			else
				tabletkipt = 3
				tabletkipi = -3
			end
			if tabletkipd > -10:
				'You find yourself holding the bottle of birth control pills, you cannot remember if you took one or not.'
			end
			if tabletkipd > 0:
				if rand(0,9) = 0:
					if tabletkipt < 0:
						'You don''t think you have taken your pill today.'
					else
						'You think you have taken your pill today.'
					end
				else
					if tabletkipt > 0:
						'You don''t think you have taken your pill today.'
					else
						'You think you have taken your pill today.'
					end
				end
			end
		else
			'You take your birth control pill for the day.'
			tabletki -= 1
			skinvan += 1
			if tabletkioddp = 0:
				pillcon += ((pillcon+15000)/40)+1000
				if pillcon > 40000: pillcon = 40000
			else
				if vitaminday ! daystart:
					vitaminday = daystart
					skinvan += 1
				end
			end
			tabletkiday = daystart
			tabletkipt = 0
			tabletkipi = 0
		end
	end		
end

if lashair ! 1:
	leghair += 1
	lobok += 1
end

if suhbelo > 0:suhbelo2 = suhbelo & suhbelo = 0

if fbreath = 1:fbreath = 0

if cheatNoEat = 1 and dounspell = 1:fat += 15

manna -= 10

if beg >= 2000:
	beg -= 4
elseif beg >= 1500:
	beg -= 3
elseif beg >= 1000:
	beg -= 2
elseif beg >= 100:
	beg -= 1
end

!STD check
if SifacOnce = 1:Sifilis += 1
if GerpesOnce = 1:Gerpes += 1
if TriperOnce = 1:Triper += 1
if KandidozOnce = 1:Kandidoz += 1

VeneraN = 0

if VeneraOnce > 0:VeneraOnce = 0
if SifacOnce = 1:VeneraN += 1
if GerpesOnce = 1:VeneraN += 1
if TriperOnce = 1:VeneraN += 1

Venera = VeneraN

!Appearance age
if vidageday <= 0:
	vidageday = 360
	vidage += 1
end

if anus > 1 and ashrink > 0 and analplugIN = 0:
	if anusK < 0:anusK = 0
	if anusK < ashrinkdays:anusK += 1
	if anusK >= ashrinkdays:anus -= ashrink & anusK = 0
	if anus < 0: anus = 0
end
if vagina > 10 and vshrink > 0:
	if vaginaK < 0:vaginaK = 0
	if vaginaK < vshrinkdays:vaginaK += 1
	if vaginaK >= vshrinkdays:vaginaK = 0 & vagina -= vshrink
end

lipkoef -= 1
!!!!!!!!!!!!
!!!jobs!!!
!!!!!!!!!!!!
if Enable_autotampon = 0 and isprok = 1:isprok = 0 & 'You threw away your used tampon.'
if Enable_autotampon = 0 and isprokp = 1:isprokp = 0 & 'You threw away your used sanitary pad.'

if preg = 1 and pregtime < 280:
	pregtime += 1

	if pregtimes = 0:pregtimes = 1
elseif preg = 1 and pregtime = 280 and hourpreg ! hour:
	hourpreg = hour
	'<center><b>A sharp pain runs through your stomach, and something flows down your legs. Snap, your water broke! You have to get to the clinic fast!</b></center>'
elseif preg = 1 and pregtime > 280:
	cla
	*clr
	over = 4
	'<center><b>A horrible pain shoots through your body.</b></center>'
	xgt 'gameover'
	exit
end

if StoryLine = 0 or altQS = 1:
	if horny < 100:horny += vagina
else
	if vagina = 0:
		razeba = 0

		if horny > 0 and horny <= 50:horny -= 10
		if horny > 50:horny -= 25
	elseif vagina > 0:
		if pregtimes = 0:
			if age < 18:
				razeba = 1

				if horny > 0 and horny <= 50:horny -= 5
				if horny > 50 and horny < 80:horny -= 10
				if horny >= 80:horny -= 20
			elseif age >= 18 and age < 21:
				razeba = 2

				if horny > 0 and horny <= 50:horny -= 1
				if horny > 50 and horny < 80:horny -= 5
				if horny >= 80:horny -= 10
			elseif age >= 21 and age < 25:
				razeba = 3

				if horny > 0 and horny <= 50:horny += 1
				if horny > 50 and horny < 80:horny -= 1
				if horny >= 80:horny -= 5
			elseif age >= 25 and age < 30:
				razeba = 4

				if horny > 0 and horny <= 50:horny += 5
				if horny > 50 and horny < 80:horny += 1
				if horny >= 80:horny -= 5
			elseif age >= 30:
				razeba = 5

				if horny > 0 and horny <= 50:horny += 10
				if horny > 50 and horny < 80:horny += 5
				if horny >= 80:horny += 1
			end
		elseif pregtimes > 0:
			if preg = 0:
				razeba = 5

				if horny > 0 and horny <= 50:horny += 10
				if horny > 50 and horny < 80:horny += 5
				if horny >= 80:horny += 1
			elseif preg > 0:
				razeba = 6

				if horny < 100:horny += pregtime / 10
			end
		end
	end
end

if horny < 0:horny = 0

!counter for Dimka avoidance
if dimaFilm = 1 and dimaRudeBlock = 0:
	nodimkaK += 1
	DimkaWarnedToday = 0
end

!!! Maruda Hair Mod
!!! Max. Hair length 600mm, or 60cm, which should be somewhere in the lower back area.
!!! Hair grows 1mm each day, it takes 20 months (1 month = 30 days) to regrow the hair from 0.
if hairlength < 601:hairlength += 1

if hcol ! nathcol: 
	dyefade -=1
	if dyefade < 0: dyefade = 0
	if dyefade > 0 and dyefade < 7: dyevmod = 5
	if dyefade = 0: dyevmod = 15
end
	
if hscrunch > 0:
	hscrunchrand = rand(1, 100)

	if hscrunchrand <= 8:hscrunch -= 1
end
!!! Maruda Hair Mod

gs 'starenie'

if nark > 60:
	nark = 60
elseif nark > 30:
	nark -= 3
elseif nark > 0:
	nark -= 1
end

if pregtime > 10:fat += 1

if pain['head'] > 0:pain['head'] -= rand(1,3)
if pain['hair'] > 0:pain['hair'] -= rand(1,3)
if pain['ears'] > 0:pain['ears'] -= rand(1,3)
if pain['eyebrows'] > 0:pain['eyebrows'] -= rand(1,3)
if pain['eyes'] > 0:pain['eyes'] -= rand(1,3)
if pain['cheeks'] > 0:pain['cheeks'] -= rand(1,3)
if pain['nose'] > 0:pain['nose'] -= rand(1,3)
if pain['mouth'] > 0:pain['mouth'] -= rand(1,3)
if pain['lips'] > 0:pain['lips'] -= rand(1,3)
if pain['tongue'] > 0:pain['tongue'] -= rand(1,3)
if pain['throat'] > 0:pain['throat'] -= rand(1,3)
if pain['neck'] > 0:pain['neck'] -= rand(1,3)
if pain['back'] > 0:pain['back'] -= rand(1,3)
if pain['asscheeks'] > 0:pain['asscheeks'] -= rand(1,3)
if pain['asshole'] > 0:pain['asshole'] -= rand(1,3)
if pain['hips'] > 0:pain['hips'] -= rand(1,3)
if pain['thighs'] > 0:pain['thighs'] -= rand(1,3)
if pain['legL'] > 0:pain['legL'] -= rand(1,3)
if pain['legR'] > 0:pain['legR'] -= rand(1,3)
if pain['feet'] > 0:pain['feet'] -= rand(1,3)
if pain['toes'] > 0:pain['toes'] -= rand(1,3)
if pain['shoulders'] > 0:pain['shoulders'] -= rand(1,3)
if pain['armL'] > 0:pain['armL'] -= rand(1,3)
if pain['armR'] > 0:pain['armR'] -= rand(1,3)
if pain['hands'] > 0:pain['hands'] -= rand(1,3)
if pain['fingers'] > 0:pain['fingers'] -= rand(1,3)
if pain['chest'] > 0:pain['chest'] -= rand(1,3)
if pain['breasts'] > 0:pain['breasts'] -= rand(1,3)
if pain['nipples'] > 0:pain['nipples'] -= rand(1,3)
if pain['ribs'] > 0:pain['ribs'] -= rand(1,3)
if pain['tummy'] > 0:pain['tummy'] -= rand(1,3)
if pain['pubic'] > 0:pain['pubic'] -= rand(1,3)
if pain['vaginal'] > 0:pain['vaginal'] -= rand(1,3)
if pain['clitoris'] > 0:pain['clitoris'] -= rand(1,3)
if pain['urethra'] > 0:pain['urethra'] -= rand(1,3)
if pain['cervix'] > 0:pain['cervix'] -= rand(1,3)

if painpub = 2:
	if painpubday + 5 < daystart:
		$painpub = 'Your vulva is painfully sore.'
		painpub = 1
		painpubday = daystart
	elseif painpubday + 5 >= daystart:
		$painpub = 'Your vulva is painfully sore.'
	end
elseif painpub = 1:
	if painpubday + 5 < daystart:
		$painpub = ''
		painpub = 0
		painpubday = daystart
	elseif painpubday + 5 >= daystart:
		$painpub = 'Your vulva is a little sore.'
	end
end

prezikProver += 1
if pirs_pain_ton > 0:pirs_pain_ton -= 1
if brow > 0 and browper = 0:brow -= 1
if shorthair = 1:
	shorthairday += 1
	if shorthairday >= 45:shorthairday = 0 & shorthair = 0
end

if KatjaOTN > 0:
	if KatjaHorny > 0 and KatjaLust < 40:KatjaHorny -= rand(1, 3)
	if KatjaLust >= 40:KatjaHorny += rand(1, 3)
	if KatjaHorny < 0:KatjaHorny = 0
	if KatjaHorny >= 100:KatjaHorny = 0 & KatjaMastr += 1 & KatjaLust += 1
end

if trenerepa > 20:trenerepa -= 1

!!!!!!!!!!!!!!!
!!!generation!!!
!!!!!!!!!!!!!!!
if NPCnum < 290:
	NPCnow = NPCnum
	NPCnum += rand(1, 3)
	gs 'npc'
elseif NPCnum < 300:
	NPCnow = NPCnum
	NPCnum += 1
	gs 'npc'
end

!!!!!!!!!!!!!!!
if kanikuli = 0:Suspeh -= 1
dmishaevent = 0

if Gspravka <= 0 and GspravkaT = 1:GspravkaT = 0 & Gspravka = 0
if GspravkaT = 1:Gspravka -= 1
if IvanPodstavaQW = 2 and PodpiskaNeviezd = 30:IvanPodstavaQW = 3
if IvanPodstavaQW = 2 and PodpiskaNeviezd > 0 and PodpiskaNeviezd < 30:PodpiskaNeviezd += 1

If dounspell = 1:
	if strenbuf > 90:
		strenbuf -= 2
	elseif strenbuf > 80:
		strenbuf -= 1
	end

	if vitalbuf > 90:
		vitalbuf -= 2
	elseif vitalbuf > 80:
		vitalbuf -= 1
	end

	if strenbuf > stren:strenbuf -= 1
	if strenbuf < stren:strenbuf += 1
	if vitalbuf > vital:vitalbuf -= 1
	if vitalbuf < vital:vitalbuf += 1
	if agilbuf > agil:agilbuf -= 1
	if agilbuf < agil:agilbuf += 1
else
	gs 'body_shape'
end


if husband > 0 and husbandrink ! 11:husbandrink = rand(0, 10)

inWorkYoungShop = 0
husbandsexday = 0
borsexkol = 0
givisexday = 0

if shantsr > 0:
	pay = shantsr * 5000
	karta += pay
	shantsr = 0
end

if shantbog > 0:
	:shantftb
	shantftbgrand = rand(0, 10)
	if shantftbgrand > 2:
		shantpopala += 1
		shantbog -= 1
		if shantbog > 0:jump 'shantftb'
	elseif shantftbgrand <= 2:
		karta += 30000
		shantbog -= 1
		if shantbog > 0:jump 'shantftb'
	end
end

petersexday = 0
klismaday1 = 0

!!MJ: Add some (daily) interest to the bank account. 
!!Not very realistic but wont make anyone too rich.

if bankAccount = 1:
	if karta >= 2000000:
		!! yearly interest of 2.3% recalculated into daily interest = 0.006% daily
		smallmoneypos += (karta * 60)
	elseif karta >= 0:
		!! yearly interest of ... recalculated into daily interest = 0.003% daily
		smallmoneypos += (karta * 30)
	else
		!! yearly overdraft interest of 20% recalculated into daily interest = 0.055% daily
		smallmoneypos -= (karta * 550)
	end

	if smallmoneypos >= 1000000 or smallmoneypos <= -1000000:
		karta += smallmoneypos / 1000000
		smallmoneypos = smallmoneypos mod 1000000
	end

	if atmDeposit > 0 and atmDepositDate <= daystart:
		karta += atmDeposit
		atmDeposit = 0
	end
end
   
!!payments
if day = 25:
	if PersSecWork = 1 and PersSecWorkTimes > 0 and paydaybistrosec = 0:
		Pay = PersSecWorkTimes * 2500
		PersSecWorkTimes = 0
		karta += Pay
		paydaybistrosec = 1
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your job as a secretary.</font></b>'
	end

	if workKafe = 1 and paydayKafe = 0:
		paydayKafe = 1
		pay = smenaKafe * 600
		karta += pay
		smenaKafe = 0
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your job as a waitress in a cafe.</font></b>'
	end

	if workhosp = 1 and nopaypoly = 0:
		pay = smena * 1000
		karta += pay
		smena = 0
		nopaypoly = 1
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your work in the clinic.</font></b>'
	end

	if worksalon = 1 and nopaysalon = 0:
		pay = smena * 800
		karta += pay
		smena = 0
		nopaysalon = 1
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your work in a beauty salon.</font></b>'
	end

	if tanwork = 1 and nopaytanwork = 0:
		nopaytanwork = 1
		karta += 25000
		'<b><font color="green">Your salary of 25,000 <b>₽</b> has been paid into your bank account for your work as a house maid.</font></b>'
	end

	if workSec = 1 and paydaySec = 0:
		paydaySec = 1
		pay = sekDay * 800

		if officebestslut >= 3:pay += 20000
		karta += pay
		sekDay = 0
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your job as a secretary.</font></b>'
	end

	if workFabrika = 1:
		pay = smenaFabrika * 400
		smenaFabrika = 0
		karta += pay
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your job at the garment factory.</font></b>'
	end	

	if husband > 0 and paydayHusb = 0:
		paydayHusb = 1

		if husbFin = 0:huspay = 15000
		if husbFin = 1:huspay = 25000
		if husbFin = 2:huspay = 40000

		karta += huspay
		'<b><font color="green">Your husband has paid <<huspay>> <b>₽</b> into your bank account.</font></b>'
	end

	if stipuha = 1 and stipuhaday = 0:stipuhaday = 1 & karta += 1200 & '<b><font color="green">You have received 1,200 <b>₽</b> scholarship.</font></b>'
	if housr = 1 and haday = 0:haday = 1 & money -= 3000 & '<b><font color="red">You paid 3,000 <b>₽</b> for your apartment.</font></b>'

	if housr = 1 and electroday = 0:
		electroday = 1
		if elektro >= 800:elektro = 800 + rand(0, 100)

		money -= elektro
		'<b><font color="red">You paid <<elektro>> for electricity.</font></b>'
	end

	if housr = 1 and kabel > 0 and kabelday = 0:kabelday = 1 & money -= 300 & '<b><font color="red">You have paid 300 <b>₽</b> for cable TV.</font></b>'
end

if day ! 25:
	if paydayHusb = 1:paydayHusb = 0
	if workKafe = 1 and paydayKafe = 1:paydayKafe = 0
	if workSec = 1 and paydaySec = 1:paydaySec = 0
	if housr = 1 and haday = 1:haday = 0
	if housr = 1 and electroday = 1:electroday = 0
	if housr = 1 and kabel > 0 and kabelday = 1:kabelday = 0
	if stipuhaday = 1:stipuhaday = 0
	if nopaytanwork = 1:nopaytanwork = 0
	if nopaypoly = 1:nopaypoly = 0
	if nopaysalon = 1:nopaysalon = 0
	if paydaybistrosec = 1:paydaybistrosec = 0
end

if sdaday = day and sdamonth = month and housr = 0:
	housr = 1
	'<b><font color="red">Your tenants have moved out and your apartment is now vacant.</font></b>'
	!msg 'Your tenants have moved out and your apartment is now vacant.'
end



if day > monthsEnd[month]:
	day -= monthsEnd[month]
	month += 1
	
	if month > 12: month = 1 & year += 1
	
	!MJ: Dont think that one is needed. But it was in the original loop.
	if month < 1: month = 1
	
	$month = $monthName[month]
end

!MJ: Dont think that one is needed. But it was here already.
if day <= 0:day = 1

if week > 7:
	:loopweek
	week -= 7
	husbandrink = 0

	if military = 1:military = 0

	if week > 7:jump 'loopweek'
end

gs 'outdoors', 'weather'

if storyline = 1 and SchoolAtestat = 0:
	$holyday = ''
	$backtoschool = '<b>, back to school tomorrow.</b>'
	kanikuli = 0

	!holiday countdown (kanicont) by illume. countdown in [cikl], summer vacation pre-set in [startalt]
	if (month = 10 and day >= 27) or (month = 11 and day <= 4):
		if month = 11:
			kanicont = 5 - day
		else
			kanicont = monthsEnd[10] - day + 1 + 4
		end
		if month = 10 and day = 27:kanicont = 9
		$holyday = '<b>Autumn holidays</b>'
		kanikuli = 1
		if month = 11 and day = 4:$holyday += $backtoschool
	elseif (month = 12 and day >= 29) or (month = 1 and day <= 13):
		if month = 1:
			kanicont = 14 - day
		else
			kanicont = monthsEnd[12] - day + 1 + 13
		end
		$holyday = '<b>Winter Break</b>'
		kanikuli = 2
		if month = 1 and day = 13:$holyday += $backtoschool
	elseif (month = 3 and day >= 25):
		if kanicount = 0:kanicont = monthsEnd[3] - day + 1
		$holyday = '<b>Spring Break</b>'
		kanikuli = 3
		if month = 3 and day = 31:$holyday += $backtoschool
	elseif (month = 5 and day >= 25) or month = 6 or month = 7 or month = 8:
		if month = 5 and day = 25 and age = 17:
			$holyday = '<b>Your graduation is today. Be there by 8h.</b>'
			kanikuli = 6
		else
			if month = 8:
				kanicont = monthsEnd[8] - day + 1
			elseif month = 7:
				kanicont = monthsEnd[7] - day + 1 + monthsEnd[8]   
			elseif month = 6:
				kanicont = monthsEnd[6] - day + 1 + monthsEnd[7] + monthsEnd[8]
			else
				kanicont = monthsEnd[5] - day + 1 + monthsEnd[6] + monthsEnd[7] + monthsEnd[8]
			end
			$holyday = '<b>Summer holidays</b>'
			kanikuli = 4
			if month = 8 and day = 31:$holyday += $backtoschool
		end
	elseif month = 1 and day = 1:
		$holyday = '<b>New Year!</b>'
		kanikuli = 5
	else
		kanicount = 0
		!cleanup if not holidays.
	end

	if kanikuli > 0 and kanikuli < 5:$holyday += ', <<kanicont>> days left.</b>'
end

if birthday = day and birthmonth = month:
	!!birthday
	age += 1
end

if bcream_used >= 1:
    bcream_used = 0
    temp = rand(0,5)
    nbsize += temp
    if temp > 0:'Feels like your breasts have grown slightly.'
end
if steroid_dose >= 1:
    if lashair < 1:
        lobok += steroid_dose 
        leghair += steroid_dose 
    end
    steroid_dose = 0
end
if aphrodisiac_overdose = 1:aphrodisiac_overdose = 0
if aphrodisiac_timer ! 0:aphrodisiac_timer  = 0

if mentats_dose = 1:
    mentats_dose = 0
elseif mentats_dose > 1:
    pain['head'] += 20 * mentats_dose
    mentats_dose = 0
end
if breastpumped = 0 and breastcount > 0: breastcount -= 1
if breastpumped = 1:breastpumped = 0

!!Appearance base calculation call
gs 'body_shape', 'basebeautycalc'

--- cikl ---------------------------------

