# vokzalholle

if $ARGS[0] = '':
	$metka = $ARGS[0]
	$loc = $CURLOC
	$location_type = 'public_indoors'
	CLOSE ALL
	if sound = 0:PLAY 'sound/vokzal.mp3',30
	cls
	gs'stat'
	'<center><img src="images/locations/shared/train/vokzalholle.jpg" ></center>'
	'Go to the <a href="exec:GT ''vokzalper''">platforms</a>'
	act 'Leave the station building':gt 'vokzal' & minut+=5
	act 'Got to the ticket office': gt 'vokzalholle', 'ticket'
	act 'Go to the restrooms':gt 'vokzaltoilet' & minut+=5
end

if $ARGS[0] = 'ticket':
	cls
!! This is a lie, but a useful one don''t change the $loc and $metka
	$loc = 'vokzalholle'
	$metka = 'cottages'
	gs 'stat'
	'<center><h4>Ticket office</h4></center>'
	'<center><img src="images/locations/shared/train/kassa.jpg"></center>'

	if money >= 50:
		act 'Buy a ticket to the city center (50 <b>₽</b>)':
			$loc = 'cityTrain'
			$metka = 'inside'
			cls
			money -= 50
			minut += 5
			gs 'stat'
			'<center><img src="images/locations/shared/train/electri.jpg"></center>'
			'You pay for the ticket and board the next train going to the city center.'
			'After 5 minutes, you see the office blocks and shops at the heart of the city. The train stops at its final destination, the busy station in the city center.'

			act 'Get off the train at this station':
				if train_event = 0 and rand(1, 100) <= 5: gt 'train_incidental', 'end'
				gt 'cityTrain', 'inside'
			end
		end
	end

	if money >= 50:
		act 'Buy a ticket to the old platform by the communal cottages (50 <b>₽</b>)':
			train_event = 0
			money -= 100
			train_dir = 2
			train_dest = 3
			gt 'vokzalholle', 'cottages'
		end
	end

	if money >= 75:
		act 'Buy a ticket to the village of Gadyukino (75 <b>₽</b>)':
			train_event = 0
			money -= 75
			train_dir = 2
			train_dest = 4
			gt 'vokzalholle', 'cottages'
		end
	end

	if money >= 100:
		act 'Buy a ticket to the old town (100 <b>₽</b>)':
			train_event = 0
			money -= 100
			train_dir = 2
			train_dest = 5
			gt 'vokzalholle', 'cottages'
		end
	end

	if money >= 125:
		act 'Buy a ticket to Pavlovsk (125 <b>₽</b>)':
			train_event = 0
			money -= 125
			train_dir = 2
			train_dest = 6
			if rand(1, 100) < 15: gt 'train', 'private'
			gt 'vokzalholle', 'cottages'
		end
	end
end

if $ARGS[0] = 'cottages':
	cls
	minut += 10
	gs'stat'
	'<center><img src="images/locations/shared/train/electri.jpg" ></center>'
	'After 10 minutes the train stops at a small station. It''s abandoned, and there is not much activity outside.'
	act 'Get off the train at this station':
		$loc = 'train'
		$metka = 'old_platform'
		if train_event = 0 and rand(1, 100) <= 5: gt 'train_incidental', 'end'
		gt 'train', 'old_platform'
	end
	if train_dest > 3:
		act 'Continue your journey':
			gt 'train', 'communalS'
		end
	end
end

--- vokzalholle ---------------------------------

