# dachain
clr
$location_type = 'private'
$loc = 'dachain'
$locm = 'dachain'
gs 'stat'
fcolor = rgb(0, 0, 0)
bcolor = rgb(255, 255, 255)
lcolor = rgb(106, 90, 205)

if $args[0] = '':
	$metka = ''
	$metkaM = ''
	cls
	clr
	gs 'stat'
	'<center><b><font color="maroon">Cottage</font></b></center>'
	if dachaest = 2:
		'<center><img src="images/etogame/dacharoom2.jpg"></center>'
	else
		'<center><img src="images/etogame/dacharoom1.jpg"></center>'
	end
	'Your favorite summer residence.'
	''
	'There is a <a href="exec:gt ''bed'', ''start''">bed</a> against one wall. Next to it is a wardrobe(where you can <a href="exec:gt ''clothing'', ''view_clothing_list'', ''wardrobe''">organize your clothes</a> or <a href="exec:gt ''clothing_QV'', ''list''">pick something to wear</a>). You have a <a href="exec:gt ''clothing'', ''view_clothing_list'', ''store''">chest</a> at the end of your bed where you can store some clothes. On the other side of the bed is a table and a <a href="exec:gt ''mirror'', ''start''">mirror</a>'
	''
	'There is a sofa in front of the fireplace, a kitchen alcove oppsite the bed, the door to the bathroom next to it and beside the entrance is the <a href="exec:gt ''cloakroom'', ''view_coat_list''">coat closet</a>.'
	''
	if hour >= 6 and hour <= 20 and etoexhib = 11:'Kopashatsya working in the garden, hmm ... maybe sometime <a href="exec:gt ''etoexhib'', ''pos10''">motivate</a> for them to work quicker and smarter.'
	if hour >= 6 and hour <= 20 and etoexhib = 12:'Leave in <a href="exec:gt ''etoexhib'', ''pos11''">garden in lingerie and robe.</a>'
	if hour >= 6 and hour <= 20 and etoexhib = 13 and temp ! daystart:'I wonder how to <a href="exec:gt ''etoexhib'', ''pos12''">garden</a>'
	
	act 'Lie on the couch': gt 'divan', 'start'
	act 'Goto the kitchen alcove': gt 'dachain', 'dachakit'
	act 'Goto the Bathroom':  gt 'dachain', 'dachavann'
	act 'Get in the bed': gt 'bed', 'start'
	act 'Go outside': gt 'dachamy'
end

if $args[0] = 'dachakit':
	$metka = 'dachakit'
	$metkaM = 'dachakit'
	cls
	clr
	gs 'stat'
	'<center><b><font color="maroon">Cottage Kitchen</font></b></center>'
	if dachaest = 2:
		'<center><img src="images/etogame/dachakit2.jpg"></center>'
	else
		'<center><img src="images/etogame/dachakit1.jpg"></center>'
	end
	if cltarelka > 0:
		'<b><<cltarelka>></b> clean plates are stored in the cupboard.'
	else
		'<b><font color="red">You have no clean dishes left.</font></b>'
	end

	if dirttarelka > 0:'<b><<dirttarelka>></b> dirty dishes are lying in the sink. <a href="exec:dynamic $dirtarm">Wash the dishes</a>.'

	if fairy > 0:
		'Next to the sink is dishwashing liquid, enough for <b><<fairy>></b> uses.'
	else
		'<b><font color="red">You have nothing to wash dishes with, you need to buy dishwashing liquid.</font></b>'
	end

	if eda > 0:
		if cltarelka = 0 or edahot > 0:$edagot = ''
		if cltarelka > 0 and edahot = 0:$edagot = '<a href="exec:dynamic $edagotd">Cook meal (0:30)</a>'
		'In the refrigerator there''s food, enough for <b><<eda>></b> servings. <<$edagot>>'
	end

	if edaD = 0 and eda = 0:'<b><font color="red">The refrigerator is empty, you have nothing to eat.</font></b>'
	if edahot > 0: act 'A cooked meal is on the table (0:30).': dynamic $edahotd

	if husband > 0 and husbandrink ! 10:
		if hour = 7 or hour = 17:'<a href="exec:gt ''husb'', ''start''">Your husband is eating at the table.</a>'
	end

	if pranik > 0:
		if pranik = 1:
			'You only have one more portion of cookies.'
		else
			'You have enough cookies for <b><<pranik>></b> more snacks.'
		end
		dynamic $pranik
	end

	dynamic $edaD
	dynamic $fatdel
	dynamic $driwater
	dynamic $lekarstvo
	dynamic $vitamin
	
	act 'Go into the main room': gt 'dachain', ''
	act 'Goto the Bathroom':  gt 'dachain', 'dachavann'
end

if $args[0] = 'dachavann':
	$metka = 'dachavann'
	$metkaM = 'dachavann'
	cls
	clr
	gs 'stat'
	'<center><b><font color="maroon">Cottage Bathroom</font></b></center>'
	if dachaest = 2:
		'<center><img src="images/etogame/dachavan2.jpg"></center>'
	else
		'<center><img src="images/etogame/dachavan1.jpg"></center>'
	end
	gs 'din_van', 'private'
	act 'Goto the kitchen alcove': gt 'dachain', 'dachakit'
	act 'Go into the main room': gt 'dachain', ''
end

--- dachain ---------------------------------

